Bugfix release; root to non-root path relocation is now handled correctly in all cases.

(Portage version: 2.1.10.3/cvs/Linux x86_64)

2 files changed, 67 insertions, 1 deletions

diff --git a/media-sound/audacious/ChangeLog b/media-sound/audacious/ChangeLog
index fef8b27787a4..efcbb9a72fa7 100644
--- a/media-sound/audacious/ChangeLog
+++ b/media-sound/audacious/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/audacious
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.232 2011/06/24 23:06:43 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.233 2011/06/29 22:48:35 chainsaw Exp $
+
+*audacious-2.5.3 (29 Jun 2011)
+
+  29 Jun 2011; Tony Vroon <chainsaw@gentoo.org> +audacious-2.5.3.ebuild:
+  Bugfix release; root to non-root path relocation is now handled correctly in
+  all cases.
 
 *audacious-2.5.2 (24 Jun 2011)
 
diff --git a/media-sound/audacious/audacious-2.5.3.ebuild b/media-sound/audacious/audacious-2.5.3.ebuild
new file mode 100644
index 000000000000..ddc4d7635051
--- /dev/null
+++ b/media-sound/audacious/audacious-2.5.3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/audacious-2.5.3.ebuild,v 1.1 2011/06/29 22:48:35 chainsaw Exp $
+
+EAPI=4
+
+MY_P="${P/_/-}"
+S="${WORKDIR}/${MY_P}"
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="http://audacious-media-player.org/"
+SRC_URI="http://distfiles.atheme.org/${MY_P}.tar.gz
+	 mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux"
+IUSE="altivec chardet nls session sse2"
+
+RDEPEND=">=dev-libs/dbus-glib-0.60
+	>=dev-libs/glib-2.16
+	>=dev-libs/libmcs-0.7.1-r2
+	>=dev-libs/libmowgli-0.9.50
+	dev-libs/libxml2
+	>=x11-libs/cairo-1.2.6
+	>=x11-libs/gtk+-2.14:2
+	>=x11-libs/pango-1.8.0
+	session? ( x11-libs/libSM )"
+
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.9.0
+	chardet? ( app-i18n/libguess )
+	nls? ( dev-util/intltool )"
+
+PDEPEND=">=media-plugins/audacious-plugins-2.5.3"
+
+src_configure() {
+	# D-Bus is a mandatory dependency, remote control,
+	# session management and some plugins depend on this.
+	# Building without D-Bus is *unsupported* and a USE-flag
+	# will not be added due to the bug reports that will result.
+	# Bugs #197894, #199069, #207330, #208606
+	econf \
+		--enable-dbus \
+		$(use_enable altivec) \
+		$(use_enable chardet) \
+		$(use_enable nls) \
+		$(use_enable session sm) \
+		$(use_enable sse2)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS NEWS README
+
+	# Gentoo_ice skin installation; bug #109772
+	insinto /usr/share/audacious/Skins/gentoo_ice
+	doins "${WORKDIR}"/gentoo_ice/*
+	docinto gentoo_ice
+	dodoc "${WORKDIR}"/README
+}