Add pre release for the 0.7.5 series; ebuild completely rewritten, now the buildsystem is based on cmake.

(Portage version: 2.1.11.9/cvs/Linux x86_64)

3 files changed, 63 insertions, 1 deletions

diff --git a/net-analyzer/ettercap/ChangeLog b/net-analyzer/ettercap/ChangeLog
index 68f776c2210f..b6fd87af46e6 100644
--- a/net-analyzer/ettercap/ChangeLog
+++ b/net-analyzer/ettercap/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-analyzer/ettercap
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/ettercap/ChangeLog,v 1.92 2012/08/24 19:05:02 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/ettercap/ChangeLog,v 1.93 2012/09/03 15:56:21 ago Exp $
+
+*ettercap-0.7.5_pre20120903 (03 Sep 2012)
+
+  03 Sep 2012; Agostino Sarubbo <ago@gentoo.org>
+  +ettercap-0.7.5_pre20120903.ebuild, metadata.xml:
+  Add pre release for the 0.7.5 series; ebuild completely rewritten, now the
+  buildsystem is based on cmake.
 
   24 Aug 2012; Agostino Sarubbo <ago@gentoo.org> metadata.xml:
   Add myself as maintainer
diff --git a/net-analyzer/ettercap/ettercap-0.7.5_pre20120903.ebuild b/net-analyzer/ettercap/ettercap-0.7.5_pre20120903.ebuild
new file mode 100644
index 000000000000..7c4f37461f3a
--- /dev/null
+++ b/net-analyzer/ettercap/ettercap-0.7.5_pre20120903.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/ettercap/ettercap-0.7.5_pre20120903.ebuild,v 1.1 2012/09/03 15:56:21 ago Exp $
+
+EAPI=4
+
+inherit cmake-utils
+
+DESCRIPTION="A suite for man in the middle attacks and network mapping"
+HOMEPAGE="http://ettercap.sourceforge.net/"
+SRC_URI="http://dev.gentoo.org/~ago/distfiles/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="gtk ipv6 ncurses plugins ssl"
+
+RDEPEND="dev-libs/libpcre
+	net-libs/libnet:1.1
+	net-libs/libpcap
+	sys-libs/zlib
+	gtk? (
+		dev-libs/atk
+		dev-libs/glib:2
+		media-libs/freetype
+		x11-libs/cairo
+		x11-libs/gdk-pixbuf:2
+		x11-libs/gtk+:2
+		x11-libs/pango
+	)
+	ncurses? ( sys-libs/ncurses )
+	plugins? ( >=net-misc/curl-7.26.0 )
+	ssl? ( dev-libs/openssl )"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	virtual/yacc"
+
+src_prepare() {
+	#ettercap defaults to using mozilla so let's try to use xdg-open and pray it works
+	sed -i 's#mozilla -remote openurl(http://%host%url)#xdg-open 'http://%host%url'#' "${S}"/share/etter.conf || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_enable ncurses CURSES)
+		$(cmake-utils_use_enable gtk)
+		$(cmake-utils_use_enable ssl)
+		$(cmake-utils_use_enable plugins)
+		$(cmake-utils_use_enable ipv6)
+	)
+	cmake-utils_src_configure
+}
diff --git a/net-analyzer/ettercap/metadata.xml b/net-analyzer/ettercap/metadata.xml
index 3a7b6f1aa366..4b9b95b48923 100644
--- a/net-analyzer/ettercap/metadata.xml
+++ b/net-analyzer/ettercap/metadata.xml
@@ -10,4 +10,7 @@
 		<email>ago@gentoo.org</email>
 		<name>Agostino Sarubbo</name>
 	</maintainer>
+	<use>
+		<flag name="plugins">Install ettercap plugins (et_*.so)</flag>
+	</use>
 </pkgmetadata>