Bump to 0.13.1.

(Portage version: 2.2_rc33/cvs/Linux x86_64)

2 files changed, 76 insertions, 1 deletions

diff --git a/media-video/pitivi/ChangeLog b/media-video/pitivi/ChangeLog
index ae7867d135de..d0324310e833 100644
--- a/media-video/pitivi/ChangeLog
+++ b/media-video/pitivi/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/pitivi
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/ChangeLog,v 1.16 2009/05/03 17:36:25 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/ChangeLog,v 1.17 2009/05/31 10:27:02 eva Exp $
+
+*pitivi-0.13.1 (31 May 2009)
+
+  31 May 2009; Gilles Dartiguelongue <eva@gentoo.org> +pitivi-0.13.1.ebuild:
+  Bump to 0.13.1.
 
   03 May 2009; Gilles Dartiguelongue <eva@gentoo.org> -pitivi-0.10.3.ebuild,
   -pitivi-0.11.1.ebuild, pitivi-0.11.3.ebuild:
diff --git a/media-video/pitivi/pitivi-0.13.1.ebuild b/media-video/pitivi/pitivi-0.13.1.ebuild
new file mode 100644
index 000000000000..7475278d54b8
--- /dev/null
+++ b/media-video/pitivi/pitivi-0.13.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/pitivi-0.13.1.ebuild,v 1.1 2009/05/31 10:27:02 eva Exp $
+
+EAPI="2"
+GCONF_DEBUG="no"
+
+inherit gnome2 python eutils
+
+DESCRIPTION="A non-linear video editor using the GStreamer multimedia framework"
+HOMEPAGE="http://www.pitivi.org"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND=">=dev-lang/python-2.5
+	>=dev-python/pygtk-2.12
+	dev-python/dbus-python
+	>=dev-python/gconf-python-2.12
+	dev-python/pycairo
+	dev-python/pygoocanvas
+	net-zope/zopeinterface
+
+	>=media-libs/gstreamer-0.10.23
+	>=dev-python/gst-python-0.10.15
+	>=media-libs/gnonlin-0.10.10.3
+	>=media-libs/gst-plugins-base-0.10.0
+	>=media-libs/gst-plugins-good-0.10.0
+	>=media-plugins/gst-plugins-ffmpeg-0.10.0
+	>=media-plugins/gst-plugins-xvideo-0.10.0
+	>=media-plugins/gst-plugins-libpng-0.10.0"
+DEPEND="${RDEPEND}
+	dev-python/setuptools
+	>=dev-util/intltool-0.35.5"
+
+DOCS="AUTHORS ChangeLog NEWS RELEASE"
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# disable pyc compiling
+	mv py-compile py-compile.orig
+	ln -s $(type -P true) py-compile
+}
+
+src_configure() {
+	addpredict $(unset HOME; echo ~)/.gconf
+	addpredict $(unset HOME; echo ~)/.gconfd
+	addpredict $(unset HOME; echo ~)/.gstreamer-0.10
+
+	gnome2_src_configure
+}
+
+src_test() {
+	export XDG_CONFIG_HOME="${WORKDIR}/.config"
+	export XDG_DATA_HOME="${WORKDIR}/.local"
+	emake check || die "tests failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	python_mod_optimize "/usr/$(get_libdir)/${PN}/python/${PN}"
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup "/usr/$(get_libdir)/${PN}/python/${PN}"
+}