Version bump, bug #456072.

(Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 74 insertions, 1 deletions

diff --git a/net-libs/gnome-online-accounts/ChangeLog b/net-libs/gnome-online-accounts/ChangeLog
index 29271ac414ca..d37ae369d37e 100644
--- a/net-libs/gnome-online-accounts/ChangeLog
+++ b/net-libs/gnome-online-accounts/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/gnome-online-accounts
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnome-online-accounts/ChangeLog,v 1.13 2013/03/29 23:31:06 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnome-online-accounts/ChangeLog,v 1.14 2013/03/30 23:05:37 eva Exp $
+
+*gnome-online-accounts-3.6.3 (30 Mar 2013)
+
+  30 Mar 2013; Gilles Dartiguelongue <eva@gentoo.org>
+  +gnome-online-accounts-3.6.3.ebuild:
+  Version bump, bug #456072.
 
   29 Mar 2013; Gilles Dartiguelongue <eva@gentoo.org>
   -gnome-online-accounts-3.4.2.ebuild:
diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.6.3.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.6.3.ebuild
new file mode 100644
index 000000000000..ff582e19af3a
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.6.3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnome-online-accounts/gnome-online-accounts-3.6.3.ebuild,v 1.1 2013/03/30 23:05:37 eva Exp $
+
+EAPI="5"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://live.gnome.org/GnomeOnlineAccounts"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+IUSE="gnome +introspection kerberos"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# pango used in goaeditablelabel
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	app-crypt/libsecret
+	dev-libs/json-glib
+	dev-libs/libxml2:2
+	net-libs/libsoup:2.4
+	>=net-libs/libsoup-gnome-2.38:2.4
+	net-libs/rest:0.7
+	net-libs/webkit-gtk:3
+	>=x11-libs/gtk+-3.5.1:3
+	>=x11-libs/libnotify-0.7:=
+	x11-libs/pango
+
+	introspection? ( >=dev-libs/gobject-introspection-0.6.2 )
+	kerberos? (
+		app-crypt/gcr
+		app-crypt/mit-krb5 )
+"
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	>=dev-util/gtk-doc-am-1.3
+	>=dev-util/gdbus-codegen-2.30.0
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# fix build failure with gcc-4.5 and USE=kerberos, bug #450706
+	# https://bugzilla.gnome.org/show_bug.cgi?id=692251
+	epatch "${FILESDIR}/${PN}-3.6.2-GoaKerberosIdentity.patch"
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# TODO: Give users a way to set the G/Y!/FB/Twitter/Windows Live secrets
+	gnome2_src_configure \
+		--disable-static \
+		--enable-documentation \
+		--enable-exchange \
+		--enable-facebook \
+		--enable-windows-live \
+		$(use_enable kerberos)
+}