Bump to 0.11.99.3.

(Portage version: 2.2_rc25/cvs/Linux x86_64)

4 files changed, 161 insertions, 121 deletions

diff --git a/media-sound/rhythmbox/ChangeLog b/media-sound/rhythmbox/ChangeLog
index 1642b3845f56..dc42152661cb 100644
--- a/media-sound/rhythmbox/ChangeLog
+++ b/media-sound/rhythmbox/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/rhythmbox
 # Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/ChangeLog,v 1.137 2009/03/18 06:36:54 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/ChangeLog,v 1.138 2009/03/18 22:58:39 eva Exp $
+
+*rhythmbox-0.11.99.3 (18 Mar 2009)
+
+  18 Mar 2009; Gilles Dartiguelongue <eva@gentoo.org> metadata.xml,
+  -rhythmbox-0.11.2-r1.ebuild, +rhythmbox-0.11.99.3.ebuild:
+  Bump to 0.11.99.3.
 
   18 Mar 2009; Joseph Jezak <josejx@gentoo.org> rhythmbox-0.11.6-r1.ebuild:
   Marked ppc stable for bug #234306.
diff --git a/media-sound/rhythmbox/metadata.xml b/media-sound/rhythmbox/metadata.xml
index 47ee5f876d80..03ea20174855 100644
--- a/media-sound/rhythmbox/metadata.xml
+++ b/media-sound/rhythmbox/metadata.xml
@@ -8,5 +8,6 @@
     <flag name="daap">Enable support for local network music sharing via daap</flag>
     <flag name="mtp">Enable support for MTP devices</flag>
     <flag name="tagwriting">support for tag writing in certain audio files</flag>
+	<flag name="brasero">Enable CD burning via <pkg>app-cdr/brasero</pkg> rather than <pkg>gnome-extra/nautilus-cd-burner</pkg></flag>
   </use>
 </pkgmetadata>
diff --git a/media-sound/rhythmbox/rhythmbox-0.11.2-r1.ebuild b/media-sound/rhythmbox/rhythmbox-0.11.2-r1.ebuild
deleted file mode 100644
index 265dc5e676c3..000000000000
--- a/media-sound/rhythmbox/rhythmbox-0.11.2-r1.ebuild
+++ /dev/null
@@ -1,120 +0,0 @@
-# Copyright 1999-2008 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/rhythmbox-0.11.2-r1.ebuild,v 1.7 2008/04/21 17:17:50 welp Exp $
-
-EAPI="1"
-
-inherit gnome2 eutils python
-
-DESCRIPTION="Music management and playback software for GNOME"
-HOMEPAGE="http://www.rhythmbox.org/"
-LICENSE="GPL-2"
-KEYWORDS="~amd64 ~ppc ~sparc ~x86"
-IUSE="doc vorbis flac mad ipod hal daap dbus libnotify lirc musicbrainz tagwriting python gnome-keyring"
-#I want tagwriting to be on by default in the future. It is just a local flag
-#now because it is still considered experimental by upstream and doesn't work
-#well with all formats due to gstreamer limitation.
-
-# We will probably want to activate crossfade backend at some point via USE flag
-
-SLOT="0"
-
-RDEPEND=">=x11-libs/gtk+-2.6
-	>=gnome-base/libgnomeui-2
-	>=gnome-base/libglade-2
-	>=gnome-base/gnome-vfs-2.8
-	>=gnome-base/libbonobo-2
-	>=gnome-extra/nautilus-cd-burner-2.13
-	>=media-video/totem-1.1.5
-	>=x11-libs/libsexy-0.1.5
-	>=gnome-extra/gnome-media-2.14.0
-	>=media-plugins/gst-plugins-cdparanoia-0.10
-	gnome-keyring? ( >=gnome-base/gnome-keyring-0.4.9 )
-	musicbrainz? ( >=media-libs/musicbrainz-2.1:1 )
-	>=net-libs/libsoup-2.2.99:2.2
-	lirc? ( app-misc/lirc )
-	hal? ( ipod? ( >=media-libs/libgpod-0.4 )
-			>=sys-apps/hal-0.5 )
-	daap? ( >=net-dns/avahi-0.6 )
-	dbus? ( >=dev-libs/dbus-glib-0.71 )
-	>=media-libs/gst-plugins-base-0.10.11
-	>=media-plugins/gst-plugins-gnomevfs-0.10
-	vorbis? ( >=media-plugins/gst-plugins-vorbis-0.10
-				>=media-plugins/gst-plugins-ogg-0.10 )
-	mad? ( >=media-plugins/gst-plugins-mad-0.10 )
-	flac? ( >=media-plugins/gst-plugins-flac-0.10 )
-	libnotify? ( >=x11-libs/libnotify-0.3.2 )
-	python? ( >=dev-lang/python-2.4.2
-				>=dev-python/pygtk-2.8
-				>=dev-python/gnome-python-2.12 )"
-
-DEPEND="${RDEPEND}
-	dev-util/pkgconfig
-	>=dev-util/intltool-0.35
-	app-text/scrollkeeper"
-
-pkg_setup() {
-
-	if ! use hal && use ipod; then
-		ewarn "ipod support requires hal support.  Please"
-		ewarn "re-emerge with USE=hal to enable ipod support"
-	fi
-
-	if use daap ; then
-		G2CONF="${G2CONF} --enable-daap --with-mdns=avahi"
-	else
-		G2CONF="${G2CONF} --disable-daap"
-	fi
-
-	G2CONF="${G2CONF}
-		$(use_enable tagwriting tag-writing)
-		$(use_with ipod)
-		$(use_enable ipod ipod-writing)
-		$(use_enable musicbrainz)
-		$(use_with dbus)
-		$(use_enable python)
-		$(use_enable libnotify)
-		$(use_enable lirc)
-		$(use_with gnome-keyring)
-		--with-playback=gstreamer-0-10
-		--with-cd-burning
-		--enable-mmkeys
-		--enable-audioscrobbler
-		--enable-track-transfer
-		--with-metadata-helper
-		--disable-schemas-install"
-
-DOCS="AUTHORS COPYING ChangeLog DOCUMENTERS INSTALL INTERNALS \
-	  MAINTAINERS NEWS README README.iPod THANKS TODO"
-
-export GST_INSPECT=/bin/true
-}
-
-src_unpack() {
-	gnome2_src_unpack
-
-	# disable pyc compiling
-	mv py-compile py-compile.orig
-	ln -s $(type -P true) py-compile
-}
-
-src_compile() {
-	addpredict "$(unset HOME; echo ~)/.gconf"
-	addpredict "$(unset HOME; echo ~)/.gconfd"
-	gnome2_src_compile
-}
-
-pkg_postinst() {
-	gnome2_pkg_postinst
-	use python && python_mod_optimize /usr/$(get_libdir)/rhythmbox/plugins
-
-	elog "The aac flag has been removed from rhythmbox."
-	elog "This is due to stabilization issues with any gst-bad plugins."
-	elog "Please emerge gst-plugins-bad and gst-plugins-faad to be able to play m4a files"
-	elog "See bug #159538 for more information"
-}
-
-pkg_postrm() {
-	gnome2_pkg_postrm
-	use python && python_mod_cleanup /usr/$(get_libdir)/rhythmbox/plugins
-}
diff --git a/media-sound/rhythmbox/rhythmbox-0.11.99.3.ebuild b/media-sound/rhythmbox/rhythmbox-0.11.99.3.ebuild
new file mode 100644
index 000000000000..e6f8eb8fefae
--- /dev/null
+++ b/media-sound/rhythmbox/rhythmbox-0.11.99.3.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/rhythmbox-0.11.99.3.ebuild,v 1.1 2009/03/18 22:58:39 eva Exp $
+
+EAPI="2"
+
+inherit eutils gnome2 python multilib virtualx
+
+SRC_URI="http://methlab42.itee.uq.edu.au/~jonathan/${P}.tar.bz2"
+DESCRIPTION="Music management and playback software for GNOME"
+HOMEPAGE="http://www.rhythmbox.org/"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+IUSE="+brasero cdr daap doc hal ipod gnome-keyring libnotify lirc musicbrainz mtp nsplugin python test"
+
+# FIXME: double check what to do with fm-radio plugin
+
+SLOT="0"
+
+RDEPEND=">=dev-libs/glib-2.15.5
+	>=x11-libs/gtk+-2.12
+	>=gnome-base/libgnomeui-2
+	>=gnome-base/libglade-2
+	>=dev-libs/totem-pl-parser-2.22.0
+	cdr? (
+		brasero? ( >=app-cdr/brasero-0.9.1 )
+		!brasero? ( >=gnome-extra/nautilus-cd-burner-2.21.6 ) )
+	>=x11-libs/libsexy-0.1.5
+	>=gnome-extra/gnome-media-2.14.0
+	gnome-keyring? ( >=gnome-base/gnome-keyring-0.4.9 )
+	musicbrainz? ( media-libs/musicbrainz:3 )
+	>=net-libs/libsoup-2.4:2.4
+	lirc? ( app-misc/lirc )
+	hal? (
+		ipod? ( >=media-libs/libgpod-0.6 )
+		mtp? ( >=media-libs/libmtp-0.3.0 )
+		>=sys-apps/hal-0.5 )
+	daap? ( >=net-dns/avahi-0.6 )
+	>=dev-libs/dbus-glib-0.71
+	>=media-libs/gst-plugins-base-0.10.12
+	>=media-plugins/gst-plugins-gnomevfs-0.10
+	|| (
+		>=media-plugins/gst-plugins-cdparanoia-0.10
+		>=media-plugins/gst-plugins-cdio-0.10 )
+	>=media-plugins/gst-plugins-meta-0.10-r2:0.10
+	>=media-plugins/gst-plugins-taglib-0.10.6
+	libnotify? ( >=x11-libs/libnotify-0.3.2 )
+	python? (
+		>=dev-lang/python-2.4.2
+		|| (
+			>=dev-lang/python-2.5
+			dev-python/celementtree )
+		>=dev-python/pygtk-2.8
+		>=dev-python/gnome-vfs-python-2.22.0
+		>=dev-python/gconf-python-2.22.0
+		>=dev-python/libgnome-python-2.22.0
+		>=dev-python/gst-python-0.10.8 )
+	nsplugin? ( || (
+		net-libs/xulrunner
+		www-client/seamonkey
+		www-client/mozilla-firefox ) )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	>=dev-util/intltool-0.40
+	app-text/scrollkeeper
+	app-text/gnome-doc-utils
+	doc? ( >=dev-util/gtk-doc-1.4 )
+	test? ( dev-libs/check )"
+
+DOCS="AUTHORS ChangeLog DOCUMENTERS INTERNALS \
+	  MAINTAINERS NEWS README README.iPod THANKS TODO"
+
+pkg_setup() {
+	if ! use hal && use ipod; then
+		ewarn "ipod support requires hal support.  Please"
+		ewarn "re-emerge with USE=hal to enable ipod support"
+	fi
+
+	if ! use hal && use mtp; then
+		ewarn "MTP support requires hal support.  Please"
+		ewarn "re-emerge with USE=hal to enable MTP support"
+	fi
+
+	if ! use cdr ; then
+		ewarn "You have cdr USE flag disabled."
+		ewarn "You will not be able to play audio CDs."
+	fi
+
+	if use brasero; then
+		G2CONF="${G2CONF} $(use_with cdr libbrasero-media) --without-libnautilus-burn"
+	else
+		G2CONF="${G2CONF} $(use_with cdr libnautilus-burn) --without-libbrasero-media"
+	fi
+
+	G2CONF="${G2CONF}
+		MOZILLA_PLUGINDIR=/usr/$(get_libdir)/nsbrowser/plugins
+		$(use_with gnome-keyring)
+		$(use_with ipod)
+		$(use_enable libnotify)
+		$(use_enable lirc)
+		$(use_enable musicbrainz)
+		$(use_with mtp)
+		$(use_enable nsplugin browser-plugin)
+		$(use_enable python)
+		$(use_enable daap)
+		$(use_with daap mdns avahi)
+		--enable-mmkeys
+		--disable-scrollkeeper
+		--disable-schemas-install
+		--disable-static
+		--disable-vala"
+
+	export GST_INSPECT=/bin/true
+}
+
+src_prepare() {
+	# disable pyc compiling
+	mv py-compile py-compile.orig
+	ln -s $(type -P true) py-compile
+}
+
+src_compile() {
+	addpredict "$(unset HOME; echo ~)/.gconf"
+	addpredict "$(unset HOME; echo ~)/.gconfd"
+	gnome2_src_compile
+}
+
+src_test() {
+	unset SESSION_MANAGER
+	unset DBUS_SESSION_BUS_ADDRESS
+	Xemake check || die "test failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	use python && python_mod_optimize /usr/$(get_libdir)/rhythmbox/plugins
+
+	ewarn
+	ewarn "If ${PN} doesn't play some music format, please check your"
+	ewarn "USE flags on media-plugins/gst-plugins-meta"
+	ewarn
+
+	elog "The aac flag has been removed from rhythmbox."
+	elog "This is due to stabilization issues with any gst-bad plugins."
+	elog "Please emerge gst-plugins-bad and gst-plugins-faad to be able to play m4a files"
+	elog "See bug #159538 for more information"
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup /usr/$(get_libdir)/rhythmbox/plugins
+}