Version bump wrt bug #488486.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

2 files changed, 85 insertions, 1 deletions

diff --git a/net-libs/libssh/ChangeLog b/net-libs/libssh/ChangeLog
index fbf3c1ba2237..8fad592e3bdf 100644
--- a/net-libs/libssh/ChangeLog
+++ b/net-libs/libssh/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libssh
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/ChangeLog,v 1.85 2013/09/22 16:43:32 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/ChangeLog,v 1.86 2013/10/18 19:54:19 johu Exp $
+
+*libssh-0.6.0_rc1 (18 Oct 2013)
+
+  18 Oct 2013; Johannes Huber <johu@gentoo.org> +libssh-0.6.0_rc1.ebuild:
+  Version bump wrt bug #488486.
 
   22 Sep 2013; Jeroen Roovers <jer@gentoo.org> libssh-0.5.5.ebuild:
   Pick the correct libdir by Nikoli (bug #485600 again).
diff --git a/net-libs/libssh/libssh-0.6.0_rc1.ebuild b/net-libs/libssh/libssh-0.6.0_rc1.ebuild
new file mode 100644
index 000000000000..fb6195756c4a
--- /dev/null
+++ b/net-libs/libssh/libssh-0.6.0_rc1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/libssh-0.6.0_rc1.ebuild,v 1.1 2013/10/18 19:54:19 johu Exp $
+
+EAPI=5
+
+MY_P=${PN}-${PV/_rc1/rc1}
+inherit eutils cmake-utils multilib
+
+DESCRIPTION="Access a working SSH implementation by means of a library"
+HOMEPAGE="http://www.libssh.org/"
+SRC_URI="https://red.libssh.org/attachments/download/52/${MY_P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+SLOT="0/4" # subslot = soname major version
+IUSE="debug doc examples gcrypt pcap +sftp ssh1 server static-libs test zlib"
+# Maintainer: check IUSE-defaults at DefineOptions.cmake
+
+RDEPEND="
+	zlib? ( >=sys-libs/zlib-1.2 )
+	!gcrypt? ( >=dev-libs/openssl-0.9.8 )
+	gcrypt? ( >=dev-libs/libgcrypt-1.4 )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cmockery )
+"
+
+DOCS=( AUTHORS README ChangeLog )
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=( "${FILESDIR}/${PN}-0.5.0-tests.patch" )
+
+src_prepare() {
+	# just install the examples do not compile them
+	sed -i \
+		-e '/add_subdirectory(examples)/s/^/#DONOTWANT/' \
+		CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with debug DEBUG_CALLTRACE)
+		$(cmake-utils_use_with debug DEBUG_CRYPTO)
+		$(cmake-utils_use_with gcrypt)
+		$(cmake-utils_use_with pcap)
+		$(cmake-utils_use_with server)
+		$(cmake-utils_use_with sftp)
+		$(cmake-utils_use_with ssh1)
+		$(cmake-utils_use_with static-libs STATIC_LIB)
+		$(cmake-utils_use_with test STATIC_LIB)
+		$(cmake-utils_use_with test TESTING)
+		$(cmake-utils_use_with zlib)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	use doc && cmake-utils_src_compile doc
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use doc && dohtml -r "${CMAKE_BUILD_DIR}"/doc/html/*
+
+	use static-libs || rm -f "${D}"/usr/$(get_libdir)/libssh{,_threads}.a
+
+	if use examples; then
+		docinto examples
+		dodoc examples/*.{c,h,cpp}
+	fi
+}