Version bump, by Per Pomsel <phantom4@gmx.net>, bug #257749

(Portage version: 2.2_rc23/cvs/Linux x86_64)

2 files changed, 68 insertions, 2 deletions

diff --git a/media-sound/mp3blaster/ChangeLog b/media-sound/mp3blaster/ChangeLog
index 3bb4e080b5ae..d9422e9a5599 100644
--- a/media-sound/mp3blaster/ChangeLog
+++ b/media-sound/mp3blaster/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/mp3blaster
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mp3blaster/ChangeLog,v 1.42 2008/08/16 17:37:41 aballier Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mp3blaster/ChangeLog,v 1.43 2009/02/08 10:16:41 aballier Exp $
+
+*mp3blaster-3.2.5 (08 Feb 2009)
+
+  08 Feb 2009; Alexis Ballier <aballier@gentoo.org>
+  +mp3blaster-3.2.5.ebuild:
+  Version bump, by Per Pomsel <phantom4@gmx.net>, bug #257749
 
   16 Aug 2008; Alexis Ballier <aballier@gentoo.org>
   mp3blaster-3.2.3-r1.ebuild:
diff --git a/media-sound/mp3blaster/mp3blaster-3.2.5.ebuild b/media-sound/mp3blaster/mp3blaster-3.2.5.ebuild
new file mode 100644
index 000000000000..da19315d104d
--- /dev/null
+++ b/media-sound/mp3blaster/mp3blaster-3.2.5.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mp3blaster/mp3blaster-3.2.5.ebuild,v 1.1 2009/02/08 10:16:41 aballier Exp $
+
+inherit eutils
+
+DESCRIPTION="Text console based program for playing audio files"
+HOMEPAGE="http://mp3blaster.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="esd lirc oss sdl sid vorbis"
+
+RDEPEND=">=sys-libs/ncurses-5.2
+	lirc? ( app-misc/lirc )
+	vorbis? ( >=media-libs/libvorbis-1 )
+	sid? ( =media-libs/libsidplay-1* )
+	esd? ( media-sound/esound )
+	sdl? ( media-libs/libsdl )"
+DEPEND="${RDEPEND}
+	x11-misc/imake"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	# File collision with media-sound/splay.
+	sed -i -e "s:splay.1:splay_mp3blaster.1:" Makefile.in
+	mv splay.1 splay_mp3blaster.1
+}
+
+src_compile() {
+	local myconf
+	if ! use esd && ! use sdl && ! use oss ; then
+		ewarn "You've disabled esd, sdl, and oss.  Enabling oss for you."
+		myconf="--with-oss"
+	fi
+
+	# newthreads and libpth support is broken.
+	econf \
+		--disable-newthreads \
+		--without-pth \
+		--without-nas \
+		$(use_with lirc) \
+		$(use_with vorbis oggvorbis) \
+		$(use_with sid sidplay) \
+		$(use_with esd) \
+		$(use_with sdl) \
+		$(use_with oss) \
+		${myconf}
+	emake || die "emake failed."
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+	# File collision with media-sound/splay.
+	mv "${D}"/usr/bin/splay "${D}"/usr/bin/splay_mp3blaster || die
+	dodoc AUTHORS BUGS ChangeLog CREDITS FAQ NEWS README TODO
+}