Support new net-tools ifconfig and route locations, bug #414243

(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

3 files changed, 106 insertions, 4 deletions

diff --git a/net-misc/gogoc/ChangeLog b/net-misc/gogoc/ChangeLog
index 7c29d9d8345e..6589212070c0 100644
--- a/net-misc/gogoc/ChangeLog
+++ b/net-misc/gogoc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/gogoc
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/gogoc/ChangeLog,v 1.15 2012/02/03 09:22:02 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/gogoc/ChangeLog,v 1.16 2012/06/11 13:18:12 voyageur Exp $
+
+*gogoc-1.2-r2 (11 Jun 2012)
+
+  11 Jun 2012; Bernard Cafarelli <voyageur@gentoo.org> gogoc-1.2-r1.ebuild,
+  +gogoc-1.2-r2.ebuild:
+  Support new net-tools ifconfig and route locations, bug #414243
 
   03 Feb 2012; Bernard Cafarelli <voyageur@gentoo.org> files/gogoc.rc:
   Fix warning message in init script, bug #401877
diff --git a/net-misc/gogoc/gogoc-1.2-r1.ebuild b/net-misc/gogoc/gogoc-1.2-r1.ebuild
index eb9ca201835d..d1516d8fd0e1 100644
--- a/net-misc/gogoc/gogoc-1.2-r1.ebuild
+++ b/net-misc/gogoc/gogoc-1.2-r1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/gogoc/gogoc-1.2-r1.ebuild,v 1.11 2011/05/07 18:14:11 tomka Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/gogoc/gogoc-1.2-r1.ebuild,v 1.12 2012/06/11 13:18:12 voyageur Exp $
 
 EAPI=2
 
@@ -24,7 +24,8 @@ IUSE="debug"
 
 DEPEND="dev-libs/openssl"
 RDEPEND="${DEPEND}
-	sys-apps/iproute2"
+	sys-apps/iproute2
+	<sys-apps/net-tools-1.60_p20120127084908"
 
 S="${WORKDIR}/${MY_P}"
 
diff --git a/net-misc/gogoc/gogoc-1.2-r2.ebuild b/net-misc/gogoc/gogoc-1.2-r2.ebuild
new file mode 100644
index 000000000000..c40c7e9c8494
--- /dev/null
+++ b/net-misc/gogoc/gogoc-1.2-r2.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/gogoc/gogoc-1.2-r2.ebuild,v 1.1 2012/06/11 13:18:12 voyageur Exp $
+
+EAPI=4
+
+inherit eutils versionator toolchain-funcs
+
+MY_P=${PN}-$(replace_all_version_separators "_")
+if [[ ${MY_P/_beta/} != ${MY_P} ]]; then
+	MY_P=${MY_P/_beta/-BETA}
+else
+	MY_P=${MY_P}-RELEASE
+fi
+
+DESCRIPTION="Client to connect to a tunnel broker using the TSP protocol (freenet6 for example)"
+HOMEPAGE="http://gogonet.gogo6.com/page/download-1"
+SRC_URI="http://gogo6.com/downloads/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~sparc ~x86"
+IUSE="debug"
+
+DEPEND="dev-libs/openssl"
+RDEPEND="${DEPEND}
+	sys-apps/iproute2
+	>=sys-apps/net-tools-1.60_p20120127084908"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-overflow.patch
+	epatch "${FILESDIR}"/${P}+gcc-4.6.patch
+
+	# Make the makefile handle linking correctly
+	find . -name Makefile -exec sed -i \
+		-e 's:LDFLAGS:LDLIBS:g' \
+		-e '/\$(LDLIBS)/s:-o:$(LDFLAGS) -o:' \
+		{} + || die "multised failed"
+
+	sed -i -e 's:/usr/local/etc/gogoc:/etc/gogoc:' \
+		gogoc-tsp/platform/*/tsp_local.c \
+		|| die "path sed failed"
+
+	# Newer net-tools use /bin
+	sed -i -e "/^\(route\|ifconfig\)=/s/sbin/bin/" \
+		gogoc-tsp/template/linux.sh \
+		|| die "net-tools sed failed"
+}
+
+src_configure() { :; }
+
+src_compile() {
+	# parallel make fails as inter-directory dependecies are missing.
+	emake -j1 \
+		AR="$(tc-getAR)" RANLIB="$(tc-getRANLIB)" \
+		CC="$(tc-getCC)" CXX="$(tc-getCXX)" LD="$(tc-getCXX)" \
+		EXTRA_CFLAGS="${CFLAGS}" EXTRA_CXXFLAGS="${CXXFLAGS}" \
+		$(use debug && echo DEBUG=1) \
+		all target=linux
+
+	emake -C gogoc-tsp/conf \
+		PLATFORM=linux PLATFORM_DIR=../platform BIN_DIR=../bin \
+		gogoc.conf.sample
+}
+
+src_install() {
+	dodoc README
+
+	cd "${S}"/gogoc-tsp
+	dosbin bin/gogoc
+
+	dodoc bin/gogoc.conf.sample
+
+	exeinto /etc/gogoc/template
+	doexe template/linux.sh
+
+	newinitd "${FILESDIR}"/gogoc.rc gogoc
+
+	doman man/{man5/gogoc.conf.5,man8/gogoc.8}
+	keepdir /var/lib/gogoc
+
+	diropts -m0700
+	keepdir /etc/gogoc
+}
+
+pkg_postinst() {
+	elog "You should create an /etc/gogoc/gogoc.conf file starting from"
+	elog "the sample configuration in /usr/share/doc/${PF}/gogo.conf.sample.*"
+	elog ""
+	elog "To add support for a TSP IPv6 connection at startup,"
+	elog "remember to run:"
+	elog "# rc-update add gogoc default"
+}