version bump

(Portage version: 2.1.3_rc6)

3 files changed, 74 insertions, 1 deletions

diff --git a/media-sound/traverso/ChangeLog b/media-sound/traverso/ChangeLog
index 8ac60bc50d6b..d8f20dfe76b0 100644
--- a/media-sound/traverso/ChangeLog
+++ b/media-sound/traverso/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/traverso
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/traverso/ChangeLog,v 1.6 2007/07/02 15:21:44 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/traverso/ChangeLog,v 1.7 2007/07/05 18:19:36 aballier Exp $
+
+*traverso-0.41.0 (05 Jul 2007)
+
+  05 Jul 2007; Alexis Ballier <aballier@gentoo.org> +traverso-0.41.0.ebuild:
+  Version bump
 
   02 Jul 2007; Diego Pettenò <flameeyes@gentoo.org> metadata.xml:
   Hand to newly-born proaudio herd.
diff --git a/media-sound/traverso/files/digest-traverso-0.41.0 b/media-sound/traverso/files/digest-traverso-0.41.0
new file mode 100644
index 000000000000..75275dbfaea2
--- /dev/null
+++ b/media-sound/traverso/files/digest-traverso-0.41.0
@@ -0,0 +1,3 @@
+MD5 0ede91520b8759a69b3b9f8f04a2eb38 traverso-0.41.0.tar.gz 712071
+RMD160 24c6a7a3678054a7a101642ef5248b257a2a8895 traverso-0.41.0.tar.gz 712071
+SHA256 7703c3bc7b9dcd010542da7330c2546808ee840ebc56eb41e7fdfbb9bde46d82 traverso-0.41.0.tar.gz 712071
diff --git a/media-sound/traverso/traverso-0.41.0.ebuild b/media-sound/traverso/traverso-0.41.0.ebuild
new file mode 100644
index 000000000000..c0000737209a
--- /dev/null
+++ b/media-sound/traverso/traverso-0.41.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/traverso/traverso-0.41.0.ebuild,v 1.1 2007/07/05 18:19:36 aballier Exp $
+
+inherit eutils qt4 toolchain-funcs
+
+DESCRIPTION="Professional Audio Tools for GNU/Linux"
+HOMEPAGE="http://traverso-daw.org/"
+SRC_URI="http://traverso-daw.org/download/releases/current/${P}.tar.gz"
+
+IUSE="alsa jack lv2 opengl sse"
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="$(qt4_min_version 4.2.3)
+	alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )
+	>=dev-libs/glib-2.8
+	>=media-libs/libsndfile-1.0.12
+	media-libs/libsamplerate
+	>=sci-libs/fftw-3
+	lv2? ( dev-libs/rasqal dev-libs/redland )"
+
+DEPEND="${RDEPEND}
+	sys-apps/sed"
+
+pkg_setup() {
+	if use opengl && ! built_with_use =x11-libs/qt-4* opengl; then
+		eerror "You need to build qt4 with opengl support to have it in ${PN}"
+		die "Enabling opengl for traverso requires qt4 to be built with opengl support"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	sed -ie "s:^\(\#define\ RESOURCES_DIR\) \(.*\):\1 \"/usr/share/traverso\":" src/config.h
+	sed -ie "s:^\(target.path\ =\) \(.*\):\1 /usr/bin:" src/traverso/traverso.pro
+	sed -ie "s:^\(DESTDIR_TARGET\ =\) \(.*\):\1 /usr/bin:" src/traverso/traverso.pro
+	#  Removing forced cxxflags
+	sed -ie "s:^\(.*QMAKE_CXXFLAGS_RELEASE.*\):#\1:" src/base.pri
+	# adding our cxxflags
+	sed -ie "s:^\(.*release\ {.*\):\1\n QMAKE_CXXFLAGS_RELEASE\ =\ ${CXXFLAGS}:" src/base.pri
+}
+
+src_compile() {
+	use jack || echo "DEFINES -= JACK_SUPPORT" >> src/base.pri
+	use alsa || echo "DEFINES -= ALSA_SUPPORT" >> src/base.pri
+	use sse || echo "DEFINES -= SSE_OPTIMIZATIONS" >> src/base.pri
+	use lv2 || echo "DEFINES -= LV2_SUPPORT" >> src/base.pri
+	use opengl || echo "DEFINES -= QT_OPENGL_SUPPORT" >> src/base.pri
+
+	QMAKE="/usr/bin/qmake"
+	$QMAKE -recursive traverso.pro -after "QMAKE_STRIP=\"/usr/bin/true\"" || die "qmake failed"
+	emake CC=$(tc-getCC) CXX=$(tc-getCXX) LINK=$(tc-getCXX) || die "emake failed"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog README resources/help.text
+	doicon resources/freedesktop/icons/128x128/apps/traverso.png
+	domenu resources/traverso.desktop
+}