Version bump (pre-release), and update also 9999-r1 to have a daap useflag to disable mongrel dependency.

(Portage version: 2.1.2-r5)

4 files changed, 102 insertions, 5 deletions

diff --git a/media-sound/amarok/ChangeLog b/media-sound/amarok/ChangeLog
index c65c8fa5b1c6..1d2e1f0c5379 100644
--- a/media-sound/amarok/ChangeLog
+++ b/media-sound/amarok/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/amarok
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.197 2007/01/31 14:01:19 gustavoz Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/ChangeLog,v 1.198 2007/02/01 20:44:24 flameeyes Exp $
+
+*amarok-1.4.5 (01 Feb 2007)
+
+  01 Feb 2007; Diego Pettenò <flameeyes@gentoo.org> +amarok-1.4.5.ebuild,
+  amarok-9999-r1.ebuild:
+  Version bump (pre-release), and update also 9999-r1 to have a daap useflag
+  to disable mongrel dependency.
 
   31 Jan 2007; Gustavo Zacarias <gustavoz@gentoo.org>
   amarok-1.4.4-r4.ebuild:
diff --git a/media-sound/amarok/amarok-1.4.5.ebuild b/media-sound/amarok/amarok-1.4.5.ebuild
new file mode 100644
index 000000000000..7e78d5ef8c1e
--- /dev/null
+++ b/media-sound/amarok/amarok-1.4.5.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-1.4.5.ebuild,v 1.1 2007/02/01 20:44:24 flameeyes Exp $
+
+LANGS="af ar az bg br ca cs cy da de el en_GB es et fa fi fr ga gl he
+hi hu is it ja ka km ko lt ms nb nl nn pa pl pt pt_BR ro ru rw se sk
+sl sq sr sr@Latn sv ta tg th tr uk uz zh_CN zh_TW"
+LANGS_DOC="da de es et fr it nl pl pt pt_BR ru sv"
+
+USE_KEG_PACKAGING=1
+
+inherit kde eutils flag-o-matic
+
+PKG_SUFFIX=""
+
+MY_P="${P/_/-}"
+S="${WORKDIR}/${P/_/-}"
+
+DESCRIPTION="Advanced audio player based on KDE framework."
+HOMEPAGE="http://amarok.kde.org/"
+
+SRC_URI="mirror://kde/stable/amarok/${PV}/src/${MY_P}.tar.bz2"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="aac kde mysql noamazon opengl postgres
+visualization ipod ifp real njb mtp musicbrainz daap"
+# kde: enables compilation of the konqueror sidebar plugin
+
+RDEPEND="kde? ( || ( kde-base/konqueror kde-base/kdebase ) )
+	>=media-libs/xine-lib-1.1.2_pre20060328-r8
+	>=media-libs/taglib-1.4
+	mysql? ( >=virtual/mysql-4.0 )
+	postgres? ( dev-db/libpq )
+	opengl? ( virtual/opengl )
+	visualization? ( media-libs/libsdl
+					 =media-plugins/libvisual-plugins-0.4* )
+	ipod? ( >=media-libs/libgpod-0.3 )
+	aac? ( media-libs/libmp4v2 )
+	ifp? ( media-libs/libifp )
+	real? ( media-video/realplayer )
+	njb? ( >=media-libs/libnjb-2.2.4 )
+	mtp? ( >=media-libs/libmtp-0.1.1 )
+	musicbrainz? ( media-libs/tunepimp )
+	=dev-lang/ruby-1.8*"
+
+DEPEND="${RDEPEND}"
+
+RDEPEND="${RDEPEND}
+	daap? ( www-servers/mongrel )"
+
+need-kde 3.3
+
+src_compile() {
+	# Extra, unsupported engines are forcefully disabled.
+	local myconf="$(use_enable mysql) $(use_enable postgres postgresql)
+				  $(use_with opengl) --without-xmms
+				  $(use_with visualization libvisual)
+				  $(use_enable !noamazon amazon)
+				  $(use_with ipod libgpod)
+				  $(use_with aac mp4v2)
+				  $(use_with ifp)
+				  $(use_with real helix)
+				  $(use_with njb libnjb)
+				  $(use_with mtp libmtp)
+				  $(use_with musicbrainz)
+				  $(use_with daap)
+				  --with-xine
+				  --without-mas
+				  --without-nmm"
+
+	kde_src_compile
+}
+
+src_install() {
+	kde_src_install
+
+	# As much as I respect Ian, I'd rather leave Amarok to use mongrel
+	# from Portage, for security and policy reasons.
+	rm -rf "${D}"/usr/share/apps/amarok/ruby_lib/rbconfig \
+		"${D}"/usr/share/apps/amarok/ruby_lib/mongrel* \
+		"${D}"/usr/share/apps/amarok/ruby_lib/rubygems* \
+		"${D}"/usr/share/apps/amarok/ruby_lib/gem* \
+		"${D}"/usr/$(get_libdir)/ruby_lib
+}
diff --git a/media-sound/amarok/amarok-9999-r1.ebuild b/media-sound/amarok/amarok-9999-r1.ebuild
index d06c3b9af024..b082563fdee8 100644
--- a/media-sound/amarok/amarok-9999-r1.ebuild
+++ b/media-sound/amarok/amarok-9999-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-9999-r1.ebuild,v 1.1 2007/01/28 14:52:30 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/amarok/amarok-9999-r1.ebuild,v 1.2 2007/02/01 20:44:24 flameeyes Exp $
 
 inherit kde subversion
 
@@ -17,7 +17,7 @@ LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS=""
 IUSE="aac kde mysql noamazon opengl postgres
-visualization ipod ifp real njb mtp musicbrainz"
+visualization ipod ifp real njb mtp musicbrainz daap"
 # kde: enables compilation of the konqueror sidebar plugin
 
 RDEPEND="kde? ( || ( kde-base/konqueror kde-base/kdebase ) )
@@ -33,14 +33,14 @@ RDEPEND="kde? ( || ( kde-base/konqueror kde-base/kdebase ) )
 	ifp? ( media-libs/libifp )
 	real? ( media-video/realplayer )
 	njb? ( >=media-libs/libnjb-2.2.4 )
-	mtp? ( >=media-libs/libmtp-0.1.0 )
+	mtp? ( >=media-libs/libmtp-0.1.1 )
 	musicbrainz? ( media-libs/tunepimp )
 	=dev-lang/ruby-1.8*"
 
 DEPEND="${RDEPEND}"
 
 RDEPEND="${RDEPEND}
-	www-servers/mongrel"
+	daap? ( www-servers/mongrel )"
 
 need-kde 3.3
 
@@ -75,6 +75,7 @@ src_compile() {
 				  $(use_with njb libnjb)
 				  $(use_with mtp libmtp)
 				  $(use_with musicbrainz)
+				  $(use_with daap)
 				  --with-xine
 				  --without-mas
 				  --without-nmm"
diff --git a/media-sound/amarok/files/digest-amarok-1.4.5 b/media-sound/amarok/files/digest-amarok-1.4.5
new file mode 100644
index 000000000000..52f890b2b5ee
--- /dev/null
+++ b/media-sound/amarok/files/digest-amarok-1.4.5
@@ -0,0 +1,3 @@
+MD5 81696ff44989334f0fc5dfd4142ded6d amarok-1.4.5.tar.bz2 18034058
+RMD160 f8273dbe872421d219cb5fbd4042caf841a51b2b amarok-1.4.5.tar.bz2 18034058
+SHA256 a9d2214cab085ac9271c31354e0f797887f0a7cb6acd68ccbc7f94a71d805451 amarok-1.4.5.tar.bz2 18034058