Initial import, bug #223103.

(Portage version: 2.1.7.5/cvs/Linux x86_64)

5 files changed, 149 insertions, 0 deletions

diff --git a/net-dns/unbound/ChangeLog b/net-dns/unbound/ChangeLog
new file mode 100644
index 000000000000..10147aede013
--- /dev/null
+++ b/net-dns/unbound/ChangeLog
@@ -0,0 +1,10 @@
+# ChangeLog for net-dns/unbound
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v 1.1 2009/11/22 16:57:33 matsuu Exp $
+
+*unbound-1.3.4 (22 Nov 2009)
+
+  22 Nov 2009; MATSUU Takuto <matsuu@gentoo.org> +unbound-1.3.4.ebuild,
+  +files/unbound.confd, +files/unbound.initd, +metadata.xml:
+  Initial import, bug #223103.
+
diff --git a/net-dns/unbound/files/unbound.confd b/net-dns/unbound/files/unbound.confd
new file mode 100644
index 000000000000..b4de7cf1142e
--- /dev/null
+++ b/net-dns/unbound/files/unbound.confd
@@ -0,0 +1,4 @@
+# Settings should normally not need any changes.
+
+# Location of the unbound configuration file. Leave empty for the default.
+#UNBOUND_CONFFILE="/etc/unbound/unbound.conf"
diff --git a/net-dns/unbound/files/unbound.initd b/net-dns/unbound/files/unbound.initd
new file mode 100644
index 000000000000..e9e902c9b9cb
--- /dev/null
+++ b/net-dns/unbound/files/unbound.initd
@@ -0,0 +1,51 @@
+#!/sbin/runscript
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/files/unbound.initd,v 1.1 2009/11/22 16:57:33 matsuu Exp $
+
+opts="${opts} checkconfig reload"
+
+UNBOUND_BINARY=${UNBOUND_BINARY:-/usr/sbin/unbound}
+UNBOUND_CHECKCONF=${UNBOUND_CHECKCONF:-/usr/sbin/unbound-checkconf}
+UNBOUND_CONFFILE=${UNBOUND_CONFFILE:-/etc/unbound/${SVCNAME}.conf}
+
+depend() {
+	need net
+	use logger
+	provide dns
+	after auth-dns
+}
+
+checkconfig() {
+	UNBOUND_PIDFILE=$("${UNBOUND_CHECKCONF}" -o pidfile "${UNBOUND_CONFFILE}")
+	return $?
+}
+
+start() {
+	checkconfig || return $?
+	ebegin "Starting unbound"
+	start-stop-daemon --start --pidfile "${UNBOUND_PIDFILE}" \
+		--exec "${UNBOUND_BINARY}" -- -c "${UNBOUND_CONFFILE}"
+	eend $?
+}
+
+stop() {
+	checkconfig || return $?
+	ebegin "Stopping unbound"
+	start-stop-daemon --stop --pidfile "${UNBOUND_PIDFILE}"
+	eend $?
+}
+
+restart() {
+	checkconfig || return $?
+	svc_stop
+	svc_start
+}
+
+reload() {
+	checkconfig || return $?
+	ebegin "Reloading unbound"
+	start-stop-daemon --stop --pidfile "${UNBOUND_PIDFILE}" \
+		--signal HUP --oknodo
+	eend $?
+}
diff --git a/net-dns/unbound/metadata.xml b/net-dns/unbound/metadata.xml
new file mode 100644
index 000000000000..5af5dbc4dc5a
--- /dev/null
+++ b/net-dns/unbound/metadata.xml
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>no-herd</herd>
+<maintainer>
+<email>matsuu@gentoo.org</email>
+</maintainer>
+<longdescription lang="en">
+Unbound is a validating, recursive, and caching DNS resolver.
+
+The C implementation of Unbound is developed and maintained by NLnet
+Labs. It is based on ideas and algorithms taken from a java prototype
+developed by Verisign labs, Nominet, Kirei and ep.net.
+
+Unbound is designed as a set of modular components, so that also
+DNSSEC (secure DNS) validation and stub-resolvers (that do not run
+as a server, but are linked into an application) are easily possible.
+</longdescription>
+<use>
+  <flag name='libevent'>Use <pkg>dev-libs/libevent</pkg> instead of internal
+  select based events</flag>
+</use>
+</pkgmetadata>
diff --git a/net-dns/unbound/unbound-1.3.4.ebuild b/net-dns/unbound/unbound-1.3.4.ebuild
new file mode 100644
index 000000000000..88317b3fed67
--- /dev/null
+++ b/net-dns/unbound/unbound-1.3.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/unbound-1.3.4.ebuild,v 1.1 2009/11/22 16:57:33 matsuu Exp $
+
+EAPI="2"
+
+inherit autotools eutils multilib
+
+DESCRIPTION="A validating, recursive and caching DNS resolver"
+HOMEPAGE="http://unbound.net/"
+SRC_URI="http://unbound.net/downloads/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug libevent python static test threads"
+
+RDEPEND=">=dev-libs/openssl-0.9.7
+	>=net-libs/ldns-1.4
+	libevent? ( dev-libs/libevent )"
+DEPEND="${RDEPEND}
+	python? ( dev-lang/swig )
+	test? (
+		net-dns/ldns-utils[examples]
+		dev-util/splint
+	)"
+
+pkg_setup() {
+	enewgroup unbound
+	enewuser unbound -1 -1 /etc/unbound unbound
+}
+
+src_prepare() {
+	sed -i -e "s:\(withval\|thedir\)/lib:\1/$(get_libdir):" configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-pidfile=/var/run/unbound.pid \
+		--with-ldns=/usr \
+		$(use_enable debug) \
+		$(use_enable debug lock-checks) \
+		$(use_enable debug alloc-checks) \
+		$(use_enable static static-exe) \
+		$(use_with libevent) \
+		$(use_with threads pthreads) \
+		$(use_with python pyunbound) \
+		$(use_with python pythonmodule) || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	newinitd "${FILESDIR}/unbound.initd" unbound || die "newinitd failed"
+	newconfd "${FILESDIR}/unbound.confd" unbound || die "newconfd failed"
+
+	dodoc doc/{README,CREDITS,TODO,Changelog,FEATURES} || die "dodoc failed"
+
+	exeinto /usr/share/${PN}
+	doexe contrib/{update-anchor.sh,update-itar.sh} || die "doexe failed"
+}