Add patch to fix unicode16 writing. Thanks for the users in bug #130922.

(Portage version: 2.1.2_pre2-r3)

1 files changed, 64 insertions, 0 deletions

diff --git a/media-libs/id3lib/id3lib-3.8.3-r5.ebuild b/media-libs/id3lib/id3lib-3.8.3-r5.ebuild
new file mode 100644
index 000000000000..09b564b5153a
--- /dev/null
+++ b/media-libs/id3lib/id3lib-3.8.3-r5.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/id3lib/id3lib-3.8.3-r5.ebuild,v 1.1 2006/10/05 08:06:51 flameeyes Exp $
+
+WANT_AUTOCONF="latest"
+WANT_AUTOMAKE="latest"
+
+inherit eutils autotools
+
+MY_P=${P/_/}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="Id3 library for C/C++"
+HOMEPAGE="http://id3lib.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc examples"
+
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	epatch "${FILESDIR}/${P}-zlib.patch"
+	epatch "${FILESDIR}/${P}-test_io.patch"
+	epatch "${FILESDIR}/${P}-autoconf259.patch"
+	epatch "${FILESDIR}/${P}-doxyinput.patch"
+	epatch "${FILESDIR}/${P}-unicode16.patch"
+
+	AT_M4DIR="${S}/m4" eautoreconf
+}
+
+src_compile() {
+	econf || die "econf failed"
+	emake || die "emake failed"
+
+	if use doc; then
+		cd doc/
+		doxygen Doxyfile || die "doxygen failed"
+	fi
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "Install failed"
+
+	dodoc AUTHORS ChangeLog HISTORY README THANKS TODO
+
+	# some example programs to be placed in docs dir.
+	if use examples; then
+		cp -pPR examples ${D}/usr/share/doc/${PF}/examples
+		cd ${D}/usr/share/doc/${PF}/examples
+		make distclean
+	fi
+
+	if use doc; then
+		dohtml -r doc
+	fi
+}