version bump, solving bug #383151.

(Portage version: 2.2.0_alpha70/cvs/Linux x86_64)

2 files changed, 107 insertions, 2 deletions

diff --git a/media-sound/aacgain/ChangeLog b/media-sound/aacgain/ChangeLog
index 00a337b287cb..7b6a33ea8c9c 100644
--- a/media-sound/aacgain/ChangeLog
+++ b/media-sound/aacgain/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/aacgain
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/aacgain/ChangeLog,v 1.9 2009/10/09 21:21:46 sbriesen Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/aacgain/ChangeLog,v 1.10 2011/10/23 17:05:17 sbriesen Exp $
+
+*aacgain-1.9 (23 Oct 2011)
+
+  23 Oct 2011; Stefan Briesenick <sbriesen@gentoo.org> +aacgain-1.9.ebuild:
+  version bump, solving bug #383151.
 
   09 Oct 2009; Stefan Briesenick <sbriesen@gentoo.org> +aacgain-1.8.ebuild,
   +files/aacgain-1.8+glibc-2.10.patch, +metadata.xml:
diff --git a/media-sound/aacgain/aacgain-1.9.ebuild b/media-sound/aacgain/aacgain-1.9.ebuild
new file mode 100644
index 000000000000..6f181fc24c15
--- /dev/null
+++ b/media-sound/aacgain/aacgain-1.9.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/aacgain/aacgain-1.9.ebuild,v 1.1 2011/10/23 17:05:17 sbriesen Exp $
+
+EAPI=4
+
+inherit eutils autotools
+
+FAAD2_PV="2.7"
+MP4V2_PV="1.9.1"
+MP3GAIN_PV="1.5.2"
+
+DESCRIPTION="AACGain normalizes the volume of digital music files using the Replay Gain algorithm."
+HOMEPAGE="http://altosdesign.com/aacgain/"
+SRC_URI="http://sbriesen.de/gentoo/distfiles/${P}.tar.xz
+	http://mp4v2.googlecode.com/files/mp4v2-${MP4V2_PV}.tar.bz2
+	mirror://sourceforge/mp3gain/mp3gain-${MP3GAIN_PV//./_}-src.zip
+	mirror://sourceforge/faac/faad2-${FAAD2_PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND=""
+DEPEND=""
+
+DOCS="${PN}/README"
+
+src_unpack() {
+	mkdir -p "${S}"
+	for X in ${A}; do
+		case "${X}" in
+			mp3gain*)
+				mkdir -p "${S}/${X%%-*}"
+				cd "${S}/${X%%-*}"
+				unpack "${X}"
+				;;
+			*)
+				cd "${S}"
+				unpack "${X}"
+				[ -d "${X%%-*}" ] || mv -f "${X%%-*}"-* "${X%%-*}"
+				;;
+		esac
+	done
+}
+
+src_prepare() {
+	sed -i -e 's:iquote :I:' faad2/libfaad/Makefile.am
+	sed -i -e 's:../\(mp4v2/\):\1:g' ${PN}/mp4v2.patch
+	sed -i -e 's:\(libmp4v2\|libfaad/libfaad\)\.la:README:g' \
+		-e 's:^\(autoreconf\|pushd\|popd\):# \1:g' aacgain/linux/prepare.sh
+
+	epatch ${PN}/mp4v2.patch
+
+	cd "${S}/${PN}/linux"
+	sh prepare.sh || die "prepare failed!"
+
+	cd "${S}"
+	eautoreconf
+
+	cd "${S}/faad2"
+	eautoreconf
+
+	cd "${S}/mp4v2"
+	elibtoolize
+}
+
+src_configure() {
+	local myconf="--disable-dependency-tracking"
+	local myconf2="${myconf} --disable-shared --enable-static"
+
+	cd "${S}/faad2"
+	econf ${myconf2} --without-xmms --without-mpeg4ip
+
+	cd "${S}/mp4v2"
+	econf ${myconf2} --disable-gch
+
+	cd "${S}"
+	econf ${myconf}
+}
+
+src_compile() {
+	cd "${S}/faad2/libfaad"
+	emake
+
+	cd "${S}/mp4v2"
+	emake
+
+	cd "${S}"
+	emake
+}
+
+pkg_postinst() {
+	ewarn
+	ewarn "BACK UP YOUR MUSIC FILES BEFORE USING AACGAIN!"
+	ewarn "THIS IS EXPERIMENTAL SOFTWARE. THERE HAVE BEEN"
+	ewarn "BUGS IN PAST RELEASES THAT CORRUPTED MUSIC FILES."
+	ewarn
+}