as per upstream, using libmad and ffmpeg directly are bad and cause issues for many people. Building that way is not recommended and unspported. I forwarded my discussions with upstream to gnome@ and pclouds@, however the ebuild hasn't changed, so I'm changing it.

(Portage version: 2.2_rc1/cvs/Linux 2.6.25-gentoo-r3 x86_64)

2 files changed, 101 insertions, 1 deletions

diff --git a/media-libs/swfdec/ChangeLog b/media-libs/swfdec/ChangeLog
index 026794830f31..d7cc22f52443 100644
--- a/media-libs/swfdec/ChangeLog
+++ b/media-libs/swfdec/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-libs/swfdec
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/swfdec/ChangeLog,v 1.38 2008/06/02 10:39:07 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/swfdec/ChangeLog,v 1.39 2008/06/20 21:34:31 cardoe Exp $
+
+*swfdec-0.6.6-r1 (20 Jun 2008)
+
+  20 Jun 2008; Doug Goldstein <cardoe@gentoo.org> +swfdec-0.6.6-r1.ebuild:
+  as per upstream, using libmad and ffmpeg directly are bad and causes
+  issues for many people. Building that way is not recommened and
+  unsupported. I forwarded my discussions with upstream to gnome@ and
+  pclouds@, however the ebuild hasn't changed. So I'm changing it.
 
   02 Jun 2008; Alexis Ballier <aballier@gentoo.org> swfdec-0.6.6.ebuild:
   keyword ~x86-fbsd
diff --git a/media-libs/swfdec/swfdec-0.6.6-r1.ebuild b/media-libs/swfdec/swfdec-0.6.6-r1.ebuild
new file mode 100644
index 000000000000..e44fe57fc71a
--- /dev/null
+++ b/media-libs/swfdec/swfdec-0.6.6-r1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/swfdec/swfdec-0.6.6-r1.ebuild,v 1.1 2008/06/20 21:34:31 cardoe Exp $
+
+EAPI=1
+
+inherit eutils versionator confutils
+
+MY_PV=$(get_version_component_range 1-2)
+DESCRIPTION="Macromedia Flash decoding library"
+HOMEPAGE="http://swfdec.freedesktop.org"
+SRC_URI="http://swfdec.freedesktop.org/download/${PN}/${MY_PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE="alsa doc ffmpeg gstreamer gtk oss pulseaudio"
+
+RDEPEND=">=dev-libs/glib-2.12
+	>=dev-libs/liboil-0.3.1
+	>=x11-libs/pango-1.16.4
+	gtk? (
+		>=x11-libs/gtk+-2.8.0
+		net-libs/libsoup:2.4
+		)
+	>=x11-libs/cairo-1.2
+	gstreamer? (
+		>=media-libs/gstreamer-0.10.11
+		>=media-libs/gst-plugins-base-0.10.15
+		ffmpeg? ( media-plugins/gst-plugins-ffmpeg )
+		)
+	alsa? ( >=media-libs/alsa-lib-1.0.12 )
+	pulseaudio? ( media-sound/pulseaudio )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( >=dev-util/gtk-doc-1.6 )"
+
+pkg_setup() {
+	if use !gtk ; then
+		ewarn "swfdec will be built without swfdec-gtk convenience"
+		ewarn "library, which is needed by swfdec-mozilla and"
+		ewarn "swfdec-gnome. Please add 'gtk' to your USE flags"
+		ewarn "unless you really know what you are doing."
+	fi
+
+	if use !gstreamer && use ffmpeg; then
+		ewarn
+		ewarn "The 'ffmpeg' USE flag enables video support via gst-plugins-ffmpeg"
+		ewarn "as such it requires the 'gstreamer' USE flag to be enabled."
+	fi
+
+	confutils_use_conflict oss alsa pulseaudio
+}
+
+src_compile() {
+	local myconf=
+
+	#--with-audio=[auto/alsa/oss/none]
+	use oss && myconf="${myconf} --with-audio=oss"
+	use pulseaudio && myconf="${myconf} --with-audio=pa"
+	use alsa && myconf="${myconf} --with-audio=alsa"
+
+	# bug #216009
+	# avoid writing to /root/.gstreamer-0.10/registry.xml
+	export GST_REGISTRY="${T}"/registry.xml
+	# also avoid loading gconf plugins, which may write to /root/.gconfd
+	export GST_PLUGIN_SYSTEM_PATH="${T}"
+
+	econf \
+		$(use_enable doc gtk-doc) \
+		$(use_enable gstreamer) \
+		$(use_enable gtk) \
+		--disable-ffmpeg \
+		--disable-mad \
+		${myconf} || die "configure failed"
+
+	# bug #216284 image tests are not ready yet
+	cat  >test/image/Makefile <<EOF
+all:
+check:
+install:
+EOF
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "emake install failed"
+	dodoc AUTHORS ChangeLog README
+}