Version bump.

(Portage version: 2.2.0_alpha40/cvs/Linux x86_64)

1 files changed, 55 insertions, 0 deletions

diff --git a/media-sound/solfege/solfege-3.20.0.ebuild b/media-sound/solfege/solfege-3.20.0.ebuild
new file mode 100644
index 000000000000..a5356b946dc7
--- /dev/null
+++ b/media-sound/solfege/solfege-3.20.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/solfege/solfege-3.20.0.ebuild,v 1.1 2011/06/17 19:21:52 radhermit Exp $
+
+EAPI=3
+PYTHON_DEPEND="2:2.6"
+PYTHON_USE_WITH="sqlite"
+
+inherit python
+
+DESCRIPTION="GNU Solfege is a program written to help you practice ear training."
+HOMEPAGE="http://www.solfege.org"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa oss"
+
+RDEPEND=">=dev-python/pygtk-2.12
+	alsa? ( dev-python/pyalsa )"
+DEPEND="dev-lang/swig
+	sys-devel/gettext
+	sys-apps/texinfo
+	dev-util/pkgconfig
+	dev-libs/libxslt
+	app-text/txt2man
+	>=app-text/docbook-xsl-stylesheets-1.60"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e '/^CFLAGS/s:-I/usr/src/linux/include::' \
+		solfege/soundcard/Makefile || die "sed failed"
+}
+
+src_configure() {
+	local xslloc=$( xmlcatalog /etc/xml/catalog	http://docbook.sourceforge.net/release/xsl/current/html/chunk.xsl | sed 's@file://@@' )
+
+	econf \
+		--enable-docbook-stylesheet=${xslloc} \
+		$(use_enable oss oss-sound)
+}
+
+src_compile() {
+	emake skipmanual=yes || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${ED}" nopycompile=YES skipmanual=yes install || die "emake install failed"
+	dodoc AUTHORS *hange*og FAQ README
+}