Add new dependencies/USE flags.

(Portage version: 2.2.0_alpha28/cvs/Linux i686)

2 files changed, 65 insertions, 1 deletions

diff --git a/net-nds/ypbind/ChangeLog b/net-nds/ypbind/ChangeLog
index 2518aab209ff..96b3fa2d61de 100644
--- a/net-nds/ypbind/ChangeLog
+++ b/net-nds/ypbind/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-nds/ypbind
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nds/ypbind/ChangeLog,v 1.60 2011/03/23 20:27:19 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nds/ypbind/ChangeLog,v 1.61 2011/03/24 19:29:17 jer Exp $
+
+*ypbind-1.32-r1 (24 Mar 2011)
+
+  24 Mar 2011; Jeroen Roovers <jer@gentoo.org> +ypbind-1.32-r1.ebuild:
+  Add new dependencies/USE flags.
 
   23 Mar 2011; Christoph Mende <angelos@gentoo.org> ypbind-1.32.ebuild:
   Stable on amd64 wrt bug #360165
diff --git a/net-nds/ypbind/ypbind-1.32-r1.ebuild b/net-nds/ypbind/ypbind-1.32-r1.ebuild
new file mode 100644
index 000000000000..4fc2933bdefe
--- /dev/null
+++ b/net-nds/ypbind/ypbind-1.32-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-nds/ypbind/ypbind-1.32-r1.ebuild,v 1.1 2011/03/24 19:29:18 jer Exp $
+
+EAPI="2"
+
+inherit eutils
+
+MY_P=${PN}-mt-${PV}
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="Multithreaded NIS bind service (ypbind-mt)"
+HOMEPAGE="http://www.linux-nis.org/nis/ypbind-mt/index.html"
+SRC_URI="ftp://ftp.kernel.org/pub/linux/utils/net/NIS/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug dbus nls slp"
+
+RDEPEND="
+	net-nds/yp-tools
+	debug? ( dev-libs/dmalloc )
+	dbus? ( dev-libs/dbus-glib )
+	slp? ( net-libs/openslp )
+	|| ( net-nds/portmap net-nds/rpcbind )"
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-1.31-man-port.patch" # bug #77810
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) $(use_enable slp) \
+		$(use_with debug dmalloc) $(use_enable dbus dbus-nm)
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+
+	dodoc AUTHORS ChangeLog README THANKS TODO
+
+	insinto /etc
+	newins etc/yp.conf yp.conf.example
+
+	newconfd "${FILESDIR}/ypbind.confd-r1" ypbind
+	newinitd "${FILESDIR}/ypbind.initd" ypbind
+}
+
+pkg_postinst() {
+	einfo "To complete setup, you will need to edit /etc/conf.d/ypbind."
+	einfo "If you are using dhcpcd, be sure to add the -Y option to"
+	einfo "dhcpcd_eth0 (or eth1, etc.) to keep dhcpcd from clobbering"
+	einfo "/etc/yp.conf."
+}