Version bump. Pull in a patch from upstream to fix contact list problems.

(Portage version: 2.1.3.19)

6 files changed, 146 insertions, 3 deletions

diff --git a/net-im/centerim/ChangeLog b/net-im/centerim/ChangeLog
index 678bff66b45f..6514d352435d 100644
--- a/net-im/centerim/ChangeLog
+++ b/net-im/centerim/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-im/centerim
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/ChangeLog,v 1.6 2007/11/03 09:33:10 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/ChangeLog,v 1.7 2007/11/28 20:08:06 swegener Exp $
+
+*centerim-4.22.1_p20071103 (28 Nov 2007)
+
+  28 Nov 2007; Sven Wegener <swegener@gentoo.org>
+  +files/centerim-ack-sbl.patch, centerim-4.22.1_p20071003.ebuild,
+  centerim-4.22.1_p20071022.ebuild, +centerim-4.22.1_p20071103.ebuild:
+  Version bump. Pull in a patch from upstream to fix contact list problems.
 
   03 Nov 2007; Sven Wegener <swegener@gentoo.org>
   centerim-4.22.1_p20071003.ebuild, centerim-4.22.1_p20071022.ebuild:
diff --git a/net-im/centerim/centerim-4.22.1_p20071003.ebuild b/net-im/centerim/centerim-4.22.1_p20071003.ebuild
index a5a7c6f9b106..e476d4e59bb5 100644
--- a/net-im/centerim/centerim-4.22.1_p20071003.ebuild
+++ b/net-im/centerim/centerim-4.22.1_p20071003.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/centerim-4.22.1_p20071003.ebuild,v 1.4 2007/11/03 09:33:10 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/centerim-4.22.1_p20071003.ebuild,v 1.5 2007/11/28 20:08:06 swegener Exp $
 
 inherit eutils
 
@@ -79,6 +79,7 @@ src_unpack() {
 	cd "${S}"
 
 	epatch "${FILESDIR}"/${PN}-imotr-config.patch
+	epatch "${FILESDIR}"/${PN}-ack-sbl.patch
 }
 
 src_compile() {
diff --git a/net-im/centerim/centerim-4.22.1_p20071022.ebuild b/net-im/centerim/centerim-4.22.1_p20071022.ebuild
index 3e6c30b3bc61..24f7f6f20ff2 100644
--- a/net-im/centerim/centerim-4.22.1_p20071022.ebuild
+++ b/net-im/centerim/centerim-4.22.1_p20071022.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/centerim-4.22.1_p20071022.ebuild,v 1.3 2007/11/03 09:33:10 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/centerim-4.22.1_p20071022.ebuild,v 1.4 2007/11/28 20:08:06 swegener Exp $
 
 inherit eutils
 
@@ -79,6 +79,7 @@ src_unpack() {
 	cd "${S}"
 
 	epatch "${FILESDIR}"/${PN}-imotr-config.patch
+	epatch "${FILESDIR}"/${PN}-ack-sbl.patch
 }
 
 src_compile() {
diff --git a/net-im/centerim/centerim-4.22.1_p20071103.ebuild b/net-im/centerim/centerim-4.22.1_p20071103.ebuild
new file mode 100644
index 000000000000..13e192277920
--- /dev/null
+++ b/net-im/centerim/centerim-4.22.1_p20071103.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/centerim/centerim-4.22.1_p20071103.ebuild,v 1.1 2007/11/28 20:08:06 swegener Exp $
+
+inherit eutils
+
+PROTOCOL_IUSE="aim gadu icq irc jabber lj msn rss yahoo"
+IUSE="${PROTOCOL_IUSE} bidi nls ssl crypt jpeg otr"
+
+DESCRIPTION="CenterIM is a fork of CenterICQ - a ncurses ICQ/Yahoo!/AIM/IRC/MSN/Jabber/GaduGadu/RSS/LiveJournal Client"
+if [[ ${PV} = *_p* ]] # is this a snaphot?
+then
+	SRC_URI="http://www.centerim.org/download/snapshots/${PN}-${PV/*_p/}.tar.gz"
+else
+	SRC_URI="http://www.centerim.org/download/releases/${P}.tar.gz"
+fi
+HOMEPAGE="http://www.centerim.org/"
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~x86 ~amd64"
+
+DEPEND=">=sys-libs/ncurses-5.2
+	bidi? ( dev-libs/fribidi )
+	ssl? ( >=dev-libs/openssl-0.9.6g )
+	jpeg? ( media-libs/jpeg )
+	otr? ( net-libs/libotr )
+	jabber? ( crypt? ( >=app-crypt/gpgme-1.0.2 ) )
+	msn? (
+		net-misc/curl
+		dev-libs/openssl
+	)"
+
+RDEPEND="${DEPEND}
+	nls? ( sys-devel/gettext )"
+
+S="${WORKDIR}"/${P/_p*}
+
+check_protocol_iuse() {
+	local flag
+
+	for flag in ${PROTOCOL_IUSE}
+	do
+		use ${flag} && return 0
+	done
+
+	return 1
+}
+
+pkg_setup() {
+	if ! check_protocol_iuse
+	then
+		eerror
+		eerror "Please activate at least one of the following protocol USE flags:"
+		eerror "${PROTOCOL_IUSE}"
+		eerror
+		die "Please activate at least one protocol USE flag!"
+	fi
+
+	if use msn && ! built_with_use net-misc/curl ssl
+	then
+		eerror
+		eerror "As of right now, the msn use flags requires curl to be built"
+		eerror "with SSL support. Make sure ssl is in your USE flags and"
+		eerror "re-emerge net-misc/curl."
+		eerror
+		die "net-misc/curl dependencie issue"
+	fi
+
+	if use gadu && ! use jpeg
+	then
+		ewarn
+		ewarn "You need jpeg support to be able to register Gadu-Gadu accounts!"
+		ewarn
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${PN}-imotr-config.patch
+	epatch "${FILESDIR}"/${PN}-ack-sbl.patch
+}
+
+src_compile() {
+	econf \
+		$(use_with ssl) \
+		$(use_enable aim) \
+		$(use_with bidi fribidi) \
+		$(use_with jpeg libjpeg) \
+		$(use_with otr libotr) \
+		$(use_enable gadu gg) \
+		$(use_enable icq) \
+		$(use_enable irc) \
+		$(use_enable jabber) \
+		$(use_enable lj) \
+		$(use_enable msn) \
+		$(use_enable nls locales-fix) \
+		$(use_enable nls) \
+		$(use_enable rss) \
+		$(use_enable yahoo) \
+		|| die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	dodoc AUTHORS ChangeLog FAQ README THANKS TODO
+}
diff --git a/net-im/centerim/files/centerim-ack-sbl.patch b/net-im/centerim/files/centerim-ack-sbl.patch
new file mode 100644
index 000000000000..55669e153587
--- /dev/null
+++ b/net-im/centerim/files/centerim-ack-sbl.patch
@@ -0,0 +1,21 @@
+From: Roger <roger@jikos.cz>
+Date: Sun, 25 Nov 2007 18:18:07 +0000 (+0100)
+Subject: Bug #39: Ack SBL to get status notifications
+X-Git-Url: http://repo.or.cz/w/centerim.git?a=commitdiff_plain;h=152235ac92c0c1c9a26ccb05e43c423b4ed64783
+
+Bug #39: Ack SBL to get status notifications
+---
+
+diff --git a/libicq2000/src/Client.cpp b/libicq2000/src/Client.cpp
+index 3bb4d36..8e453c8 100644
+--- a/libicq2000/src/Client.cpp
++++ b/libicq2000/src/Client.cpp
+@@ -1524,7 +1524,7 @@ namespace ICQ2000
+ 	SignalLog(LogEvent::INFO, "Received server-based list from server\n");
+ 	SBLListSNAC *sbs = static_cast<SBLListSNAC*>(snac);
+ 	mergeSBL( sbs->getContactTree() );
+-//        SendSBLReceivedACK();
++        SendSBLReceivedACK();
+ 	break;
+       }
+       
diff --git a/net-im/centerim/files/digest-centerim-4.22.1_p20071103 b/net-im/centerim/files/digest-centerim-4.22.1_p20071103
new file mode 100644
index 000000000000..2f8d1a409709
--- /dev/null
+++ b/net-im/centerim/files/digest-centerim-4.22.1_p20071103
@@ -0,0 +1,3 @@
+MD5 5679cce67ac21f2fa2411f258e608054 centerim-20071103.tar.gz 2612329
+RMD160 db403c5747d5cd1a34295044ec048030e82fc6cb centerim-20071103.tar.gz 2612329
+SHA256 c8417b5ecd46c66cfcd16df117c402bd72c55aa117f025866e3d41743972b014 centerim-20071103.tar.gz 2612329