Don't use deprecated opts, bug 385639 thank Martin von Gagern for report and Dustin Polke for fix.

(Portage version: 2.1.10.20/cvs/Linux x86_64)

5 files changed, 230 insertions, 5 deletions

diff --git a/net-fs/autofs/ChangeLog b/net-fs/autofs/ChangeLog
index 0d00cc6bd7ca..16e28fb487c8 100644
--- a/net-fs/autofs/ChangeLog
+++ b/net-fs/autofs/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for net-fs/autofs
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/ChangeLog,v 1.129 2011/09/21 15:49:56 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/ChangeLog,v 1.130 2011/10/05 14:27:26 pva Exp $
+
+*autofs-5.0.6-r3 (05 Oct 2011)
+*autofs-4.1.4-r1 (05 Oct 2011)
+
+  05 Oct 2011; Peter Volkov <pva@gentoo.org> +autofs-4.1.4-r1.ebuild,
+  files/autofs5.initd, files/autofs-4.1.4-init.patch, +autofs-5.0.6-r3.ebuild:
+  Don't use deprecated opts, bug 385639 thank Martin von Gagern for report and
+  Dustin Polke for fix.
 
   21 Sep 2011; Peter Volkov <pva@gentoo.org> autofs-5.0.5-r4.ebuild,
   autofs-5.0.6-r2.ebuild:
diff --git a/net-fs/autofs/autofs-4.1.4-r1.ebuild b/net-fs/autofs/autofs-4.1.4-r1.ebuild
new file mode 100644
index 000000000000..901385edd80c
--- /dev/null
+++ b/net-fs/autofs/autofs-4.1.4-r1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/autofs-4.1.4-r1.ebuild,v 1.1 2011/10/05 14:27:26 pva Exp $
+
+EAPI="4"
+
+inherit eutils multilib autotools
+
+PATCH_VER="1"
+DESCRIPTION="Kernel based automounter"
+HOMEPAGE="http://www.linux-consulting.com/Amd_AutoFS/autofs.html"
+SRC_URI="mirror://kernel/linux/daemons/${PN}/v4/${P}.tar.bz2
+	mirror://gentoo/${P}-patches-${PATCH_VER}.tar.lzma"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="hesiod ldap"
+
+DEPEND="hesiod? ( net-dns/hesiod )
+	ldap? ( >=net-nds/openldap-2.0 )"
+RDEPEND="${DEPEND}"
+
+UPSTREAM_FILESDIR="gentoo/${CATEGORY}/${PN}/files"
+
+src_prepare() {
+	EPATCH_SUFFIX="patch" \
+		epatch "${WORKDIR}"/patches
+
+	# Accumulated fixes for bugs
+	#    #154797: Respect CC and CFLAGS
+	#    #253412: Respect LDFLAGS
+	#    #247969: Link order for --as-needed
+	epatch "${FILESDIR}"/${P}-respect-user-flags-and-fix-asneeded.patch
+
+	# Reflect init script implementation
+	epatch "${FILESDIR}"/${P}-fix-man-pages.patch
+
+	# Use Gentoo specific maps, init script and config file
+	for i in home master misc; do
+		if [ -e samples/auto.${i} ]; then
+			mv samples/auto.${i}{,.bak} || die "Failed to backup auto.${i}"
+		fi
+		ln -s "${S}/${UPSTREAM_FILESDIR}"/auto.${i} samples/auto.${i} || \
+			die "Failed to symlink auto.${i}"
+	done
+
+	# Clean-up maps and disable everything.
+	epatch "${FILESDIR}"/${P}-clean-up-maps.patch
+
+	# Fix installation path of ldap samples and maps
+	epatch "${FILESDIR}"/${P}-fix-install-ldap-samples-and-maps.patch
+
+	epatch "${FILESDIR}"/${P}-init.patch #Fix init script deps
+
+	# Do not include <nfs/nfs.h>, rather <linux/nfs.h>,
+	# as the former is a lame header for the latter (bug #157968)
+	sed 's@nfs/nfs.h@linux/nfs.h@' -i lib/rpc_subs.c || die
+
+	eautoreconf
+}
+
+src_configure() {
+	# work around bug #355975 (mount modifies timestamp of /etc/mtab)
+	# with >=sys-apps/util-linux-2.19,
+	addpredict "/etc/mtab"
+
+	econf \
+		$(use_with ldap openldap) \
+		$(use_with hesiod)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc README* CHANGELOG CREDITS COPYRIGHT
+
+	newinitd ${UPSTREAM_FILESDIR}/${PN}.init ${PN}
+	newconfd ${UPSTREAM_FILESDIR}/${PN}.conf ${PN}
+}
+
+pkg_postinst() {
+	elog "If you plan on using autofs for automounting remote NFS mounts,"
+	elog "please check that both portmap (or rpcbind) and rpc.statd/lockd"
+	elog "are running."
+	elog
+	elog "Also the normal autofs status has been renamed stats"
+	elog "as there is already a predefined Gentoo status"
+	if use ldap; then
+		elog
+		elog "Sample files for ldap have been installed into"
+		elog "${PREFIX}/usr/share/share/doc/${P}/samples."
+	fi
+}
diff --git a/net-fs/autofs/autofs-5.0.6-r3.ebuild b/net-fs/autofs/autofs-5.0.6-r3.ebuild
new file mode 100644
index 000000000000..955fee22ac2d
--- /dev/null
+++ b/net-fs/autofs/autofs-5.0.6-r3.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/autofs-5.0.6-r3.ebuild,v 1.1 2011/10/05 14:27:26 pva Exp $
+
+EAPI="4"
+inherit eutils multilib autotools linux-info
+
+DESCRIPTION="Kernel based automounter"
+HOMEPAGE="http://www.linux-consulting.com/Amd_AutoFS/autofs.html"
+PATCH_VER=""
+[[ -n ${PATCH_VER} ]] && \
+	PATCHSET_URI="mirror://gentoo/${P}-patches-${PATCH_VER}.tar.lzma"
+SRC_URI="mirror://kernel/linux/daemons/${PN}/v5/${P}.tar.bz2
+	${PATCHSET_URI}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="hesiod ldap sasl"
+
+# USE="sasl" adds SASL support to the LDAP module which will not be build. If
+# SASL support should be available, please add "ldap" to the USE flags.
+REQUIRED_USE="sasl? ( ldap )"
+
+# currently, sasl code assumes the presence of kerberosV
+RDEPEND="
+	hesiod? ( net-dns/hesiod )
+	ldap? ( >=net-nds/openldap-2.0
+		sasl? ( dev-libs/cyrus-sasl
+			dev-libs/libxml2
+			virtual/krb5 ) )"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	virtual/yacc"
+
+src_prepare() {
+	# Upstream's patchset
+	if [[ -n ${PATCH_VER} ]]; then
+		EPATCH_SUFFIX="patch" \
+			epatch "${WORKDIR}"/patches
+	fi
+
+	# Fix for bug #210762
+	# Upstream reference: http://thread.gmane.org/gmane.linux.kernel.autofs/4203
+	epatch "${FILESDIR}"/${PN}-5.0.3-heimdal.patch
+
+	# Accumulated fixes for bugs
+	#    #154797: Respect CC and CFLAGS
+	#    #253412: Respect LDFLAGS
+	#    #247969: Link order for --as-needed
+	epatch "${FILESDIR}"/${P}-respect-user-flags-and-fix-asneeded.patch
+
+	# do not include <nfs/nfs.h>, rather <linux/nfs.h>,
+	# as the former is a lame header for the latter (bug #157968)
+	sed 's@nfs/nfs.h@linux/nfs.h@' -i include/rpc_subs.h || die
+
+	# Upstream reference: http://thread.gmane.org/gmane.linux.kernel.autofs/5371
+	epatch "${FILESDIR}"/${PN}-5.0.5-fix-install-deadlink.patch
+
+	# Upstream reference: http://thread.gmane.org/gmane.linux.kernel.autofs/6039
+	# Disable LDAP specific code if USE="-ldap", let's see what upstream says...
+	epatch "${FILESDIR}"/${PN}-5.0.5-fix-building-without-ldap.patch
+
+	# https://bugs.gentoo.org/show_bug.cgi?id=361899
+	epatch "${FILESDIR}"/${PN}-5.0.5-add-missing-endif-HAVE_SASL-in-modules-lookup_ldap.c.patch
+
+	# Fix for bug #373577
+	# Upstream reference: http://article.gmane.org/gmane.linux.kernel.autofs/6187
+	# Fix regression in IPv6 name lookup regression
+	epatch "${FILESDIR}"/${P}-ipv6_name_lookup_regression.patch
+
+	# https://bugs.gentoo.org/show_bug.cgi?id=381315
+	epatch "${FILESDIR}"/${P}-revert-ldap.patch
+	eautoreconf
+}
+
+src_configure() {
+	# work around bug #355975 (mount modifies timestamp of /etc/mtab)
+	# with >=sys-apps/util-linux-2.19,
+	addpredict "/etc/mtab"
+
+	# --with-confdir is for bug #361481
+	econf \
+		--with-confdir=/etc/conf.d \
+		$(use_with ldap openldap) \
+		$(use_with sasl) \
+		$(use_with hesiod) \
+		--enable-ignore-busy
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc README* CHANGELOG CREDITS COPYRIGHT INSTALL
+
+	# kernel patches
+	docinto patches
+	dodoc patches/${PN}4-2.6.??{,.?{,?}}-v5-update-????????.patch
+
+	newinitd "${FILESDIR}"/autofs5.initd autofs
+	insinto etc/autofs
+	newins "${FILESDIR}"/autofs5-auto.master auto.master
+}
+
+pkg_postinst() {
+	if kernel_is -lt 2 6 30; then
+		elog "This version of ${PN} requires a kernel with autofs4 supporting"
+		elog "protocol version 5.00. Patches for kernels older than 2.6.30 have"
+		elog "been installed into"
+		elog "${EROOT}usr/share/doc/${P}/patches."
+		elog "For further instructions how to patch the kernel, please refer to"
+		elog "${EROOT}usr/share/doc/${P}/INSTALL."
+		elog
+	fi
+	elog "If you plan on using autofs for automounting remote NFS mounts,"
+	elog "please check that both portmap (or rpcbind) and rpc.statd/lockd"
+	elog "are running."
+}
diff --git a/net-fs/autofs/files/autofs-4.1.4-init.patch b/net-fs/autofs/files/autofs-4.1.4-init.patch
index d7ec75164094..cdb66e73ef21 100644
--- a/net-fs/autofs/files/autofs-4.1.4-init.patch
+++ b/net-fs/autofs/files/autofs-4.1.4-init.patch
@@ -1,6 +1,6 @@
 --- gentoo/net-fs/autofs/files/autofs.init.orig
 +++ gentoo/net-fs/autofs/files/autofs.init
-@@ -11,8 +11,8 @@ DAEMON=/usr/sbin/automount
+@@ -11,11 +11,12 @@ DAEMON=/usr/sbin/automount
  SYSCONFDIR=/etc/autofs
  
  depend() {
@@ -10,4 +10,9 @@
 +	use ypbind nfs slapd portmap net
  }
  
- opts="start stop status stats reload restart"
+-opts="start stop status stats reload restart"
++extra_commands="stats"
++extra_started_commands="reload"
+ 
+ #
+ # Check for all maps that are to be loaded
diff --git a/net-fs/autofs/files/autofs5.initd b/net-fs/autofs/files/autofs5.initd
index 73857bc5d8b9..bd3f14f0bdb4 100644
--- a/net-fs/autofs/files/autofs5.initd
+++ b/net-fs/autofs/files/autofs5.initd
@@ -1,7 +1,7 @@
 #!/sbin/runscript
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/files/autofs5.initd,v 1.2 2011/04/03 17:55:17 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/files/autofs5.initd,v 1.3 2011/10/05 14:27:26 pva Exp $
 
 DAEMON=/usr/sbin/automount
 PIDFILE=/var/run/autofs.pid
@@ -12,7 +12,7 @@ depend() {
 	use ypbind nfs slapd portmap net
 }
 
-opts="start stop restart status reload"
+extra_started_commands="reload"
 
 start() {
 	ebegin "Starting automounter"