Version bump. Change default to aac instead of mp3 since mp3 streams can only be used by premium users.

(Portage version: 2.2.0_alpha112/cvs/Linux x86_64)

3 files changed, 68 insertions, 4 deletions

diff --git a/media-sound/pianobar/ChangeLog b/media-sound/pianobar/ChangeLog
index d454dbdabd64..771b7ff94481 100644
--- a/media-sound/pianobar/ChangeLog
+++ b/media-sound/pianobar/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/pianobar
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pianobar/ChangeLog,v 1.20 2012/05/14 09:36:54 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pianobar/ChangeLog,v 1.21 2012/06/27 09:51:27 radhermit Exp $
+
+*pianobar-2012.06.24 (27 Jun 2012)
+
+  27 Jun 2012; Tim Harder <radhermit@gentoo.org> +pianobar-2012.06.24.ebuild,
+  pianobar-9999.ebuild:
+  Version bump. Change default to aac instead of mp3 since mp3 streams can only
+  be used by premium users.
 
   14 May 2012; Tim Harder <radhermit@gentoo.org> pianobar-9999.ebuild:
   Update live ebuild.
diff --git a/media-sound/pianobar/pianobar-2012.06.24.ebuild b/media-sound/pianobar/pianobar-2012.06.24.ebuild
new file mode 100644
index 000000000000..bda5571efdac
--- /dev/null
+++ b/media-sound/pianobar/pianobar-2012.06.24.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pianobar/pianobar-2012.06.24.ebuild,v 1.1 2012/06/27 09:51:27 radhermit Exp $
+
+EAPI="4"
+
+inherit toolchain-funcs flag-o-matic eutils multilib
+
+DESCRIPTION="A console-based replacement for Pandora's flash player"
+HOMEPAGE="http://6xq.net/projects/pianobar/"
+SRC_URI="http://6xq.net/static/projects/${PN}/${P}.tar.bz2"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+aac mp3 static-libs"
+
+RDEPEND="media-libs/libao
+	net-libs/gnutls
+	dev-libs/libgcrypt
+	dev-libs/json-c
+	aac? ( media-libs/faad2 )
+	mp3? ( media-libs/libmad )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+REQUIRED_USE="|| ( aac mp3 )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2011.12.11-tests.patch
+}
+
+src_compile() {
+	local myconf="DYNLINK=1"
+	! use aac && myconf+=" DISABLE_FAAD=1"
+	! use mp3 && myconf+=" DISABLE_MAD=1"
+
+	append-cflags -std=c99
+	tc-export CC
+	emake ${myconf}
+}
+
+src_test() {
+	cp src/libwaitress/waitress.c src/libwaitress/waitress-test.c
+	emake test
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX=/usr LIBDIR=/usr/$(get_libdir) DYNLINK=1 install
+	dodoc ChangeLog README
+
+	use static-libs || rm -f "${D}"/usr/lib*/*.a
+
+	docinto contrib
+	dodoc -r contrib/{config-example,*.sh,eventcmd-examples}
+	docompress -x /usr/share/doc/${PF}/contrib
+}
diff --git a/media-sound/pianobar/pianobar-9999.ebuild b/media-sound/pianobar/pianobar-9999.ebuild
index 0d908f7effd0..2a10b397938a 100644
--- a/media-sound/pianobar/pianobar-9999.ebuild
+++ b/media-sound/pianobar/pianobar-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pianobar/pianobar-9999.ebuild,v 1.2 2012/05/14 09:36:54 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pianobar/pianobar-9999.ebuild,v 1.3 2012/06/27 09:51:27 radhermit Exp $
 
 EAPI="4"
 
@@ -15,7 +15,7 @@ SRC_URI=""
 LICENSE="as-is"
 SLOT="0"
 KEYWORDS=""
-IUSE="aac +mp3 static-libs"
+IUSE="+aac mp3 static-libs"
 
 RDEPEND="media-libs/libao
 	net-libs/gnutls
@@ -26,7 +26,7 @@ RDEPEND="media-libs/libao
 DEPEND="${RDEPEND}
 	virtual/pkgconfig"
 
-REQUIRED_USE="|| ( mp3 aac )"
+REQUIRED_USE="|| ( aac mp3 )"
 
 # Only releases are tested since patches required for testing often break
 RESTRICT="test"