version bump

(Portage version: 2.1.2.3)

3 files changed, 104 insertions, 1 deletions

diff --git a/net-im/ekiga/ChangeLog b/net-im/ekiga/ChangeLog
index 96ac2bdc9188..19c7d47b9616 100644
--- a/net-im/ekiga/ChangeLog
+++ b/net-im/ekiga/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/ekiga
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/ekiga/ChangeLog,v 1.39 2007/04/14 08:13:08 genstef Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/ekiga/ChangeLog,v 1.40 2007/04/14 08:57:59 genstef Exp $
+
+*ekiga-2.0.9 (14 Apr 2007)
+
+  14 Apr 2007; Stefan Schweizer <genstef@gentoo.org> +ekiga-2.0.9.ebuild:
+  version bump
 
   14 Apr 2007; Stefan Schweizer <genstef@gentoo.org> -ekiga-2.0.3.ebuild,
   -ekiga-2.0.5.ebuild:
diff --git a/net-im/ekiga/ekiga-2.0.9.ebuild b/net-im/ekiga/ekiga-2.0.9.ebuild
new file mode 100644
index 000000000000..77886a1a91e5
--- /dev/null
+++ b/net-im/ekiga/ekiga-2.0.9.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/ekiga/ekiga-2.0.9.ebuild,v 1.1 2007/04/14 08:57:59 genstef Exp $
+
+inherit gnome2 eutils flag-o-matic
+
+DESCRIPTION="H.323 and SIP VoIP softphone"
+HOMEPAGE="http://www.ekiga.org/"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="avahi dbus doc gnome sdl"
+
+RDEPEND="~dev-libs/pwlib-1.10.$[${PV##*.}-2]
+	~net-libs/opal-2.2.$[${PV##*.}-1]
+	>=net-nds/openldap-2.0.0
+	>=x11-libs/gtk+-2.4.0
+	>=dev-libs/glib-2.0.0
+	>=dev-libs/libxml2-2.6.1
+	sdl? ( >=media-libs/libsdl-1.2.4 )
+	dbus? ( || ( >=dev-libs/dbus-glib-0.71
+		( <sys-apps/dbus-0.90 >=sys-apps/dbus-0.61 ) ) )
+	avahi? ( net-dns/avahi )
+	gnome? ( >=gnome-base/libbonoboui-2.2.0
+		>=gnome-base/libbonobo-2.2.0
+		>=gnome-base/libgnomeui-2.2.0
+		>=gnome-base/libgnome-2.2.0
+		>=gnome-base/gnome-vfs-2.2.0
+		>=gnome-base/gconf-2.2.0
+		>=gnome-base/orbit-2.5.0
+		gnome-extra/evolution-data-server
+		>=media-sound/esound-0.2.28
+		doc? ( app-text/gnome-doc-utils ) )"
+
+
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	>=dev-util/pkgconfig-0.12.0
+	>=dev-util/intltool-0.20
+	gnome? ( app-text/scrollkeeper )"
+
+pkg_setup() {
+	if ! built_with_use dev-libs/pwlib ldap; then
+		eerror "You need to build dev-libs/pwlib with USE=ldap enabled."
+		die "Pwlib w/o ldap-support detected."
+	fi
+
+	if use avahi && ! built_with_use net-dns/avahi dbus; then
+		eerror "You need to build net-dns/avahi with USE=dbus enabled."
+		die "Avahi without dbus-support detected."
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+
+	cd "${S}"
+	# Fix configure to install schemafile into the proper directory
+	epatch "${FILESDIR}"/${PN}-1.99.0-configure.patch
+}
+
+src_compile() {
+	econf \
+		$(use_enable dbus) \
+		$(use_enable sdl) \
+		$(use_enable avahi) \
+		$(use_enable doc) \
+		$(use_enable gnome) \
+		|| die "econf failed"
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	if use gnome; then
+		gnome2_src_install
+	else
+		make DESTDIR="${D}" install || die "make install failed"
+
+		dodoc AUTHORS ChangeLog NEWS
+	fi
+}
+
+pkg_postinst() {
+	if use gnome; then
+		gnome2_pkg_postinst
+
+		# we need to fix the GConf permissions, see bug #59764
+		einfo "Fixing GConf permissions for ekiga"
+		ekiga-config-tool --fix-permissions
+	fi
+}
+
+DOCS="AUTHORS ChangeLog NEWS"
diff --git a/net-im/ekiga/files/digest-ekiga-2.0.9 b/net-im/ekiga/files/digest-ekiga-2.0.9
new file mode 100644
index 000000000000..f051ac2eabb3
--- /dev/null
+++ b/net-im/ekiga/files/digest-ekiga-2.0.9
@@ -0,0 +1,3 @@
+MD5 6c7a01faef8203d6f0ba0dfe6188bb1a ekiga-2.0.9.tar.bz2 5530540
+RMD160 c9b26fd195137c911a3fecbbfb319670c2617ab6 ekiga-2.0.9.tar.bz2 5530540
+SHA256 686b303f807460cd5486dab07654a7f76acaee44db640748b62dd0326f15ec72 ekiga-2.0.9.tar.bz2 5530540