Version bump to 1.4.0. Add live version. Thanks to Ondrej Caletka for the ebuilds.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 8EEE3BE8)

3 files changed, 77 insertions, 10 deletions

diff --git a/net-dns/knot/ChangeLog b/net-dns/knot/ChangeLog
index 237238e5adf3..10a06de50b6b 100644
--- a/net-dns/knot/ChangeLog
+++ b/net-dns/knot/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for net-dns/knot
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/knot/ChangeLog,v 1.20 2013/08/21 09:23:59 scarabeus Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-dns/knot/ChangeLog,v 1.21 2014/01/09 18:04:02 scarabeus Exp $
+
+*knot-9999 (09 Jan 2014)
+*knot-1.4.0 (09 Jan 2014)
+
+  09 Jan 2014; Tomáš Chvátal <scarabeus@gentoo.org> +knot-1.4.0.ebuild,
+  +knot-9999.ebuild, -knot-1.3.0-r1.ebuild:
+  Version bump to 1.4.0. Add live version. Thanks to Ondrej Caletka for the
+  ebuilds.
 
 *knot-1.3.0-r1 (21 Aug 2013)
 
diff --git a/net-dns/knot/knot-1.4.0.ebuild b/net-dns/knot/knot-1.4.0.ebuild
new file mode 100644
index 000000000000..14297a3fe347
--- /dev/null
+++ b/net-dns/knot/knot-1.4.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-dns/knot/knot-1.4.0.ebuild,v 1.1 2014/01/09 18:04:02 scarabeus Exp $
+
+EAPI=5
+
+EGIT_REPO_URI="https://gitlab.labs.nic.cz/labs/${PN}.git"
+[[ ${PV} == 9999 ]] && inherit autotools git-r3
+inherit eutils user
+
+DESCRIPTION="High-performance authoritative-only DNS server"
+HOMEPAGE="http://www.knot-dns.cz/"
+[[ ${PV} == 9999 ]] || SRC_URI="http://public.nic.cz/files/knot-dns/${P/_/-}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~x86"
+IUSE="debug caps +fastparser"
+
+RDEPEND="
+	dev-libs/openssl
+	dev-libs/userspace-rcu
+	caps? ( sys-libs/libcap-ng )
+"
+#	sys-libs/glibc
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/flex
+	virtual/yacc
+	fastparser? ( dev-util/ragel )
+"
+
+S="${WORKDIR}/${P/_/-}"
+
+src_prepare() {
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-storage="${EPREFIX}/var/lib/${PN}" \
+		--with-rundir="${EPREFIX}/var/run/${PN}" \
+		--disable-lto \
+		--enable-recvmmsg \
+		$(use_enable fastparser) \
+		$(use_enable debug debug server,zones,xfr,packet,dname,rr,ns,hash,compiler) \
+		$(use_enable debug debuglevel details)
+}
+
+src_install() {
+	default
+	newinitd "${FILESDIR}/knot.init" knot
+}
+
+pkg_postinst() {
+	enewgroup knot 53
+	enewuser knot 53 -1 /var/lib/knot knot
+}
diff --git a/net-dns/knot/knot-1.3.0-r1.ebuild b/net-dns/knot/knot-9999.ebuild
index 3df494d0bcf3..d58e1dc8f123 100644
--- a/net-dns/knot/knot-1.3.0-r1.ebuild
+++ b/net-dns/knot/knot-9999.ebuild
@@ -1,17 +1,20 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/knot/knot-1.3.0-r1.ebuild,v 1.1 2013/08/21 09:23:59 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/knot/knot-9999.ebuild,v 1.1 2014/01/09 18:04:02 scarabeus Exp $
 
 EAPI=5
 
-inherit eutils autotools user
+EGIT_REPO_URI="https://gitlab.labs.nic.cz/labs/${PN}.git"
+[[ ${PV} == 9999 ]] && inherit autotools git-r3
+inherit eutils user
 
 DESCRIPTION="High-performance authoritative-only DNS server"
 HOMEPAGE="http://www.knot-dns.cz/"
-SRC_URI="http://public.nic.cz/files/knot-dns/${P/_/-}.tar.gz"
+[[ ${PV} == 9999 ]] || SRC_URI="http://public.nic.cz/files/knot-dns/${P/_/-}.tar.gz"
 
 LICENSE="GPL-3"
 SLOT="0"
+[[ ${PV} == 9999 ]] || \
 KEYWORDS="~amd64 ~x86"
 IUSE="debug caps +fastparser"
 
@@ -31,10 +34,7 @@ DEPEND="${RDEPEND}
 S="${WORKDIR}/${P/_/-}"
 
 src_prepare() {
-	sed -i \
-		-e 's:-Werror::g' \
-		configure.ac || die
-	eautoreconf
+	[[ ${PV} == 9999 ]] && eautoreconf
 }
 
 src_configure() {