Initial import; ebuild mainly by Thomas Kuther who I'm proxy maintaining the package for.

(Portage version: 2.2_rc8/cvs/Linux 2.6.26.3 x86_64)

1 files changed, 61 insertions, 0 deletions

diff --git a/media-libs/stk/stk-4.3.1.ebuild b/media-libs/stk/stk-4.3.1.ebuild
new file mode 100644
index 000000000000..236358e89563
--- /dev/null
+++ b/media-libs/stk/stk-4.3.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/stk/stk-4.3.1.ebuild,v 1.1 2008/09/17 07:28:34 aballier Exp $
+
+inherit eutils autotools
+
+DESCRIPTION="Synthesis ToolKit in C++"
+HOMEPAGE="http://ccrma.stanford.edu/software/stk/"
+SRC_URI="http://ccrma.stanford.edu/software/stk/release/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="alsa debug doc jack oss"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	dev-lang/perl"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}/${P}-cflags-lib.patch"
+	epatch "${FILESDIR}/${P}-gcc43.patch"
+	epatch "${FILESDIR}/${P}-fpic.patch"
+	epatch "${FILESDIR}/${P}-missing.patch"
+	epatch "${FILESDIR}/${P}-ldflags.patch"
+	eautoreconf
+}
+
+src_compile() {
+	econf \
+		`use_with alsa` \
+		`use_with jack` \
+		`use_with oss` \
+		`use_enable debug` \
+		RAWWAVE_PATH=/usr/share/stk/rawwaves/ \
+		|| die "configure failed!"
+
+	# compile libstk
+	cd src
+	emake || die "make in src failed!"
+}
+
+src_install() {
+	dodoc README
+	# install the lib
+	dolib src/libstk.*
+	# install headers
+	insinto /usr/include/stk
+	doins include/*.h include/*.msg include/*.tbl
+	# install rawwaves
+	insinto /usr/share/stk/rawwaves
+	doins rawwaves/*.raw
+	# install docs
+	if use doc; then
+		dohtml -r doc/html/*
+	fi
+}