Bump to 0.7.2, bug 431982. Thanks to Nikoli

(Portage version: 2.1.11.5/cvs/Linux i686)

2 files changed, 63 insertions, 2 deletions

diff --git a/media-sound/flacon/ChangeLog b/media-sound/flacon/ChangeLog
index b4b084a18f7a..18133013f5f6 100644
--- a/media-sound/flacon/ChangeLog
+++ b/media-sound/flacon/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/flacon
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/flacon/ChangeLog,v 1.5 2012/05/21 09:40:07 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/flacon/ChangeLog,v 1.6 2012/08/23 15:16:36 maksbotan Exp $
+
+*flacon-0.7.2 (23 Aug 2012)
+
+  23 Aug 2012; Maxim Koltsov <maksbotan@gentoo.org> +flacon-0.7.2.ebuild:
+  Bump to 0.7.2, bug 431982. Thanks to Nikoli
 
   21 May 2012; Pawel Hajdan jr <phajdan.jr@gentoo.org> flacon-0.6.1.ebuild:
   x86 stable wrt bug #413359
@@ -23,4 +28,3 @@
   24 Sep 2011; Maxim Koltsov <maksbotan@gentoo.org> +flacon-0.5.7.ebuild,
   +metadata.xml:
   Add initial ebuild, thanks to Nikoli <nikoli@lavabit.com>. Bug 353606.
-
diff --git a/media-sound/flacon/flacon-0.7.2.ebuild b/media-sound/flacon/flacon-0.7.2.ebuild
new file mode 100644
index 000000000000..bcaa0e2bf1ef
--- /dev/null
+++ b/media-sound/flacon/flacon-0.7.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/flacon/flacon-0.7.2.ebuild,v 1.1 2012/08/23 15:16:36 maksbotan Exp $
+
+EAPI="4"
+
+PYTHON_DEPEND="2"
+
+inherit python
+
+DESCRIPTION="Extracts audio tracks from audio CD image to separate tracks"
+HOMEPAGE="https://code.google.com/p/flacon/"
+SRC_URI="https://flacon.googlecode.com/files/${P}.tgz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flac mac mp3 mp4 ogg replaygain tta wavpack"
+
+RDEPEND="
+	dev-python/PyQt4[X]
+	dev-python/chardet
+	media-sound/shntool[mac?]
+	flac? ( media-libs/flac )
+	mac? ( media-sound/mac )
+	mp3? ( media-sound/lame )
+	mp4? ( media-libs/faac )
+	ogg? ( media-sound/vorbis-tools )
+	tta? ( media-sound/ttaenc )
+	wavpack? ( media-sound/wavpack )
+	replaygain? (
+		mp3? ( media-sound/mp3gain )
+		ogg? ( media-sound/vorbisgain )
+	)
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	python_convert_shebangs -r 2 .
+
+	sed -e '/cd $(INST_DIR) && python -mcompileall ./d' -i Makefile || die
+}
+
+src_compile() { :; }
+
+pkg_postinst() {
+	python_mod_optimize /usr/share/${PN}
+}
+
+pkg_postrm() {
+	python_mod_cleanup /usr/share/${PN}
+}