Version bump for Gnome 3.8

(Portage version: 2.1.11.60/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 62 insertions, 1 deletions

diff --git a/net-misc/networkmanager-openvpn/ChangeLog b/net-misc/networkmanager-openvpn/ChangeLog
index 4d250c771baa..2e0515451d46 100644
--- a/net-misc/networkmanager-openvpn/ChangeLog
+++ b/net-misc/networkmanager-openvpn/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/networkmanager-openvpn
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-openvpn/ChangeLog,v 1.38 2013/02/03 11:24:12 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-openvpn/ChangeLog,v 1.39 2013/04/07 15:12:05 pacho Exp $
+
+*networkmanager-openvpn-0.9.8.0 (07 Apr 2013)
+
+  07 Apr 2013; Pacho Ramos <pacho@gentoo.org>
+  +networkmanager-openvpn-0.9.8.0.ebuild:
+  Version bump for Gnome 3.8
 
   03 Feb 2013; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Cleanup due #333419
diff --git a/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.8.0.ebuild b/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.8.0.ebuild
new file mode 100644
index 000000000000..4a2862ac83ec
--- /dev/null
+++ b/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.8.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-openvpn/networkmanager-openvpn-0.9.8.0.ebuild,v 1.1 2013/04/07 15:12:05 pacho Exp $
+
+EAPI=5
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit eutils gnome2-utils gnome.org
+
+DESCRIPTION="NetworkManager OpenVPN plugin"
+HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk test"
+
+RDEPEND="
+	>=dev-libs/dbus-glib-0.74
+	>=net-misc/networkmanager-${PV}
+	>=net-misc/openvpn-2.1_rc9
+	gtk? (
+		>=x11-libs/gtk+-2.91.4:3
+		gnome-base/gnome-keyring
+	)"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	>=dev-util/intltool-0.35
+	virtual/pkgconfig"
+
+src_prepare() {
+	# Test will fail if the machine doesn't have a particular locale installed
+	# FAIL: (tls-import-data) unexpected 'ca' secret value
+	sed '/test_non_utf8_import (plugin, test_dir)/ d' \
+		-i properties/tests/test-import-export.c || die "sed failed"
+
+	# Drop DEPRECATED flags, bug #385597
+	gnome2_disable_deprecation_warning
+}
+
+src_configure() {
+	econf \
+		--disable-more-warnings \
+		--disable-static \
+		--with-dist-version=Gentoo \
+		--with-gtkver=3 \
+		$(use_with gtk gnome) \
+		$(use_with test tests)
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}