Version bump. Clean up patch.

(Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key A792A613)

1 files changed, 40 insertions, 0 deletions

diff --git a/net-analyzer/iftop/iftop-1.0_pre3.ebuild b/net-analyzer/iftop/iftop-1.0_pre3.ebuild
new file mode 100644
index 000000000000..24dc37489265
--- /dev/null
+++ b/net-analyzer/iftop/iftop-1.0_pre3.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/iftop/iftop-1.0_pre3.ebuild,v 1.1 2014/01/08 03:22:37 jer Exp $
+
+EAPI=5
+
+inherit autotools eutils
+
+DESCRIPTION="display bandwidth usage on an interface"
+SRC_URI="http://www.ex-parrot.com/~pdw/iftop/download/${P/_/}.tar.gz"
+HOMEPAGE="http://www.ex-parrot.com/~pdw/iftop/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE=""
+
+DEPEND="
+	net-libs/libpcap
+	sys-libs/ncurses"
+
+S="${WORKDIR}"/${P/_/}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.0_pre3-tinfo.patch
+	sed -i 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/g' configure.in || die
+
+	# bug 490168
+	cat "${FILESDIR}"/ax_pthread.m4 >> "${S}"/acinclude.m4 || die
+	epatch "${FILESDIR}"/${PN}-1.0_pre2-pthread.patch
+
+	eautoreconf
+}
+
+src_install() {
+	dosbin iftop
+	doman iftop.8
+
+	dodoc AUTHORS ChangeLog README "${FILESDIR}"/iftoprc
+}