Version bump and remove old.

(Portage version: 2.2.0_alpha28/cvs/Linux x86_64)

3 files changed, 81 insertions, 79 deletions

diff --git a/media-libs/libmediainfo/ChangeLog b/media-libs/libmediainfo/ChangeLog
index 9a45491ea784..a3bdcd9b73b9 100644
--- a/media-libs/libmediainfo/ChangeLog
+++ b/media-libs/libmediainfo/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libmediainfo
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.12 2011/03/24 08:48:01 tomka Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.13 2011/03/28 19:00:24 radhermit Exp $
+
+*libmediainfo-0.7.43 (28 Mar 2011)
+
+  28 Mar 2011; Tim Harder <radhermit@gentoo.org>
+  -libmediainfo-0.7.36-r1.ebuild, +libmediainfo-0.7.43.ebuild:
+  Version bump and remove old.
 
   24 Mar 2011; Thomas Kahle <tomka@gentoo.org> libmediainfo-0.7.41.ebuild:
   x86 stable per bug 357575
diff --git a/media-libs/libmediainfo/libmediainfo-0.7.36-r1.ebuild b/media-libs/libmediainfo/libmediainfo-0.7.36-r1.ebuild
deleted file mode 100644
index 63c121ba753c..000000000000
--- a/media-libs/libmediainfo/libmediainfo-0.7.36-r1.ebuild
+++ /dev/null
@@ -1,78 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.36-r1.ebuild,v 1.3 2011/01/31 19:06:53 fauli Exp $
-
-EAPI="2"
-
-inherit autotools multilib
-
-MY_PN="MediaInfo"
-DESCRIPTION="MediaInfo libraries"
-HOMEPAGE="http://mediainfo.sourceforge.net/"
-SRC_URI="mirror://sourceforge/mediainfo/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"
-
-S="${WORKDIR}/${MY_PN}Lib/Project/GNU/Library"
-
-LICENSE="LGPL-3"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="curl debug doc libmms static-libs"
-
-RDEPEND="sys-libs/zlib
-	>=media-libs/libzen-0.4.14[static-libs=]
-	curl? ( net-misc/curl )
-	libmms? ( >=media-libs/libmms-0.4 )"
-DEPEND="${RDEPEND}
-	dev-util/pkgconfig
-	doc? ( app-doc/doxygen )"
-
-src_prepare() {
-	# https://bugs.launchpad.net/libmms/+bug/531326
-	sed -i -e 's/mmsx/mms/g' \
-		"${WORKDIR}/${MY_PN}Lib/Source/MediaInfo/Reader/Reader_libmms.cpp" \
-		|| die "sed failed"
-
-	# Fix linking problem for bug #343125
-	sed -i -e "s:\(#define LIBCURL_DLL_RUNTIME\)://\1:" \
-		"${WORKDIR}/${MY_PN}Lib/Source/MediaInfo/Reader/Reader_libcurl.cpp" \
-		|| die "sed failed"
-
-	eautoreconf
-}
-
-src_configure() {
-	econf \
-		--disable-dependency-tracking \
-		--enable-shared \
-		$(use_enable debug) \
-		$(use_with curl libcurl) \
-		$(use_with libmms) \
-		$(use_enable static-libs static) \
-		$(use_enable static-libs staticlibs)
-}
-
-src_compile() {
-	emake || die "emake failed"
-	if use doc; then
-		cd "${WORKDIR}/${MY_PN}Lib/Source/Doc"
-		doxygen Doxyfile || die "doxygen failed"
-	fi
-}
-
-src_install() {
-	emake DESTDIR="${D}" install || die "emake install failed"
-
-	insinto "/usr/$(get_libdir)/pkgconfig"
-	doins "${PN}.pc" || die
-
-	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
-		insinto "/usr/include/${MY_PN}/${x}"
-		doins "${WORKDIR}/${MY_PN}Lib/Source/${MY_PN}/${x}/"*.h || die
-	done
-
-	dodoc "${WORKDIR}/${MY_PN}Lib/"*.txt
-	if use doc; then
-		dohtml "${WORKDIR}/${MY_PN}Lib/Source/Doc/Documentation.html" || die
-		dohtml -r "${WORKDIR}/${MY_PN}Lib/Doc" || die
-	fi
-}
diff --git a/media-libs/libmediainfo/libmediainfo-0.7.43.ebuild b/media-libs/libmediainfo/libmediainfo-0.7.43.ebuild
new file mode 100644
index 000000000000..57f4cb4083a9
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-0.7.43.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.43.ebuild,v 1.1 2011/03/28 19:00:24 radhermit Exp $
+
+EAPI="4"
+
+inherit autotools-utils multilib eutils
+
+MY_PN="MediaInfo"
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="http://mediainfo.sourceforge.net/"
+SRC_URI="mirror://sourceforge/mediainfo/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl debug doc libmms static-libs"
+
+RDEPEND="sys-libs/zlib
+	>=media-libs/libzen-0.4.18[static-libs=]
+	curl? ( net-misc/curl )
+	libmms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
+S="${WORKDIR}/${MY_PN}Lib/Project/GNU/Library"
+
+src_prepare() {
+	# Fix linking problem for bug #343125
+	EPATCH_OPTS="-p1 -d ${WORKDIR}/${MY_PN}Lib" epatch "${FILESDIR}"/${PN}-0.7.41-curl.patch
+
+	# Don't force -O2 by default
+	sed -i -e "s:-O2::" configure.ac
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs
+	myeconfargs=(
+		$(use_with curl libcurl)
+		$(use_with libmms)
+		$(use_enable static-libs staticlibs)
+	)
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile
+	if use doc; then
+		cd "${WORKDIR}/${MY_PN}Lib/Source/Doc"
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins "${S}"/${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+	if use doc; then
+		dohtml -r "${WORKDIR}"/${MY_PN}Lib/Doc/*
+	fi
+}