Version bump.

(Portage version: 2.2.0_alpha116/cvs/Linux x86_64)

3 files changed, 90 insertions, 1 deletions

diff --git a/media-libs/libpng/ChangeLog b/media-libs/libpng/ChangeLog
index b22efffa157f..e7adb0ed6d76 100644
--- a/media-libs/libpng/ChangeLog
+++ b/media-libs/libpng/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/libpng
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.369 2012/06/16 15:58:39 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.370 2012/07/13 12:45:05 ssuominen Exp $
+
+*libpng-1.5.12 (13 Jul 2012)
+*libpng-1.2.50 (13 Jul 2012)
+
+  13 Jul 2012; Samuli Suominen <ssuominen@gentoo.org> +libpng-1.2.50.ebuild,
+  +libpng-1.5.12.ebuild:
+  Version bump.
 
 *libpng-1.5.11 (16 Jun 2012)
 
diff --git a/media-libs/libpng/libpng-1.2.50.ebuild b/media-libs/libpng/libpng-1.2.50.ebuild
new file mode 100644
index 000000000000..7d42b9960255
--- /dev/null
+++ b/media-libs/libpng/libpng-1.2.50.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.2.50.ebuild,v 1.1 2012/07/13 12:45:05 ssuominen Exp $
+
+# this ebuild is only for the libpng12.so.0 SONAME for ABI compat
+
+EAPI=4
+
+inherit multilib libtool
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+
+LICENSE="as-is"
+SLOT="1.2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE=""
+
+RDEPEND="sys-libs/zlib
+	!=media-libs/libpng-1.2*:0"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils"
+
+src_prepare() {
+	elibtoolize
+}
+
+src_configure() {
+	econf --disable-static
+}
+
+src_compile() {
+	emake libpng12.la
+}
+
+src_install() {
+	newlib.so .libs/libpng12.so.0.* libpng12.so.0
+}
diff --git a/media-libs/libpng/libpng-1.5.12.ebuild b/media-libs/libpng/libpng-1.5.12.ebuild
new file mode 100644
index 000000000000..93edb65baf07
--- /dev/null
+++ b/media-libs/libpng/libpng-1.5.12.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.5.12.ebuild,v 1.1 2012/07/13 12:45:05 ssuominen Exp $
+
+EAPI=4
+
+inherit eutils libtool
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? ( mirror://sourceforge/${PN}-apng/${PN}-1.5.11-apng.patch.gz )"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="apng neon static-libs"
+
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils"
+
+DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
+
+src_prepare() {
+	if use apng; then
+		epatch "${WORKDIR}"/${PN}-*-apng.patch
+		# Don't execute symbols check with apng patch wrt #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable neon arm-neon)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}