Enable multilib support, required for media-video/ffmpeg.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

3 files changed, 99 insertions, 1 deletions

diff --git a/media-libs/libquvi/ChangeLog b/media-libs/libquvi/ChangeLog
index fbbccd2e3b46..7f8efc6a1530 100644
--- a/media-libs/libquvi/ChangeLog
+++ b/media-libs/libquvi/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/libquvi
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libquvi/ChangeLog,v 1.34 2014/03/04 20:42:46 vincent Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libquvi/ChangeLog,v 1.35 2014/06/15 13:51:02 mgorny Exp $
+
+*libquvi-0.4.1-r2 (15 Jun 2014)
+*libquvi-0.9.4-r1 (15 Jun 2014)
+
+  15 Jun 2014; Michał Górny <mgorny@gentoo.org> +libquvi-0.4.1-r2.ebuild,
+  +libquvi-0.9.4-r1.ebuild:
+  Enable multilib support, required for media-video/ffmpeg.
 
   04 Mar 2014; Vicente Olivert Riera <vincent@gentoo.org> libquvi-0.4.1.ebuild:
   Add ~mips keyword.
diff --git a/media-libs/libquvi/libquvi-0.4.1-r2.ebuild b/media-libs/libquvi/libquvi-0.4.1-r2.ebuild
new file mode 100644
index 000000000000..e51c4f2c3af1
--- /dev/null
+++ b/media-libs/libquvi/libquvi-0.4.1-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libquvi/libquvi-0.4.1-r2.ebuild,v 1.1 2014/06/15 13:51:02 mgorny Exp $
+
+EAPI=5
+
+inherit autotools-utils multilib-minimal
+
+DESCRIPTION="Library for parsing video download links"
+HOMEPAGE="http://quvi.sourceforge.net/"
+SRC_URI="mirror://sourceforge/quvi/${PV:0:3}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0.4"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="examples static-libs"
+
+RDEPEND=">=net-misc/curl-7.18.2[${MULTILIB_USEDEP}]
+	!<media-libs/quvi-0.4.0
+	>=media-libs/libquvi-scripts-0.4.0:0.4[${MULTILIB_USEDEP}]
+	>=dev-lang/lua-5.1[deprecated,${MULTILIB_USEDEP}]
+	!=media-libs/libquvi-0.4*:0"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--without-manual
+	)
+	autotools-utils_src_configure
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+
+	if use examples ; then
+		docinto examples
+		dodoc examples/*.{c,h}
+	fi
+}
diff --git a/media-libs/libquvi/libquvi-0.9.4-r1.ebuild b/media-libs/libquvi/libquvi-0.9.4-r1.ebuild
new file mode 100644
index 000000000000..11730077e371
--- /dev/null
+++ b/media-libs/libquvi/libquvi-0.9.4-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libquvi/libquvi-0.9.4-r1.ebuild,v 1.1 2014/06/15 13:51:02 mgorny Exp $
+
+EAPI=5
+AUTOTOOLS_AUTORECONF=1
+
+inherit autotools-utils multilib-minimal
+
+DESCRIPTION="Library for parsing video download links"
+HOMEPAGE="http://quvi.sourceforge.net/"
+SRC_URI="mirror://sourceforge/quvi/${PV:0:3}/${P}.tar.xz"
+
+LICENSE="AGPL-3"
+SLOT="0/8" # subslot = libquvi soname version
+KEYWORDS="~amd64 ~arm ~hppa ~x86"
+IUSE="examples nls static-libs"
+
+RDEPEND="!<media-libs/quvi-0.4.0
+	>=dev-libs/glib-2.24.2:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libgcrypt-1.4.5:0=[${MULTILIB_USEDEP}]
+	>=media-libs/libquvi-scripts-0.9[${MULTILIB_USEDEP}]
+	>=net-libs/libproxy-0.3.1[${MULTILIB_USEDEP}]
+	>=net-misc/curl-7.21.0[${MULTILIB_USEDEP}]
+	>=dev-lang/lua-5.1[deprecated,${MULTILIB_USEDEP}]
+	nls? ( virtual/libintl[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+	nls? ( sys-devel/gettext )"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.9.1-headers-reinstall.patch )
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable nls)
+		--with-manual
+	)
+	autotools-utils_src_configure
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+
+	use examples && dodoc -r examples
+}