Version bump with USE="static-libs" and removed libtool files.

(Portage version: 2.2.0_alpha88/cvs/Linux x86_64)

2 files changed, 72 insertions, 2 deletions

diff --git a/media-libs/imlib2/ChangeLog b/media-libs/imlib2/ChangeLog
index 33d734a7fa5c..07fadac2c24e 100644
--- a/media-libs/imlib2/ChangeLog
+++ b/media-libs/imlib2/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/imlib2
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/imlib2/ChangeLog,v 1.106 2011/07/21 04:01:44 vapier Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/imlib2/ChangeLog,v 1.107 2012/02/21 06:54:16 ssuominen Exp $
+
+*imlib2-1.4.5 (21 Feb 2012)
+
+  21 Feb 2012; Samuli Suominen <ssuominen@gentoo.org> +imlib2-1.4.5.ebuild:
+  Version bump with USE="static-libs" and removed libtool files.
 
   21 Jul 2011; Mike Frysinger <vapier@gentoo.org> imlib2-1.4.4.ebuild:
   Pull in pkg-config for png support #375195.
diff --git a/media-libs/imlib2/imlib2-1.4.5.ebuild b/media-libs/imlib2/imlib2-1.4.5.ebuild
new file mode 100644
index 000000000000..02a3d61c4120
--- /dev/null
+++ b/media-libs/imlib2/imlib2-1.4.5.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/imlib2/imlib2-1.4.5.ebuild,v 1.1 2012/02/21 06:54:16 ssuominen Exp $
+
+EAPI=4
+inherit enlightenment toolchain-funcs
+
+DESCRIPTION="Version 2 of an advanced replacement library for libraries like libXpm"
+HOMEPAGE="http://www.enlightenment.org/"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="X bzip2 gif jpeg mmx mp3 png static-libs tiff zlib"
+
+RDEPEND="=media-libs/freetype-2*
+	bzip2? ( app-arch/bzip2 )
+	zlib? ( sys-libs/zlib )
+	gif? ( >=media-libs/giflib-4.1.0 )
+	png? ( media-libs/libpng:0 )
+	jpeg? ( virtual/jpeg )
+	tiff? ( media-libs/tiff:0 )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+		)
+	mp3? ( media-libs/libid3tag )"
+DEPEND="${RDEPEND}
+	png? ( dev-util/pkgconfig )
+	X? (
+		x11-proto/xextproto
+		x11-proto/xproto
+		)"
+
+src_configure() {
+	# imlib2 has diff configure options for x86/amd64 mmx
+	local myconf
+	if [[ $(tc-arch) == amd64 ]]; then
+		myconf="$(use_enable mmx amd64) --disable-mmx"
+	else
+		myconf="--disable-amd64 $(use_enable mmx)"
+	fi
+
+	[[ $(gcc-major-version) -ge 4 ]] && myconf="${myconf} --enable-visibility-hiding"
+
+	export MY_ECONF="
+		$(use_enable static-libs static)
+		$(use_with X x)
+		$(use_with jpeg)
+		$(use_with png)
+		$(use_with tiff)
+		$(use_with gif)
+		$(use_with zlib)
+		$(use_with bzip2)
+		$(use_with mp3 id3)
+		${myconf}
+		"
+
+	enlightenment_src_configure
+}
+
+src_install() {
+	enlightenment_src_install
+
+	# enlightenment_src_install should take care of this for us, but it doesn't
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}