Version bump.

(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

2 files changed, 77 insertions, 1 deletions

diff --git a/media-sound/mpg123/ChangeLog b/media-sound/mpg123/ChangeLog
index f7823ef80c76..0bbb7ecbb1d4 100644
--- a/media-sound/mpg123/ChangeLog
+++ b/media-sound/mpg123/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mpg123
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.252 2012/04/12 20:41:39 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.253 2012/05/01 04:27:42 radhermit Exp $
+
+*mpg123-1.14.0 (01 May 2012)
+
+  01 May 2012; Tim Harder <radhermit@gentoo.org> +mpg123-1.14.0.ebuild:
+  Version bump.
 
 *mpg123-1.13.8 (12 Apr 2012)
 
diff --git a/media-sound/mpg123/mpg123-1.14.0.ebuild b/media-sound/mpg123/mpg123-1.14.0.ebuild
new file mode 100644
index 000000000000..26e52aad667d
--- /dev/null
+++ b/media-sound/mpg123/mpg123-1.14.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/mpg123-1.14.0.ebuild,v 1.1 2012/05/01 04:27:42 radhermit Exp $
+
+EAPI=4
+inherit toolchain-funcs libtool
+
+DESCRIPTION="a realtime MPEG 1.0/2.0/2.5 audio player for layers 1, 2 and 3"
+HOMEPAGE="http://www.mpg123.org/"
+SRC_URI="http://www.mpg123.org/download/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="3dnow 3dnowext alsa altivec coreaudio ipv6 jack mmx nas oss portaudio pulseaudio sdl sse"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )
+	nas? ( media-libs/nas )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sdl? ( media-libs/libsdl )
+	sys-devel/libtool"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog NEWS NEWS.libmpg123 README )
+
+src_prepare() {
+	elibtoolize # for Darwin bundles
+}
+
+src_configure() {
+	local _audio=dummy
+	local _output=dummy
+	local _cpu=generic_fpu
+
+	for flag in nas portaudio sdl oss jack alsa pulseaudio coreaudio; do
+		if use ${flag}; then
+			_audio="${_audio} ${flag/pulseaudio/pulse}"
+			_output=${flag/pulseaudio/pulse}
+		fi
+	done
+
+	use altivec && _cpu=altivec
+
+	if [[ $(tc-arch) == amd64 || ${ARCH} == x64-* ]]; then
+		use sse && _cpu=x86-64
+	elif use x86 && gcc-specs-pie ; then
+		# Don't use any mmx, 3dnow, sse and 3dnowext #bug 164504
+		_cpu=generic_fpu
+	else
+		use mmx && _cpu=mmx
+		use 3dnow && _cpu=3dnow
+		use sse && _cpu=x86
+		use 3dnowext && _cpu=x86
+	fi
+
+	econf \
+		--with-optimization=0 \
+		--with-audio="${_audio}" \
+		--with-default-audio=${_output} \
+		--with-cpu=${_cpu} \
+		--enable-network \
+		$(use_enable ipv6)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}