Now using unicode patch instead of recode patch as it has been accepted upstream. Added a patch to hide xmms on the task bar if xmms-status-plugin is enabled. Added --show-jump-box command line arg. Added patch to fix libjoy related crash. Closes bugs #55398, #57755, #59863, #63168, #64367.

4 files changed, 234 insertions, 2 deletions

diff --git a/media-sound/xmms/ChangeLog b/media-sound/xmms/ChangeLog
index 43dc64479785..b6f8e2d402bf 100644
--- a/media-sound/xmms/ChangeLog
+++ b/media-sound/xmms/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for media-sound/xmms
 # Copyright 2002-2004 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/xmms/ChangeLog,v 1.137 2004/09/05 17:11:18 eradicator Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/xmms/ChangeLog,v 1.138 2004/09/30 23:09:35 eradicator Exp $
+
+*xmms-1.2.10-r6 (30 Sep 2004)
+
+  30 Sep 2004; Jeremy Huddleston <eradicator@gentoo.org>
+  +xmms-1.2.10-r6.ebuild:
+  Now using unicode patch instead of recode patch as it has been accepted
+  upstream. Added a patch to hide xmms on the task bar if xmms-status-plugin
+  is enabled. Added --show-jump-box command line arg. Added patch to fix
+  libjoy related crash. Closes bugs #55398, #57755, #59863, #63168, #64367.
 
   05 Sep 2004; Jeremy Huddleston <eradicator@gentoo.org>
   xmms-1.2.10-r5.ebuild, xmms-1.2.8-r4.ebuild:
diff --git a/media-sound/xmms/Manifest b/media-sound/xmms/Manifest
index 130e7551355c..512a7a3a4bb9 100644
--- a/media-sound/xmms/Manifest
+++ b/media-sound/xmms/Manifest
@@ -1,7 +1,9 @@
-MD5 ea44e898793ed849f6de1a1aa9be46ab ChangeLog 25029
+MD5 f51160856f462f37626b68da56bdd830 ChangeLog 25444
 MD5 5a8290e44006ccff0dff3094555d6366 metadata.xml 257
+MD5 0073adefe6677a12fc1e831a79d1066b xmms-1.2.10-r6.ebuild 5957
 MD5 33180edc5b30f54debff69322fae465a xmms-1.2.8-r4.ebuild 5271
 MD5 e8f74b9f98c9a742f9d9e7559227ef84 xmms-1.2.10-r5.ebuild 5386
+MD5 d08394d75f553a29e69e949744914183 files/digest-xmms-1.2.10-r6 219
 MD5 f52f09b25da87c876de70b6177292f2e files/digest-xmms-1.2.8-r4 216
 MD5 7d2f3807ebbff435b909ecf0539cbf4f files/xmms.desktop 722
 MD5 aa46b23a1cf0655c7f09adbdd623d49f files/digest-xmms-1.2.10-r5 219
diff --git a/media-sound/xmms/files/digest-xmms-1.2.10-r6 b/media-sound/xmms/files/digest-xmms-1.2.10-r6
new file mode 100644
index 000000000000..f305390266cf
--- /dev/null
+++ b/media-sound/xmms/files/digest-xmms-1.2.10-r6
@@ -0,0 +1,3 @@
+MD5 03a85cfc5e1877a2e1f7be4fa1d3f63c xmms-1.2.10.tar.bz2 2418265
+MD5 41eababfa8bad11e9e34e467cdfb86be gentoo_ice-xmms-0.2.tar.bz2 51839
+MD5 f29e089b6351a90fefb3a234a8155099 xmms-1.2.10-gentoo-patches-1.1.tar.bz2 163903
diff --git a/media-sound/xmms/xmms-1.2.10-r6.ebuild b/media-sound/xmms/xmms-1.2.10-r6.ebuild
new file mode 100644
index 000000000000..fea18859e274
--- /dev/null
+++ b/media-sound/xmms/xmms-1.2.10-r6.ebuild
@@ -0,0 +1,218 @@
+# Copyright 1999-2004 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/xmms/xmms-1.2.10-r6.ebuild,v 1.1 2004/09/30 23:09:35 eradicator Exp $
+
+IUSE="xml nls esd opengl mmx oggvorbis 3dnow mikmod directfb ipv6 cjk alsa oss arts jack sndfile lirc"
+
+inherit flag-o-matic eutils libtool gnuconfig
+
+PATCHVER="1.1"
+
+MY_P=${P/_pre/-pre}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="X MultiMedia System"
+HOMEPAGE="http://www.xmms.org/"
+SRC_URI="http://www.xmms.org/files/1.2.x/${MY_P}.tar.bz2
+	mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2
+	http://dev.gentoo.org/~eradicator/xmms/${P}-gentoo-patches-${PATCHVER}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~x86 ~ppc ~sparc ~alpha ~hppa ~amd64 ~ia64 ~mips ~ppc64"
+
+DEPEND="=x11-libs/gtk+-1.2*
+	mikmod? ( >=media-libs/libmikmod-3.1.10 )
+	esd? ( >=media-sound/esound-0.2.22 )
+	xml? ( >=dev-libs/libxml-1.8.15 )
+	opengl? ( virtual/opengl )
+	alsa? ( >=media-libs/alsa-lib-0.9.0 )
+	oggvorbis? ( >=media-libs/libvorbis-1.0 )"
+
+RDEPEND="${DEPEND}
+	directfb? ( dev-libs/DirectFB )
+	sys-devel/gettext
+	app-arch/unzip"
+
+PDEPEND="!alpha? ( !hppa? ( !ia64? ( !mips? ( !ppc64? ( jack? ( media-plugins/xmms-jack ) ) ) ) ) )
+	 !alpha? ( !ia64? ( !ppc64? ( lirc? ( media-plugins/xmms-lirc ) ) ) )
+	 !ia64? ( !ppc64? ( arts? ( media-plugins/xmms-arts ) ) )
+	 !alpha? ( !hppa? ( !ia64? ( !mips? ( !ppc64? ( sndfile? ( media-plugins/xmms-sndfile ) ) ) ) ) )"
+
+#We want these things in DEPEND only
+DEPEND="${DEPEND}
+	nls? ( dev-util/intltool )
+	>=sys-devel/automake-1.7.8
+	>=sys-devel/autoconf-2.58"
+
+PATCHDIR=${WORKDIR}/patches
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	# Add dynamic taste detection patch...
+	# goto http://bugs.xmms.org/show_bug.cgi?id=756 to vote for its inclusion in mainline xmms
+	# This patch is no longer included in gentoo xmms due to problems with later versions of glib.
+	# epatch ${PATCHDIR}/${P}-dtd.patch
+
+	# Fix gcc3.4 C++ problem. See bug #53125
+	epatch ${PATCHDIR}/${P}-gcc34.patch
+
+	# Patch to allow external programmes to have the "jump to" dialog box
+	epatch ${PATCHDIR}/${P}-jump.patch
+	epatch ${PATCHDIR}/${P}-jumpcl.patch
+
+	# Save playlist, etc on SIGTERM and SIGINT, bug #13604.
+	epatch ${PATCHDIR}/${P}-sigterm.patch
+
+	# Patch for mpg123 to convert Japanese character code of MP3 tag info
+	# the Japanese patch and the Russian one overlap, so its one or the other
+	if use cjk; then
+		# id3v2 editing support in mpg123 plugin
+		epatch ${PATCHDIR}/${P}-id3v2edit.patch
+
+		epatch ${PATCHDIR}/${P}-mpg123j.patch
+#	elif use unicode; then
+	else
+		epatch ${PATCHDIR}/${P}-unicode.patch
+#	else
+#		# id3v2 editing support in mpg123 plugin
+#		epatch ${PATCHDIR}/${P}-id3v2edit.patch
+#
+#		# add recode patch http://sourceforge.net/projects/rusxmms/
+#		# epatch ${PATCHDIR}/${P}-recode-csa27.3.dtd.patch
+#		epatch ${PATCHDIR}/${P}-recode-csa27.3.patch
+#		epatch ${PATCHDIR}/${P}-recode-csa27.3.regressionFix.patch
+#		epatch ${PATCHDIR}/${P}-recode-csa27.3.nullTitle.patch
+#
+	fi
+
+	# Add /usr/local/share/xmms/Skins to the search path for skins
+	epatch ${PATCHDIR}/${P}-fhs-skinsdir.patch
+
+	# This patch passes audio output through the output plugin
+	# before recording via the diskwriter plugin
+	# http://forum.xmms.org/viewtopic.php?t=500&sid=c286e1c01fb924a2f81f519969f33764
+	epatch ${PATCHDIR}/${P}-diskwriter-audio.patch
+
+	# Patch to enable superior randomised playlists:
+	epatch ${PATCHDIR}/${P}-random.patch
+
+	# This patch changes the search-bar's behaviour when playing
+	# sid tunes using xmms-sid plugin. It enables you to select the
+	# different tunes that are sometimes included in a single .sid file
+	epatch ${PATCHDIR}/${P}-sid-songpos.patch
+
+	# Bug #45720 ... bugfix when unpausing with alsa
+	epatch ${PATCHDIR}/${P}-alsa-pause.patch
+
+	# Bug #47761 ... Patch to enable seeking in HTTP streams
+	epatch ${PATCHDIR}/${P}-stream-seek.patch
+
+	# Bug #55398 ... fix libjoy crash
+	epatch ${PATCHDIR}/${P}-joycrash.patch
+
+	# Bug #57755 ... remember playlist location
+	epatch ${PATCHDIR}/${P}-status.patch
+
+	if [ ! -f ${S}/config.rpath ] ; then
+		touch ${S}/config.rpath
+		chmod +x ${S}/config.rpath
+	fi
+
+	# dtd updates Makefile.am, but not Makefile.in
+	export WANT_AUTOCONF=2.5
+	export WANT_AUTOMAKE=1.7
+	for subd in .; do
+		cd ${S}/${subd}
+
+		ebegin "Running aclocal in ${S}/${subd}"
+		aclocal
+		eend $?
+
+		ebegin "Running automake in ${S}/${subd}"
+		automake --gnu --add-missing --include-deps
+		retval=$?
+		eend $retval
+
+		if [ $retval -ne 0 ]; then
+			exit 1;
+		fi
+	done
+
+	#elibtoolize
+	cd ${S}
+	libtoolize --force --copy || die
+}
+
+src_compile() {
+	filter-flags -fforce-addr -D_FILE_OFFSET_BITS=64 -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE
+
+	local myconf=""
+
+	# Allow configure to detect mipslinux systems
+	gnuconfig_update
+
+	if use amd64; then
+		myconf="${myconf} --disable-simd"
+	else
+	  	if use 3dnow || use mmx; then
+			myconf="${myconf} --enable-simd"
+		else
+			myconf="${myconf} --disable-simd"
+		fi
+	fi
+
+	use xml || myconf="${myconf} --disable-cdindex"
+
+	econf \
+		--with-dev-dsp=/dev/sound/dsp \
+		--with-dev-mixer=/dev/sound/mixer \
+		`use_enable oggvorbis vorbis` \
+		`use_enable oggvorbis oggtest` \
+		`use_enable oggvorbis vorbistest` \
+		`use_enable esd` \
+		`use_enable esd esdtest` \
+		`use_enable mikmod` \
+		`use_enable mikmod mikmodtest` \
+		`use_with mikmod libmikmod` \
+		`use_enable opengl` \
+		`use_enable nls` \
+		`use_enable ipv6` \
+		`use_enable oss oss` \
+		${myconf} \
+		|| die
+
+	emake -j1 || die
+}
+
+src_install() {
+	make DESTDIR=${D} install || die
+
+	dodoc AUTHORS ChangeLog FAQ NEWS README TODO
+
+	keepdir /usr/share/xmms/Skins
+	insinto /usr/share/pixmaps/
+	donewins xmms/xmms_logo.xpm xmms.xpm
+	doins xmms/xmms_logo.xpm
+	insinto /usr/share/pixmaps/mini
+	doins xmms/xmms_mini.xpm
+
+	insinto /etc/X11/wmconfig
+	donewins xmms/xmms.wmconfig xmms
+
+	# Not installed per bug #47502
+	#insinto /usr/share/gnome/apps/Multimedia
+	#doins ${FILESDIR}/xmms.desktop
+	insinto /usr/share/applnk/Multimedia
+	doins ${FILESDIR}/xmms.desktop
+	insinto /usr/share/applications
+	doins ${FILESDIR}/xmms.desktop
+
+	# Add the sexy Gentoo Ice skin
+	insinto /usr/share/xmms/Skins/gentoo_ice
+	doins ${WORKDIR}/gentoo_ice/*
+	docinto gentoo_ice
+	dodoc ${WORKDIR}/README
+}