Version bump.

(Portage version: 2.2.0_alpha92/cvs/Linux x86_64)

2 files changed, 89 insertions, 1 deletions

diff --git a/media-libs/libbluray/ChangeLog b/media-libs/libbluray/ChangeLog
index 606e48b3c179..ead1a3808714 100644
--- a/media-libs/libbluray/ChangeLog
+++ b/media-libs/libbluray/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libbluray
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/ChangeLog,v 1.26 2012/02/29 11:21:35 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/ChangeLog,v 1.27 2012/03/26 01:08:24 radhermit Exp $
+
+*libbluray-0.2.2 (26 Mar 2012)
+
+  26 Mar 2012; Tim Harder <radhermit@gentoo.org> +libbluray-0.2.2.ebuild:
+  Version bump.
 
   29 Feb 2012; Samuli Suominen <ssuominen@gentoo.org>
   -libbluray-0.0.1_pre20110819.ebuild:
diff --git a/media-libs/libbluray/libbluray-0.2.2.ebuild b/media-libs/libbluray/libbluray-0.2.2.ebuild
new file mode 100644
index 000000000000..bd1ea49b230d
--- /dev/null
+++ b/media-libs/libbluray/libbluray-0.2.2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libbluray/libbluray-0.2.2.ebuild,v 1.1 2012/03/26 01:08:24 radhermit Exp $
+
+EAPI=4
+
+inherit autotools java-pkg-opt-2 flag-o-matic
+
+DESCRIPTION="Blu-ray playback libraries"
+HOMEPAGE="http://www.videolan.org/developers/libbluray.html"
+SRC_URI="ftp://ftp.videolan.org/pub/videolan/libbluray/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="aacs java static-libs utils +xml"
+
+COMMON_DEPEND="
+	xml? ( dev-libs/libxml2 )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	aacs? ( media-libs/libaacs )
+	java? ( >=virtual/jre-1.6 )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	java? (
+		>=virtual/jdk-1.6
+		dev-java/ant-core
+	)
+	dev-util/pkgconfig
+"
+REQUIRED_USE="utils? ( static-libs )"
+
+DOCS=( ChangeLog README.txt )
+
+src_prepare() {
+	use java && export JDK_HOME="$(java-config -g JAVA_HOME)"
+	eautoreconf
+
+	java-pkg-opt-2_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+	if use java; then
+		export JAVACFLAGS="$(java-pkg_javac-args)"
+		append-cflags "$(java-pkg_get-jni-cflags)"
+		myconf="--with-jdk=${JDK_HOME}"
+	fi
+
+	use xml && myconf+=" --enable-libxml2"
+
+	econf \
+		--disable-debug \
+		--disable-optimizations \
+		$(use_enable java bdjava) \
+		$(use_enable static-libs static) \
+		$(use_enable utils examples) \
+		${myconf}
+}
+
+src_install() {
+	default
+
+	if use utils; then
+		cd src/examples/
+		dobin clpi_dump index_dump mobj_dump mpls_dump sound_dump
+		cd .libs/
+		dobin bd_info bdsplice hdmv_test libbluray_test list_titles
+		if use java; then
+			dobin bdj_test
+		fi
+	fi
+
+	if use java; then
+		java-pkg_dojar "${S}/src/.libs/${PN}.jar"
+		doenvd "${FILESDIR}"/90${PN}
+	fi
+
+	use static-libs || find "${ED}" -name '*.la' -exec rm -f '{}' +
+}