Revbump with the fix for the hang

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

3 files changed, 85 insertions, 5 deletions

diff --git a/media-libs/gst-plugins-base/ChangeLog b/media-libs/gst-plugins-base/ChangeLog
index 0eb9f27dfd3d..c1959dc77feb 100644
--- a/media-libs/gst-plugins-base/ChangeLog
+++ b/media-libs/gst-plugins-base/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/gst-plugins-base
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-base/ChangeLog,v 1.260 2015/01/19 11:15:29 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-base/ChangeLog,v 1.261 2015/01/19 11:17:34 pacho Exp $
+
+*gst-plugins-base-0.10.36-r2 (19 Jan 2015)
+
+  19 Jan 2015; Pacho Ramos <pacho@gentoo.org>
+  +gst-plugins-base-0.10.36-r2.ebuild, gst-plugins-base-0.10.36-r1.ebuild:
+  Revbump with the fix for the hang
 
   19 Jan 2015; Pacho Ramos <pacho@gentoo.org>
   +files/gst-plugins-base-0.10.36-gcc-4.9.patch,
diff --git a/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r1.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r1.ebuild
index 246f4a6f8c34..66e022fca463 100644
--- a/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r1.ebuild
+++ b/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r1.ebuild,v 1.12 2015/01/19 11:15:29 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r1.ebuild,v 1.13 2015/01/19 11:17:34 pacho Exp $
 
 EAPI="5"
 
@@ -40,9 +40,6 @@ src_prepare() {
 
 	# Fix compilation with gcc-4.9, bug #529962
 	epatch "${FILESDIR}"/${PN}-0.10.36-gcc-4.9.patch
-
-	# baseaudiosink: Resync when ringbuffer resets (from '0.10' branch)
-	epatch "${FILESDIR}"/${PN}-0.10.36-resync-ringbuffer.patch
 }
 
 multilib_src_configure() {
diff --git a/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r2.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r2.ebuild
new file mode 100644
index 000000000000..dccafad3f7a1
--- /dev/null
+++ b/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r2.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r2.ebuild,v 1.1 2015/01/19 11:17:34 pacho Exp $
+
+EAPI="5"
+
+GST_ORG_MODULE="gst-plugins-base"
+inherit eutils gstreamer
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="http://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2+ LGPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+introspection nls +orc"
+
+RDEPEND=">=media-libs/gstreamer-${PV}:0.10[introspection?,${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	app-text/iso-codes
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12 )
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.3
+"
+RDEPEND="${RDEPEND}
+	!<media-libs/gst-plugins-bad-0.10.10:0.10
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-medialibs-20140508-r5
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)]
+	)
+"
+
+src_prepare() {
+	# The AC_PATH_XTRA macro unnecessarily pulls in libSM and libICE even
+	# though they are not actually used. This needs to be fixed upstream by
+	# replacing AC_PATH_XTRA with PKG_CONFIG calls.
+	sed -i -e 's:X_PRE_LIBS -lSM -lICE:X_PRE_LIBS:' "${S}"/configure || die
+
+	# Fix compilation with gcc-4.9, bug #529962
+	epatch "${FILESDIR}"/${PN}-0.10.36-gcc-4.9.patch
+
+	# baseaudiosink: Resync when ringbuffer resets (from '0.10' branch)
+	epatch "${FILESDIR}"/${PN}-0.10.36-resync-ringbuffer.patch
+}
+
+multilib_src_configure() {
+	gstreamer_multilib_src_configure \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable nls) \
+		$(use_enable orc) \
+		--disable-examples \
+		--disable-debug \
+		--disable-static
+
+	# bug #366931, flag-o-matic for the whole thing is overkill
+	if [[ ${CHOST} == *86-*-darwin* ]] ; then
+		sed -i \
+			-e '/FLAGS = /s|-O[23]|-O1|g' \
+			gst/audioconvert/Makefile \
+			gst/volume/Makefile || die
+	fi
+
+	if multilib_is_native_abi; then
+		local x
+		for x in libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}