Version bump. Dep versioning cleanup. Drop loop-playback useflag

(now always enabled). Add ifp and lua useflags and deps.
(Portage version: 2.2_rc26/cvs/Linux x86_64)

3 files changed, 96 insertions, 3 deletions

diff --git a/media-sound/aqualung/ChangeLog b/media-sound/aqualung/ChangeLog
index 88147126949f..09a85e12fe90 100644
--- a/media-sound/aqualung/ChangeLog
+++ b/media-sound/aqualung/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/aqualung
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/ChangeLog,v 1.1 2008/04/15 03:05:05 yngwin Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/ChangeLog,v 1.2 2009/03/21 11:10:35 yngwin Exp $
+
+*aqualung-0.9_beta10 (21 Mar 2009)
+
+  21 Mar 2009; Ben de Groot <yngwin@gentoo.org> +aqualung-0.9_beta10.ebuild:
+  Version bump. Dep versioning cleanup. Drop loop-playback useflag (now
+  always enabled). Add ifp and lua useflags and deps.
 
 *aqualung-0.9_beta9_p1 (15 Apr 2008)
 
diff --git a/media-sound/aqualung/aqualung-0.9_beta10.ebuild b/media-sound/aqualung/aqualung-0.9_beta10.ebuild
new file mode 100644
index 000000000000..dd1493e51160
--- /dev/null
+++ b/media-sound/aqualung/aqualung-0.9_beta10.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/aqualung-0.9_beta10.ebuild,v 1.1 2009/03/21 11:10:35 yngwin Exp $
+
+EAPI="1"
+inherit eutils versionator
+
+MY_PV="$(delete_version_separator 2)"
+MY_PV="${MY_PV/_p/.}"
+
+DESCRIPTION="A music player for a wide range of formats designed for gapless playback"
+HOMEPAGE="http://aqualung.factorial.hu/"
+SRC_URI="mirror://sourceforge/aqualung/${PN}-${MY_PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="sndfile modplug mp3 vorbis speex flac musepack wavpack ffmpeg taglib ladspa
+	cddb cdda ifp jack lua alsa oss lame systray debug"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="vorbis? ( media-libs/libvorbis )
+	sndfile? ( media-libs/libsndfile )
+	flac? ( media-libs/flac )
+	modplug? ( media-libs/libmodplug )
+	alsa? ( virtual/alsa )
+	mp3? ( media-libs/libmad )
+	lame? ( media-sound/lame )
+	musepack? ( media-libs/libmpcdec )
+	ffmpeg? ( media-video/ffmpeg )
+	speex? ( media-libs/speex media-libs/liboggz )
+	wavpack? ( media-sound/wavpack )
+	cddb? ( media-libs/libcddb )
+	jack? ( media-sound/jack-audio-connection-kit )
+	taglib? ( media-libs/taglib )
+	cdda? ( dev-libs/libcdio )
+	ifp? ( media-libs/libifp )
+	lua? ( dev-lang/lua )
+	media-libs/libsamplerate
+	x11-libs/gtk+:2"
+
+DEPEND="ladspa? ( media-libs/liblrdf )
+	dev-util/pkgconfig
+	dev-libs/libxml2
+	media-libs/raptor
+	${RDEPEND}"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+src_compile() {
+	econf \
+		$(use_with alsa) \
+		$(use_with oss) \
+		$(use_with jack) \
+		$(use_with flac) \
+		$(use_with vorbis ogg) \
+		$(use_with vorbis vorbisenc) \
+		$(use_with sndfile) \
+		$(use_with mp3 mpeg) \
+		$(use_with lame) \
+		$(use_with modplug mod) \
+		$(use_with musepack mpc) \
+		$(use_with ffmpeg lavc) \
+		$(use_with speex) \
+		$(use_with wavpack) \
+		$(use_with cddb) \
+		$(use_with systray) \
+		$(use_with ladspa) \
+		$(use_with taglib metadata) \
+		$(use_with cdda) \
+		$(use_with lua) \
+		$(use_with ifp) \
+		$(use_enable debug) \
+		--with-loop \
+		|| die "econf failed"
+
+	emake || die "make failed"
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "make install failed"
+	dodoc AUTHORS README
+	newicon src/img/icon_64.png aqualung.png
+	make_desktop_entry aqualung Aqualung
+}
diff --git a/media-sound/aqualung/metadata.xml b/media-sound/aqualung/metadata.xml
index 1b9b2811be63..fd1aed131369 100644
--- a/media-sound/aqualung/metadata.xml
+++ b/media-sound/aqualung/metadata.xml
@@ -5,6 +5,9 @@
   <use>
     <flag name="cdda">Enables libcdda cd audio playback support</flag>
     <flag name="loop-playback">Enable adjustable loop playback support</flag>
-    <flag name="systray">Enable system tray support</flag>
+	<flag name="systray">Enable system tray support</flag>
+	<flag name="ifp">Enable support for iRiver iFP portable audio players</flag>
+	<flag name="lua">Enable support for programmable title formatting with
+		<pkg>dev-lang/lua</pkg></flag>
   </use>
 </pkgmetadata>