Enable multilib support.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 90 insertions, 1 deletions

diff --git a/net-libs/gupnp/ChangeLog b/net-libs/gupnp/ChangeLog
index 6383f417478e..cea1cb3d299b 100644
--- a/net-libs/gupnp/ChangeLog
+++ b/net-libs/gupnp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/gupnp
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp/ChangeLog,v 1.84 2014/05/31 15:38:07 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp/ChangeLog,v 1.85 2014/06/10 18:01:44 mgorny Exp $
+
+*gupnp-0.20.12-r1 (10 Jun 2014)
+
+  10 Jun 2014; Michał Górny <mgorny@gentoo.org> +gupnp-0.20.12-r1.ebuild:
+  Enable multilib support.
 
 *gupnp-0.20.12 (31 May 2014)
 
diff --git a/net-libs/gupnp/gupnp-0.20.12-r1.ebuild b/net-libs/gupnp/gupnp-0.20.12-r1.ebuild
new file mode 100644
index 000000000000..97d3ede4b81c
--- /dev/null
+++ b/net-libs/gupnp/gupnp-0.20.12-r1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp/gupnp-0.20.12-r1.ebuild,v 1.1 2014/06/10 18:01:44 mgorny Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+VALA_MIN_API_VERSION="0.14"
+VALA_USE_DEPEND="vapigen"
+# FIXME: Claims to works with python3 but appears to be wishful thinking
+PYTHON_COMPAT=( python{2_6,2_7} )
+PYTHON_REQ_USE="xml"
+
+inherit gnome2 multilib-minimal python-r1 vala
+
+DESCRIPTION="An object-oriented framework for creating UPnP devs and control points"
+HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP"
+
+LICENSE="LGPL-2"
+SLOT="0/4"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="connman +introspection kernel_linux networkmanager"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=net-libs/gssdp-0.13.0:0=[introspection?,${MULTILIB_USEDEP}]
+	>=net-libs/libsoup-2.28.2:2.4[introspection?,${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.28.0:2[${MULTILIB_USEDEP}]
+	dev-libs/libxml2[${MULTILIB_USEDEP}]
+	|| (
+		>=sys-apps/util-linux-2.16[${MULTILIB_USEDEP}]
+		<sys-libs/e2fsprogs-libs-1.41.8[${MULTILIB_USEDEP}] )
+	introspection? (
+			>=dev-libs/gobject-introspection-0.6.4
+			$(vala_depend) )
+	connman? ( >=dev-libs/glib-2.28:2[${MULTILIB_USEDEP}] )
+	networkmanager? ( >=dev-libs/glib-2.26:2[${MULTILIB_USEDEP}] )
+	!net-libs/gupnp-vala
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1
+	sys-devel/gettext
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+"
+
+# either of the two backends will be used
+REQUIRED_USE="^^ ( connman networkmanager )"
+
+src_prepare() {
+	use introspection && vala_src_prepare
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	local backend=unix
+	use kernel_linux && backend=linux
+	use connman && backend=connman
+	use networkmanager && backend=network-manager
+
+	# fake connman.pc to avoid pulling it in unnecessarily (only dbus
+	# interface is used) and fix multilib.
+	# https://bugzilla.gnome.org/show_bug.cgi?id=731457
+
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		CONNMAN_CFLAGS=' ' CONNMAN_LIBS=' ' \
+		$(multilib_native_use_enable introspection) \
+		--disable-static \
+		--with-context-manager=${backend}
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/doc/html doc/html || die
+	fi
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	python_parallel_foreach_impl python_doscript tools/gupnp-binding-tool
+}