Version bump, wrt bug #445212.

(Portage version: 2.1.11.33/cvs/Linux x86_64, signed Manifest commit with key 675D0D2C)

2 files changed, 91 insertions, 1 deletions

diff --git a/media-video/smplayer/ChangeLog b/media-video/smplayer/ChangeLog
index 44f22491f7bf..2e05aa8c79be 100644
--- a/media-video/smplayer/ChangeLog
+++ b/media-video/smplayer/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/smplayer
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.122 2012/10/29 19:45:40 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.123 2012/12/05 12:14:08 kensington Exp $
+
+*smplayer-0.8.2.1 (05 Dec 2012)
+
+  05 Dec 2012; Michael Palimaka <kensington@gentoo.org>
+  +smplayer-0.8.2.1.ebuild:
+  Version bump, wrt bug #445212.
 
   29 Oct 2012; Jeroen Roovers <jer@gentoo.org> smplayer-0.8.1.ebuild:
   Stable for HPPA (bug #439258).
diff --git a/media-video/smplayer/smplayer-0.8.2.1.ebuild b/media-video/smplayer/smplayer-0.8.2.1.ebuild
new file mode 100644
index 000000000000..8369df0567aa
--- /dev/null
+++ b/media-video/smplayer/smplayer-0.8.2.1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/smplayer-0.8.2.1.ebuild,v 1.1 2012/12/05 12:14:08 kensington Exp $
+
+EAPI=4
+PLOCALES="ar_SY bg ca cs da de el_GR en_US es et eu fi fr gl hr hu it ja ka ko
+ku lt mk nl pl pt pt_BR ro_RO ru_RU sk sl_SI sr sv tr uk_UA vi_VN zh_CN zh_TW"
+PLOCALE_BACKUP="en_US"
+
+inherit eutils l10n qt4-r2
+
+MY_PV=${PV##*_p}
+if [[ "${MY_PV}" != "${PV}" ]]; then
+	# svn snapshot
+	MY_PV=r${MY_PV}
+	MY_P=${PN}-${MY_PV}
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="mirror://gentoo/${MY_P}.tar.bz2"
+else
+	# regular upstream release
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+fi
+
+DESCRIPTION="Great Qt4 GUI front-end for mplayer"
+HOMEPAGE="http://smplayer.sourceforge.net/"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc64 ~x86 ~x86-fbsd"
+IUSE="debug"
+
+DEPEND="x11-libs/qt-core:4
+	x11-libs/qt-gui:4
+	dev-libs/quazip"
+MPLAYER_USE="[libass,png,X]"
+RDEPEND="${DEPEND}
+	|| ( media-video/mplayer${MPLAYER_USE} media-video/mplayer2${MPLAYER_USE} )"
+
+src_prepare() {
+	# Unbundle dev-libs/quazip
+	rm -R src/findsubtitles/quazip/ || die
+	epatch "${FILESDIR}"/${PN}-0.8.0-quazip.patch
+
+	# Upstream Makefile sucks
+	sed -i -e "/^PREFIX=/s:/usr/local:/usr:" \
+		-e "/^DOC_PATH=/s:packages/smplayer:${PF}:" \
+		-e '/\.\/get_svn_revision\.sh/,+2c\
+	cd src && $(DEFS) $(MAKE)' \
+		"${S}"/Makefile || die "sed failed"
+
+	# Turn debug message flooding off
+	if ! use debug ; then
+		sed -i 's:#\(DEFINES += NO_DEBUG_ON_CONSOLE\):\1:' \
+			"${S}"/src/smplayer.pro || die "sed failed"
+	fi
+
+	# l10n_find_plocales_changes "${S}/src/translations" "${PN}_" '.ts'
+}
+
+src_configure() {
+	cd "${S}"/src
+	echo "#define SVN_REVISION \"SVN-${MY_PV} (Gentoo)\"" > svn_revision.h
+	eqmake4
+}
+
+gen_translation() {
+	ebegin "Generating $1 translation"
+	lrelease ${PN}_${1}.ts
+	eend $? || die "failed to generate $1 translation"
+}
+
+src_compile() {
+	emake
+
+	cd "${S}"/src/translations
+	l10n_for_each_locale_do gen_translation
+}
+
+src_install() {
+	# remove unneeded copies of GPL
+	rm -f Copying.txt docs/{cs,en,hu,it,ja,pt,ru,zh_CN}/gpl.html || die
+	rm -rf docs/{de,es,nl,ro} || die
+
+	emake DESTDIR="${D}" install
+}