Version bump, add missing user.eclass to inherit (enewgroup/enewuser)

(Portage version: 2.2.0_alpha138/cvs/Linux x86_64, signed Manifest commit with key 0x5D21B852895192F9)

3 files changed, 79 insertions, 4 deletions

diff --git a/net-libs/libinfinity/ChangeLog b/net-libs/libinfinity/ChangeLog
index fff1d52f3ec6..939564978ebc 100644
--- a/net-libs/libinfinity/ChangeLog
+++ b/net-libs/libinfinity/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/libinfinity
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libinfinity/ChangeLog,v 1.14 2012/05/05 02:54:31 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libinfinity/ChangeLog,v 1.15 2012/10/22 06:47:50 xarthisius Exp $
+
+*libinfinity-0.5.3 (22 Oct 2012)
+
+  22 Oct 2012; Kacper Kowalik <xarthisius@gentoo.org> +libinfinity-0.5.3.ebuild,
+  libinfinity-0.5.2.ebuild:
+  Version bump, add missing user.eclass to inherit (enewgroup/enewuser)
 
   05 May 2012; Jeff Horelick <jdhore@gentoo.org> libinfinity-0.5.2.ebuild:
   dev-util/pkgconfig -> virtual/pkgconfig
@@ -68,4 +74,3 @@
   +files/infinoted.confd-0.2, +files/infinoted.initd-0.2, +metadata.xml,
   +libinfinity-0.2.0.ebuild:
   Initial commit (ebuild written by me) for new version of gobby.
-
diff --git a/net-libs/libinfinity/libinfinity-0.5.2.ebuild b/net-libs/libinfinity/libinfinity-0.5.2.ebuild
index 567387645534..cb4853db3713 100644
--- a/net-libs/libinfinity/libinfinity-0.5.2.ebuild
+++ b/net-libs/libinfinity/libinfinity-0.5.2.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libinfinity/libinfinity-0.5.2.ebuild,v 1.2 2012/05/05 02:54:31 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libinfinity/libinfinity-0.5.2.ebuild,v 1.3 2012/10/22 06:47:50 xarthisius Exp $
 
 EAPI=4
 
-inherit autotools-utils eutils versionator
+inherit autotools-utils eutils versionator user
 
 MY_PV=$(get_version_component_range 1-2)
 
diff --git a/net-libs/libinfinity/libinfinity-0.5.3.ebuild b/net-libs/libinfinity/libinfinity-0.5.3.ebuild
new file mode 100644
index 000000000000..ee5b4c572877
--- /dev/null
+++ b/net-libs/libinfinity/libinfinity-0.5.3.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libinfinity/libinfinity-0.5.3.ebuild,v 1.1 2012/10/22 06:47:50 xarthisius Exp $
+
+EAPI=4
+
+inherit autotools-utils eutils versionator user
+
+MY_PV=$(get_version_component_range 1-2)
+
+DESCRIPTION="An implementation of the Infinote protocol written in GObject-based C."
+HOMEPAGE="http://gobby.0x539.de/"
+SRC_URI="http://releases.0x539.de/${PN}/${P}.tar.gz"
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="avahi doc gtk server static-libs"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/libxml2
+	net-libs/gnutls
+	sys-libs/pam
+	virtual/gsasl
+	avahi? ( net-dns/avahi )
+	gtk? ( x11-libs/gtk+:3 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext
+	doc? ( dev-util/gtk-doc )"
+
+DOCS=(AUTHORS NEWS README TODO)
+
+pkg_setup() {
+	if use server ; then
+		enewgroup infinote 100
+		enewuser infinote 100 /bin/bash /var/lib/infinote infinote
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable doc gtk-doc)
+		$(use_with gtk inftextgtk)
+		$(use_with gtk infgtk)
+		$(use_with gtk gtk3)
+		$(use_with server infinoted)
+		$(use_with avahi)
+		$(use_with avahi libdaemon)
+	)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	if use server ; then
+		newinitd "${FILESDIR}/infinoted.initd" infinoted
+		newconfd "${FILESDIR}/infinoted.confd" infinoted
+
+		keepdir /var/lib/infinote
+		fowners infinote:infinote /var/lib/infinote
+		fperms 770 /var/lib/infinote
+
+		dosym /usr/bin/infinoted-${MY_PV} /usr/bin/infinoted
+
+		elog "Add local users who should have local access to the documents"
+		elog "created by infinoted to the infinote group."
+		elog "The documents are saved in /var/lib/infinote per default."
+	fi
+}