Version Bump, #378635

(Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

3 files changed, 123 insertions, 13 deletions

diff --git a/net-im/gajim/ChangeLog b/net-im/gajim/ChangeLog
index 0ee05d5c1600..6ff887074d7f 100644
--- a/net-im/gajim/ChangeLog
+++ b/net-im/gajim/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-im/gajim
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v 1.118 2011/06/20 12:19:50 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v 1.119 2011/08/14 16:56:59 jlec Exp $
+
+*gajim-0.14.4 (14 Aug 2011)
+
+  14 Aug 2011; Justin Lecher <jlec@gentoo.org> +gajim-0.14.4.ebuild,
+  metadata.xml:
+  Version Bump, #378635
 
 *gajim-0.14.3 (20 Jun 2011)
 
diff --git a/net-im/gajim/gajim-0.14.4.ebuild b/net-im/gajim/gajim-0.14.4.ebuild
new file mode 100644
index 000000000000..e4eabee49d1d
--- /dev/null
+++ b/net-im/gajim/gajim-0.14.4.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/gajim-0.14.4.ebuild,v 1.1 2011/08/14 16:56:59 jlec Exp $
+
+EAPI=2
+
+PYTHON_DEPEND="2"
+PYTHON_USE_WITH="sqlite xml"
+
+inherit eutils python versionator
+
+DESCRIPTION="Jabber client written in PyGTK"
+HOMEPAGE="http://www.gajim.org/"
+SRC_URI="http://www.gajim.org/downloads/$(get_version_component_range 1-2)/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="avahi crypt dbus gmail gnome idle jingle libnotify networkmanager nls spell srv X xhtml"
+
+COMMON_DEPEND="
+	dev-python/pygtk:2
+	x11-libs/gtk+:2"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.1
+	dev-util/pkgconfig
+	>=sys-devel/gettext-0.17-r1"
+RDEPEND="${COMMON_DEPEND}
+	dev-python/pyopenssl
+	crypt? (
+		app-crypt/gnupg
+		dev-python/pycrypto
+		)
+	dbus? (
+		dev-python/dbus-python
+		dev-libs/dbus-glib
+		libnotify? ( dev-python/notify-python )
+		avahi? ( net-dns/avahi[dbus,gtk,python] )
+		)
+	gmail? ( net-dns/bind-tools )
+	gnome? (
+		dev-python/libgnome-python
+		dev-python/gnome-keyring-python
+		dev-python/egg-python
+		)
+	idle? ( x11-libs/libXScrnSaver )
+	jingle? ( net-libs/farsight2[python] )
+	networkmanager? (
+			dev-python/dbus-python
+			|| ( >=net-misc/networkmanager-0.7.1 net-misc/networkmanager[gnome] )
+		)
+	srv? (
+		|| (
+			dev-python/libasyncns-python
+			net-dns/bind-tools )
+		)
+	spell? ( app-text/gtkspell )
+	xhtml? ( dev-python/docutils )"
+
+pkg_setup() {
+	if ! use dbus; then
+		if use libnotify; then
+			eerror "The dbus USE flag is required for libnotify support"
+			die "USE=\"dbus\" needed for libnotify support"
+		fi
+		if use avahi; then
+			eerror "The dbus USE flag is required for avahi support"
+			die "USE=\"dbus\" needed for avahi support"
+		fi
+	fi
+	python_pkg_setup
+	python_set_active_version 2
+}
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/0.14-python-version.patch \
+		"${FILESDIR}"/0.14.1-testing.patch
+	echo '#!/bin/sh' > config/py-compile
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_with X x) \
+		--docdir="/usr/share/doc/${PF}" \
+		--libdir="$(python_get_sitedir)" \
+		--enable-site-packages
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	rm "${D}/usr/share/doc/${PF}/"{README.html,COPYING} || die
+	dohtml README.html || die
+}
+
+pkg_postinst() {
+	python_mod_optimize $(python_get_sitedir)/${PN}
+}
+
+pkg_postrm() {
+	python_mod_cleanup $(python_get_sitedir)/${PN}
+}
diff --git a/net-im/gajim/metadata.xml b/net-im/gajim/metadata.xml
index 11a05b2ee3d1..1ad01b863a1f 100644
--- a/net-im/gajim/metadata.xml
+++ b/net-im/gajim/metadata.xml
@@ -1,18 +1,18 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-  <herd>net-im</herd>
-<maintainer>
-	<email>jlec@gentoo.org</email>
-</maintainer>
-  <longdescription>
+	<herd>net-im</herd>
+	<maintainer>
+		<email>jlec@gentoo.org</email>
+	</maintainer>
+	<longdescription>
     A fully featured and easy to use GTK+ Jabber client written in PyGTK.
   </longdescription>
-  <use>
-	  <flag name='gmail'>Depend on net-dns/bind-tools to get gmail chats working</flag>
-	  <flag name='idle'>Enable idle module</flag>
-	  <flag name='srv'>SRV capabilities</flag>
-	  <flag name='trayicon'>Enable support for trayicon</flag>
-	  <flag name='xhtml'>Enable XHTML support</flag>
-  </use>
+	<use>
+		<flag name="gmail">Depend on net-dns/bind-tools to get gmail chats working</flag>
+		<flag name="idle">Enable idle module</flag>
+		<flag name="srv">SRV capabilities</flag>
+		<flag name="trayicon">Enable support for trayicon</flag>
+		<flag name="xhtml">Enable XHTML support</flag>
+	</use>
 </pkgmetadata>