new package, a fork of supybot which has ceased active development. ebuild base on the old supybot ebuild, re-written by proxy maintainer, ebuilds extensively developed and tested with submissions upstream which is currently active. No corresponding bug for this

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

5 files changed, 219 insertions, 0 deletions

diff --git a/net-irc/limnoria/ChangeLog b/net-irc/limnoria/ChangeLog
new file mode 100644
index 000000000000..e22f0456a757
--- /dev/null
+++ b/net-irc/limnoria/ChangeLog
@@ -0,0 +1,13 @@
+# ChangeLog for net-irc/limnoria
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/limnoria/ChangeLog,v 1.1 2015/03/04 09:13:38 idella4 Exp $
+
+*limnoria-20150208 (04 Mar 2015)
+*limnoria-99999999 (04 Mar 2015)
+
+  04 Mar 2015; Ian Delaney <idella4@gentoo.org> +limnoria-20150208.ebuild,
+  +limnoria-99999999.ebuild, +metadata.xml:
+  new package, a fork of supybot which has ceased active development. ebuild
+  base on the old supybot ebuild, re-written by proxy maintainer, ebuilds
+  extensively developed and tested with submissions upstream which is currently
+  active. No corresponding bug for this
diff --git a/net-irc/limnoria/Manifest b/net-irc/limnoria/Manifest
new file mode 100644
index 000000000000..41f83c48431c
--- /dev/null
+++ b/net-irc/limnoria/Manifest
@@ -0,0 +1,4 @@
+DIST limnoria-20150208.tar.gz 902312 SHA256 2d30bb0f2054a159bc8074c7d286611fed4ccb3841900dabfc2393f666ba11ad SHA512 df4db9f7b0c8a016f19488c8229509fcea61b75856c6fc342bc35935c5e253532307013674fe544d31eeffbc9bcb48788aae74010352ff70f142276407aeb6ef WHIRLPOOL c8f6c8f3d3a527454216bbd66db7525c4dcc544e2a1be8e966d10603471458f7184da99a075589938626dd8229c0e4076ec06cc92b9d34efd94c5d8f0f9ca2eb
+EBUILD limnoria-20150208.ebuild 2657 SHA256 b76814ce329db03284c64d7e4bb72a1d353285f8e1d48eb3735f9fa26141d355 SHA512 29558369b3eb314c0518d24524673cca620f669d409f8af65b63d6f904d3a0256697603f347a4d5c5235bbf6d110e6f1d8868a7264f6f146abc9261e595420ca WHIRLPOOL 0792aa3c8437c17723d693206aa3a5ad7cf2af73c51f062801edeb2d0e892a420c41af62b75cd09dd8e13f0abfca70af4263097bee624b4e3540e619d023a0bf
+EBUILD limnoria-99999999.ebuild 2680 SHA256 693d1217bb24e78ed2d9ff8ca57243d270c3bb87e8d01e25dcbb0ff898644976 SHA512 f20aaa1f550dd905661cea6be7512e379583484e3a56ef85e90d2ed11c006020f6543d5366b135ca2e5886e9396bb93274d797ffd7440430388abc6761a185dd WHIRLPOOL 9e24d18fec4b0aef35eae4b76f83b6b609f46f63f0243043fee449b936b9cea0fe9c380c8b33ca40cc07f0f1850433892c0e29b7010eb55af87fcf83e9d71654
+MISC metadata.xml 477 SHA256 a6eba8192097a9d15384a11b5691ded2b0a83d57a4006a78a2af0b03d6f00423 SHA512 f8aa94af426f01f436e7ccb60bea47343216c1b45232825a278b5f7155a9cb98fbd546ba74878529ffc8a9c28f1d0e78335040cf4d101427e72060a05053c83b WHIRLPOOL 40f8a2b5011881da7a35f749cf07e52aaad830447c62ce9f15e88f54c17ec3a34a7c1c3a3c9ebe669bb54e7ba49efd0585e4bb61ab6fbd121026d49259945750
diff --git a/net-irc/limnoria/limnoria-20150208.ebuild b/net-irc/limnoria/limnoria-20150208.ebuild
new file mode 100644
index 000000000000..7735a592c722
--- /dev/null
+++ b/net-irc/limnoria/limnoria-20150208.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/limnoria/limnoria-20150208.ebuild,v 1.1 2015/03/04 09:13:38 idella4 Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
+MY_PN="Limnoria"
+MY_P="${MY_PN}-${MY_PV}"
+
+if [[ ${PV} == "99999999" ]]; then
+	EGIT_REPO_URI="git://github.com/ProgVal/Limnoria.git"
+	EGIT_BRANCH="master"
+	inherit git-r3
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/ProgVal/${MY_PN}/archive/master-${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${MY_PN}-master-${MY_PV}"
+fi
+
+DESCRIPTION="Python based extensible IRC infobot and channel bot"
+HOMEPAGE="http://supybot.aperio.fr/"
+LICENSE="BSD"
+SLOT="0"
+IUSE="crypt test"
+
+RDEPEND="
+	dev-python/charade[${PYTHON_USEDEP}]
+	dev-python/ecdsa[${PYTHON_USEDEP}]
+	dev-python/feedparser[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/socksipy[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	crypt? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
+	!net-irc/supybot
+	!net-irc/supybot-plugins
+	"
+DEPEND="${RDEPEND}
+	test? ( $(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7) )"
+
+src_unpack() {
+	if [[ ${PV} == "99999999" ]]; then
+		git-r3_src_unpack
+	else
+		unpack ${P}.tar.gz
+	fi
+}
+
+python_prepare(){
+	distutils-r1_python_prepare
+	if python_is_python3; then
+		einfo "Removing the RSS plugin because of clashes between libxml2's Python3"
+		einfo "bindings and feedparser."
+		rm -rf "plugins/RSS" || die
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	doman man/*
+}
+
+python_test() {
+	pushd "${T}" > /dev/null
+	PLUGINS_DIR="${BUILD_DIR}/lib/supybot/plugins"
+	# recommended by upstream, unknown random failure
+	EXCLUDE_PLUGINS=( --exclude="${PLUGINS_DIR}/Scheduler" )
+	# recommended by upstream, unknown random failure
+	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Filter" )
+	# intermittent failure due to issues loading libsandbox.so from LD_PRELOAD
+	# runs successfully when running the tests on the installed system
+	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Unix" )
+	"${PYTHON}" "${BUILD_DIR}"/scripts/supybot-test \
+		--plugins-dir="${PLUGINS_DIR}" --no-network \
+		--disable-multiprocessing "${EXCLUDE_PLUGINS[@]}" \
+		|| die "Tests failed under ${EPYTHON}"
+	popd > /dev/null
+}
+
+pkg_postinst() {
+	elog "Complete user documentation is available at https://limnoria-doc.readthedocs.org/"
+	elog ""
+	elog "Use supybot-wizard to create a configuration file."
+	elog "Run supybot </path/to/config> to use the bot."
+	elog ""
+	elog "There are additional plugins available in net-im/limnoria-plugins"
+	elog ""
+}
diff --git a/net-irc/limnoria/limnoria-99999999.ebuild b/net-irc/limnoria/limnoria-99999999.ebuild
new file mode 100644
index 000000000000..0d4d7c286fb5
--- /dev/null
+++ b/net-irc/limnoria/limnoria-99999999.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/limnoria/limnoria-99999999.ebuild,v 1.1 2015/03/04 09:13:38 idella4 Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
+MY_PN="Limnoria"
+MY_P="${MY_PN}-${MY_PV}"
+
+if [[ ${PV} == "99999999" ]]; then
+	EGIT_REPO_URI="git://github.com/ProgVal/Limnoria.git"
+	EGIT_BRANCH="master"
+	inherit git-r3
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/ProgVal/${MY_PN}/archive/master-${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${MY_PN}-master-${MY_PV}"
+fi
+
+DESCRIPTION="Python based extensible IRC infobot and channel bot"
+HOMEPAGE="http://supybot.aperio.fr/"
+LICENSE="BSD"
+SLOT="0"
+IUSE="crypt test"
+
+RDEPEND="
+	dev-python/charade[${PYTHON_USEDEP}]
+	dev-python/ecdsa[${PYTHON_USEDEP}]
+	dev-python/feedparser[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/socksipy[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	crypt? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
+	!net-irc/supybot
+	!net-irc/supybot-plugins
+	"
+DEPEND="${RDEPEND}
+	test? ( $(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7) )"
+
+src_unpack() {
+	if [[ ${PV} == "99999999" ]]; then
+		git-r3_src_unpack
+	else
+		unpack ${P}.tar.gz
+	fi
+}
+
+python_prepare(){
+	distutils-r1_python_prepare
+	if python_is_python3; then
+		einfo "Removing the RSS plugin because of clashes between libxml2's Python3"
+		einfo "bindings and feedparser."
+		rm -rf "plugins/RSS" || die
+	fi
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	doman man/*
+}
+
+python_test() {
+	pushd "${T}" > /dev/null
+	PLUGINS_DIR="${BUILD_DIR}/lib/supybot/plugins"
+	# recommended by upstream, unknown random failure
+	EXCLUDE_PLUGINS=( --exclude="${PLUGINS_DIR}/Scheduler" )
+	# recommended by upstream, unknown random failure
+	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Filter" )
+	# intermittent failure due to issues loading libsandbox.so from LD_PRELOAD
+	# runs successfully when running the tests on the installed system
+	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Unix" )
+	"${PYTHON}" "${BUILD_DIR}"/scripts/supybot-test "${BUILD_DIR}/../test" \
+		--plugins-dir="${PLUGINS_DIR}" --no-network \
+		--disable-multiprocessing "${EXCLUDE_PLUGINS[@]}" \
+		|| die "Tests failed under ${EPYTHON}"
+	popd > /dev/null
+}
+
+pkg_postinst() {
+	elog "Complete user documentation is available at https://limnoria-doc.readthedocs.org/"
+	elog ""
+	elog "Use supybot-wizard to create a configuration file."
+	elog "Run supybot </path/to/config> to use the bot."
+	elog ""
+	elog "There are additional plugins available in net-im/limnoria-plugins"
+	elog ""
+}
diff --git a/net-irc/limnoria/metadata.xml b/net-irc/limnoria/metadata.xml
new file mode 100644
index 000000000000..c9f7ad0ffbd1
--- /dev/null
+++ b/net-irc/limnoria/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>proxy-maintainers</herd>
+	<maintainer>
+		<email>idella4@gentoo.org</email>
+	</maintainer>
+	<maintainer>
+		<email>np.hardass@gmail.com</email>
+		<name>NP-Hardass</name>
+		<description>proxy maintainer and recipient of bugs</description>
+	</maintainer>
+	<use>
+		<flag name="crypt">Enables user authentication with GPG</flag>
+	</use>
+</pkgmetadata>