New ebuild for a Dropbox-like collaboration and sharing tool (bug #362295); thanks to Sven Mueller, Christoph Brill (egore), Aurélien Delogu, and Travis Hansen.

(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

3 files changed, 105 insertions, 0 deletions

diff --git a/net-misc/sparkleshare/ChangeLog b/net-misc/sparkleshare/ChangeLog
new file mode 100644
index 000000000000..8a2e6510daef
--- /dev/null
+++ b/net-misc/sparkleshare/ChangeLog
@@ -0,0 +1,12 @@
+# ChangeLog for net-misc/sparkleshare
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/sparkleshare/ChangeLog,v 1.1 2012/05/01 23:51:47 tetromino Exp $
+
+*sparkleshare-0.8.4 (01 May 2012)
+
+  01 May 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +sparkleshare-0.8.4.ebuild, +metadata.xml:
+  New ebuild for a Dropbox-like collaboration and sharing tool (bug #362295);
+  thanks to Sven Mueller, Christoph Brill (egore), Aurélien Delogu, and Travis
+  Hansen.
+
diff --git a/net-misc/sparkleshare/metadata.xml b/net-misc/sparkleshare/metadata.xml
new file mode 100644
index 000000000000..44e4dd149099
--- /dev/null
+++ b/net-misc/sparkleshare/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>gnome</herd>
+<use>
+	<flag name="nautilus">Build the <pkg>gnome-base/nautilus</pkg> extension</flag>
+</use>
+</pkgmetadata>
diff --git a/net-misc/sparkleshare/sparkleshare-0.8.4.ebuild b/net-misc/sparkleshare/sparkleshare-0.8.4.ebuild
new file mode 100644
index 000000000000..b3decdccb288
--- /dev/null
+++ b/net-misc/sparkleshare/sparkleshare-0.8.4.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/sparkleshare/sparkleshare-0.8.4.ebuild,v 1.1 2012/05/01 23:51:47 tetromino Exp $
+
+EAPI="4"
+
+GCONF_DEBUG="no" # --enable-debug does not do anything
+PYTHON_DEPEND="nautilus? 2"
+
+inherit gnome2 mono python
+
+DESCRIPTION="Git-based collaboration and file sharing tool"
+HOMEPAGE="http://www.sparkleshare.org"
+SRC_URI="http://github.com/downloads/hbons/SparkleShare/${PN}-linux-${PV}.tar.gz"
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="nautilus" # ayatana
+
+COMMON_DEPEND=">=dev-lang/mono-2.8
+	>=dev-dotnet/glib-sharp-2.12.7
+	>=dev-dotnet/gtk-sharp-2.12.10
+	dev-dotnet/notify-sharp
+	dev-dotnet/webkit-sharp
+	nautilus? ( || (
+		(
+			>=dev-python/nautilus-python-1.1-r1
+			>=gnome-base/nautilus-3 )
+		(
+			<dev-python/nautilus-python-1.1
+			=gnome-base/nautilus-2* )
+	) )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-vcs/git-1.7.3
+	gnome-base/gvfs
+	net-misc/curl[ssl]
+	net-misc/openssh
+	nautilus? ( || (
+		(
+			dev-python/pygobject:3
+			>=gnome-base/nautilus-3[introspection]
+			x11-libs/gtk+:3[introspection] )
+		(
+			dev-python/pygobject:2
+			dev-python/pygtk:2 )
+	) )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.6
+	dev-util/pkgconfig
+"
+
+pkg_setup () {
+	DOCS="AUTHORS NEWS TRADEMARK"
+	G2CONF="${G2CONF}
+		--disable-appindicator
+		$(use_enable nautilus nautilus-extension)"
+	#	$(use_enable ayatana appindicator)
+	# requires >=appindicator-sharp-0.0.7
+	python_pkg_setup
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# XXX: check if still needed in >=sparkleshare-0.9
+	sed -e '/	update-desktop-database/ d' \
+		-i SparkleShare/Makefile.in || die "sed failed"
+}
+
+src_compile() {
+	# FIXME: parallel make fails
+	MAKEOPTS="${MAKEOPTS} -j1" gnome2_src_compile
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	use nautilus && python_mod_optimize /usr/share/nautilus-python/extensions/
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	use nautilus && python_mod_cleanup /usr/share/nautilus-python/extensions/
+}