Version bump, wrt bug 341775

(Portage version: 2.2.0_alpha29/cvs/Linux i686)

2 files changed, 95 insertions, 2 deletions

diff --git a/media-video/2mandvd/2mandvd-1.5.5.ebuild b/media-video/2mandvd/2mandvd-1.5.5.ebuild
new file mode 100644
index 000000000000..62b45d28110c
--- /dev/null
+++ b/media-video/2mandvd/2mandvd-1.5.5.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/2mandvd/2mandvd-1.5.5.ebuild,v 1.1 2011/04/22 16:00:01 chiiph Exp $
+
+EAPI="2"
+LANGS="cs de en it"
+
+inherit qt4-r2
+
+MY_PN="2ManDVD"
+
+DESCRIPTION="The successor of ManDVD"
+HOMEPAGE="http://kde-apps.org/content/show.php?content=99450"
+SRC_URI="http://download.tuxfamily.org/${PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug mad xine"
+
+DEPEND="x11-libs/qt-core:4
+	x11-libs/qt-gui:4
+	x11-libs/qt-opengl:4
+	x11-libs/qt-webkit:4"
+
+RDEPEND="${DEPEND}
+	|| ( app-cdr/cdrkit app-cdr/cdrtools )
+	dev-lang/perl
+	media-fonts/dejavu
+	media-gfx/exif
+	media-libs/netpbm
+	xine? ( media-libs/xine-lib )
+	mad? ( media-sound/sox[mad] ) || ( media-sound/sox )
+	media-video/dvdauthor
+	media-video/ffmpeg
+	media-video/ffmpegthumbnailer
+	media-video/mjpegtools
+	media-video/mplayer[encode]"
+
+PATCHES=( "${FILESDIR}/2mandvd-fix-const-char-concatenation.patch" )
+
+S="${WORKDIR}/${MY_PN}"
+
+src_prepare() {
+	# Cleaning old backup files:
+	find . -name "*~" -exec rm -f {} \; || die "find and remove failed"
+
+	for file in *.cpp
+	do
+	  # Fix path:
+	  sed -e "s:qApp->applicationDirPath().\?+.\?\":\"/usr/share/${PN}:g" -i "${file}" || die "sed failed"
+	  sed -e "s:qApp->applicationDirPath():\"/usr/share/${PN}/\":g" -i "${file}" || die "sed failed"
+	done
+
+	# We'll make a newbin called "${PV}" so we need to change references to the old "2ManDVD" ( ${MY_PV} ).
+	# Sed is more flexible than a patch.
+	sed -e "s:openargument.right(${#MY_PN}) != \"${MY_PN}\":openargument.right(${#PN}) != \"${PN}\":" \
+	    -e "s:openargument.right($(( ${#MY_PN} + 2 ))) != \"./${MY_PN}\":openargument.right($(( ${#PN} + 2 ))) != \"./${PN}\":" \
+	    -i "mainfrm.cpp" || die "sed failed"
+
+	qt4-r2_src_prepare
+}
+
+src_install() {
+	insinto "/usr/share/${PN}/"
+
+	# Data:
+	doins -r Bibliotheque || die "failed to install Library"
+	doins -r Interface || die "failed to install Interface"
+
+	doins "fake.pl" || die "failed to install \"fake.pl\""
+
+	# Translations:
+	for lang in ${LINGUAS}; do
+		for x in ${LANGS}; do
+			[[ ${lang} == ${x} ]] && doins ${PN}_${x}.qm
+		done
+	done
+	[[ -z ${LINGUAS} ]] && doins ${PN}_en.qm
+
+	# Doc:
+	dodoc README.txt || die "dodoc failed"
+
+	# Bin and menu entry:
+	newbin 2ManDVD ${PN} || die "newbin failed"
+	doicon Interface/mandvd.png || die "doicon failed"
+	make_desktop_entry "${PN}" "${MY_PN}" "mandvd" "Qt;AudioVideo;Video" || die "make_desktop_entry failed"
+}
diff --git a/media-video/2mandvd/ChangeLog b/media-video/2mandvd/ChangeLog
index cbb9e05a8019..fb4d4d9390f4 100644
--- a/media-video/2mandvd/ChangeLog
+++ b/media-video/2mandvd/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/2mandvd
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/2mandvd/ChangeLog,v 1.15 2010/10/23 00:41:36 hwoarang Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/2mandvd/ChangeLog,v 1.16 2011/04/22 16:00:01 chiiph Exp $
+
+*2mandvd-1.5.5 (22 Apr 2011)
+
+  22 Apr 2011; Tomas Touceda <chiiph@gentoo.org> +2mandvd-1.5.5.ebuild:
+  Version bump, wrt bug 341775
 
   23 Oct 2010; Markos Chandras <hwoarang@gentoo.org> metadata.xml:
   Remove myself from metadata