Version bump.

(Portage version: 2.2.0_alpha73/cvs/Linux x86_64)

2 files changed, 64 insertions, 1 deletions

diff --git a/media-sound/lame/ChangeLog b/media-sound/lame/ChangeLog
index 163c51c6f86c..4ba9145adce0 100644
--- a/media-sound/lame/ChangeLog
+++ b/media-sound/lame/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/lame
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v 1.133 2011/10/21 21:56:10 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v 1.134 2011/11/16 17:18:04 ssuominen Exp $
+
+*lame-3.99.1 (16 Nov 2011)
+
+  16 Nov 2011; Samuli Suominen <ssuominen@gentoo.org> +lame-3.99.1.ebuild:
+  Version bump.
 
 *lame-3.99 (21 Oct 2011)
 
diff --git a/media-sound/lame/lame-3.99.1.ebuild b/media-sound/lame/lame-3.99.1.ebuild
new file mode 100644
index 000000000000..0bc51e76eb26
--- /dev/null
+++ b/media-sound/lame/lame-3.99.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/lame-3.99.1.ebuild,v 1.1 2011/11/16 17:18:04 ssuominen Exp $
+
+EAPI=4
+inherit autotools eutils
+
+DESCRIPTION="LAME Ain't an MP3 Encoder"
+HOMEPAGE="http://lame.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug mmx mp3rtp sndfile static-libs"
+
+RDEPEND=">=sys-libs/ncurses-5.2
+	sndfile? ( >=media-libs/libsndfile-1.0.2 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	mmx? ( dev-lang/nasm )"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-3.96-ccc.patch \
+		"${FILESDIR}"/${PN}-3.98-gtk-path.patch
+
+	mkdir libmp3lame/i386/.libs || die #workaround parallel build with nasm
+
+	sed -i -e '/define sp/s/+/ + /g' libmp3lame/i386/nasm.h || die
+
+	AT_M4DIR=${S} eautoreconf
+	epunt_cxx #74498
+}
+
+src_configure() {
+	local myconf
+	use sndfile && myconf="--with-fileio=sndfile"
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable debug debug norm) \
+		$(use_enable mmx nasm) \
+		--disable-mp3x \
+		$(use_enable mp3rtp) \
+		--enable-dynamic-frontends \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkghtmldir="${EPREFIX}/usr/share/doc/${PF}/html" install
+	dobin misc/mlame
+
+	dodoc API ChangeLog HACKING README STYLEGUIDE TODO USAGE
+	dohtml misc/lameGUI.html Dll/LameDLLInterface.htm
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}