[media-sound/amarok] Bump to the 2.5.0 release.

Dropped ~ppc64 keywords as all KDE versions are masked on the ppc64 arch.

(Portage version: 2.2.0_alpha76/cvs/Linux x86_64)

4 files changed, 161 insertions, 5 deletions

diff --git a/media-sound/amarok/ChangeLog b/media-sound/amarok/ChangeLog
index 695b953264d1..e1d0cf15eb71 100644
--- a/media-sound/amarok/ChangeLog
+++ b/media-sound/amarok/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/amarok
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.413 2011/11/08 20:16:45 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.414 2011/12/20 09:22:09 jmbsvicetto Exp $
+
+*amarok-2.5.0 (20 Dec 2011)
+
+  20 Dec 2011; Jorge Manuel B. S. Vicetto <jmbsvicetto@gentoo.org>
+  amarok-2.4.0.ebuild, amarok-2.4.3.ebuild, +amarok-2.5.0.ebuild:
+  [media-sound/amarok] Bump to the 2.5.0 release.
+  Dropped ~ppc64 keywords as all KDE versions are masked on the ppc64 arch.
 
   08 Nov 2011; Andreas K. Huettel <dilfridge@gentoo.org> amarok-2.4.3.ebuild:
   No use-deps on strigi, bug 386259
diff --git a/media-sound/amarok/amarok-2.4.0.ebuild b/media-sound/amarok/amarok-2.4.0.ebuild
index 4b2f3cf204ee..ca38a051c7b9 100644
--- a/media-sound/amarok/amarok-2.4.0.ebuild
+++ b/media-sound/amarok/amarok-2.4.0.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.4.0.ebuild,v 1.9 2011/08/23 21:55:04 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.4.0.ebuild,v 1.10 2011/12/20 09:22:09 jmbsvicetto Exp $
 
 EAPI="3"
 
@@ -9,7 +9,7 @@ if [[ ${PV} != *9999* ]]; then
 	KDE_LINGUAS="bg ca cs da de en_GB es et eu fi fr it ja km nb nds nl
 	pa pl pt pt_BR ru sl sr sr@latin sv th tr uk wa zh_TW"
 	SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.bz2"
-	KEYWORDS="amd64 ppc ~ppc64 x86"
+	KEYWORDS="amd64 ppc x86"
 else
 	KDE_SCM="git"
 	KEYWORDS=""
diff --git a/media-sound/amarok/amarok-2.4.3.ebuild b/media-sound/amarok/amarok-2.4.3.ebuild
index 4127dd143642..f99fae9ee7c0 100644
--- a/media-sound/amarok/amarok-2.4.3.ebuild
+++ b/media-sound/amarok/amarok-2.4.3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.4.3.ebuild,v 1.4 2011/11/08 20:16:45 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.4.3.ebuild,v 1.5 2011/12/20 09:22:10 jmbsvicetto Exp $
 
 EAPI=4
 
@@ -14,7 +14,7 @@ DESCRIPTION="Advanced audio player based on KDE framework."
 HOMEPAGE="http://amarok.kde.org/"
 if [[ ${PV} != *9999* ]]; then
 	SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.bz2"
-	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+	KEYWORDS="~amd64 ~ppc ~x86"
 else
 	KEYWORDS=""
 fi
diff --git a/media-sound/amarok/amarok-2.5.0.ebuild b/media-sound/amarok/amarok-2.5.0.ebuild
new file mode 100644
index 000000000000..eeed0ea69aca
--- /dev/null
+++ b/media-sound/amarok/amarok-2.5.0.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-2.5.0.ebuild,v 1.1 2011/12/20 09:22:10 jmbsvicetto Exp $
+
+EAPI=4
+
+KDE_LINGUAS="bg ca cs da de en_GB es et eu fi fr it ja km nb nds nl pa
+pl pt pt_BR ru sl sr sr@latin sv th tr uk wa zh_TW"
+KDE_SCM="git"
+KDE_REQUIRED="never"
+inherit flag-o-matic kde4-base
+
+DESCRIPTION="Advanced audio player based on KDE framework."
+HOMEPAGE="http://amarok.kde.org/"
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~ppc ~x86"
+else
+	KEYWORDS=""
+fi
+
+LICENSE="GPL-2"
+SLOT="4"
+IUSE="cdda daap debug +embedded ipod lastfm mp3tunes mtp opengl +player semantic-desktop +utils"
+
+# Tests require gmock - http://code.google.com/p/gmock/
+# It's not in the tree yet
+RESTRICT="test"
+
+# ipod requires gdk enabled and also gtk compiled in libgpod
+COMMONDEPEND="
+	>=media-libs/taglib-1.6.1[asf,mp4]
+	>=media-libs/taglib-extras-1.0.1
+	player? (
+		app-crypt/qca:2
+		>=app-misc/strigi-0.5.7
+		$(add_kdebase_dep kdelibs 'opengl?,semantic-desktop?')
+		$(add_kdebase_dep kdebase-kioslaves)
+		sys-libs/zlib
+		>=virtual/mysql-5.1[embedded?]
+		x11-libs/qt-script
+		>=x11-libs/qtscriptgenerator-0.1.0
+		cdda? (
+			$(add_kdebase_dep libkcddb)
+			$(add_kdebase_dep libkcompactdisc)
+			$(add_kdebase_dep kdemultimedia-kioslaves)
+		)
+		ipod? ( >=media-libs/libgpod-0.7.0[gtk] )
+		lastfm? ( >=media-libs/liblastfm-0.3.0 )
+		mp3tunes? (
+			dev-libs/glib:2
+			dev-libs/libxml2
+			dev-libs/openssl
+			net-libs/loudmouth
+			net-misc/curl
+			x11-libs/qt-core[glib]
+		)
+		mtp? ( >=media-libs/libmtp-1.0.0 )
+		opengl? ( virtual/opengl )
+	)
+	utils? (
+		x11-libs/qt-core
+		x11-libs/qt-dbus
+	)
+	!player? ( !utils? ( media-sound/amarok[player] ) )
+"
+DEPEND="${COMMONDEPEND}
+	dev-util/automoc
+	dev-util/pkgconfig
+"
+RDEPEND="${COMMONDEPEND}
+	!media-sound/amarok-utils
+	player? ( $(add_kdebase_dep phonon-kde) )
+"
+
+src_prepare() {
+	if ! use player; then
+		# Disable po processing
+		sed -e "s:include(MacroOptionalAddSubdirectory)::" \
+			-i "${S}/CMakeLists.txt" \
+			|| die "Removing include of MacroOptionalAddSubdirectory failed."
+		sed -e "s:macro_optional_add_subdirectory( po )::" \
+			-i "${S}/CMakeLists.txt" \
+			|| die "Removing include of MacroOptionalAddSubdirectory failed."
+	fi
+
+	kde4-base_src_prepare
+}
+
+src_configure() {
+	# Append minimal-toc cflag for ppc64, see bug 280552 and 292707
+	use ppc64 && append-flags -mminimal-toc
+	local mycmakeargs
+
+	if use player; then
+		mycmakeargs=(
+			-DWITH_PLAYER=ON
+			-DWITH_Libgcrypt=OFF
+			$(cmake-utils_use embedded WITH_MYSQL_EMBEDDED)
+			$(cmake-utils_use_with ipod)
+			$(cmake-utils_use_with ipod Gdk)
+			$(cmake-utils_use_with lastfm LibLastFm)
+			$(cmake-utils_use_with mtp)
+			$(cmake-utils_use_with mp3tunes MP3Tunes)
+		)
+	else
+		mycmakeargs=(
+			-DWITH_PLAYER=OFF
+		)
+	fi
+
+	mycmakeargs+=(
+		$(cmake-utils_use_with utils UTILITIES)
+	)
+		# $(cmake-utils_use_with semantic-desktop Nepomuk)
+		# $(cmake-utils_use_with semantic-desktop Soprano)
+
+	kde4-base_src_configure
+}
+
+pkg_postinst() {
+	kde4-base_pkg_postinst
+
+	if use player; then
+
+		if use daap; then
+			echo
+			elog "You have installed amarok with daap support."
+			elog "You may be interested in installing www-servers/mongrel as well."
+			echo
+		fi
+
+		if ! use embedded; then
+			echo
+			elog "You've disabled the amarok support for embedded mysql DBs."
+			elog "You'll have to configure amarok to use an external db server."
+			echo
+			elog "Please read http://amarok.kde.org/wiki/MySQL_Server for details on how"
+			elog "to configure the external db and migrate your data from the embedded database."
+			echo
+
+			if has_version "virtual/mysql[minimal]"; then
+				elog "You built mysql with the minimal use flag, so it doesn't include the server."
+				elog "You won't be able to use the local mysql installation to store your amarok collection."
+				echo
+			fi
+		fi
+	fi
+}