Version bump.

(Portage version: 2.1.8.3/cvs/Linux x86_64)

2 files changed, 87 insertions, 1 deletions

diff --git a/net-libs/ortp/ChangeLog b/net-libs/ortp/ChangeLog
index f73e447727c7..784b32d01978 100644
--- a/net-libs/ortp/ChangeLog
+++ b/net-libs/ortp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/ortp
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/ortp/ChangeLog,v 1.55 2010/05/20 10:06:39 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/ortp/ChangeLog,v 1.56 2010/05/20 12:41:58 pva Exp $
+
+*ortp-0.16.2 (20 May 2010)
+
+  20 May 2010; Peter Volkov <pva@gentoo.org> +ortp-0.16.2.ebuild:
+  Version bump.
 
   20 May 2010; Peter Volkov <pva@gentoo.org> ortp-0.16.1.ebuild:
   amd64 stable, bug 317235.
diff --git a/net-libs/ortp/ortp-0.16.2.ebuild b/net-libs/ortp/ortp-0.16.2.ebuild
new file mode 100644
index 000000000000..8e55194bf15e
--- /dev/null
+++ b/net-libs/ortp/ortp-0.16.2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/ortp/ortp-0.16.2.ebuild,v 1.1 2010/05/20 12:41:58 pva Exp $
+
+EAPI="3"
+
+inherit eutils
+
+DESCRIPTION="Open Real-time Transport Protocol (RTP, RFC3550) stack"
+HOMEPAGE="http://www.linphone.org/index.php/eng/code_review/ortp/"
+SRC_URI="http://download.savannah.nongnu.org/releases-noredirect/linphone/${PN}/sources/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~ppc-macos ~x86-macos"
+IUSE="debug doc examples ipv6 minimal srtp ssl"
+
+RDEPEND="srtp? ( net-libs/libsrtp )
+	ssl? ( dev-libs/openssl )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	# to be sure doc is not builded nor installed w/ -doc and doxygen installed
+	if ! use doc; then
+		sed -i -e 's/test $DOXYGEN != //' configure \
+			|| die "patching configure failed"
+	fi
+
+	# to authorize -srtp even with libsrtp installed
+	if ! use srtp; then
+		sed -i -e 's/$have_srtp_headers$have_srtp_lib//' configure \
+			|| die "patching configure failed"
+	fi
+
+	# to authorize -ssl even with openssl installed
+	if ! use ssl; then
+		sed -i -e 's/SSL_LIBS=".*"/SSL_LIBS=""/' \
+			-e 's/openssl\/.*.h/poll.h/' configure \
+			|| die "patching configure failed"
+	fi
+
+	# do not build examples programs, see bug 226247
+	sed -i -e 's/SUBDIRS = . tests/SUBDIRS = ./' src/Makefile.in \
+		|| die "patching src/Makefile.in failed"
+
+	# ${P} is added after ${docdir}
+	if use doc; then
+		sed -i -e 's/$(docdir)\/$(PACKAGE)-$(VERSION)/$(docdir)/' Makefile.in \
+			|| die "patching Makefile.in failed"
+	fi
+}
+
+src_configure() {
+	# force docdir to standard Gentoo doc directory
+	# memcheck is for HP-UX only
+	# mode64bit adds +DA2.0W +DS2.0 CFLAGS wich are needed for HP-UX
+	# strict adds -Werror, don't want it
+	econf \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		--disable-memcheck \
+		--disable-mode64bit \
+		--disable-strict \
+		--disable-dependency-tracking \
+		--enable-fast-install \
+		--enable-libtool-lock \
+		$(use_enable debug) \
+		$(use_enable ipv6) \
+		$(use_enable minimal perf)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins src/tests/*.c || die "doins failed"
+	fi
+}