Version bump. Add python handling for testsuite (still broken). Drop unneeded blocker since the file is now slotted properly.

(Portage version: 2.2.0_alpha141/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 98 insertions, 1 deletions

diff --git a/media-libs/grilo/ChangeLog b/media-libs/grilo/ChangeLog
index 3163af4552f0..2a78ea78832d 100644
--- a/media-libs/grilo/ChangeLog
+++ b/media-libs/grilo/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/grilo
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/grilo/ChangeLog,v 1.10 2012/10/04 14:56:33 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/grilo/ChangeLog,v 1.11 2012/10/28 15:10:36 eva Exp $
+
+*grilo-0.2.2 (28 Oct 2012)
+
+  28 Oct 2012; Gilles Dartiguelongue <eva@gentoo.org> +grilo-0.2.2.ebuild:
+  Version bump. Add python handling for testsuite (still broken). Drop unneeded
+  blocker since the file is now slotted properly.
 
   04 Oct 2012; Agostino Sarubbo <ago@gentoo.org> grilo-0.1.18-r1.ebuild:
   Stable for amd64, wrt bug #427544
diff --git a/media-libs/grilo/grilo-0.2.2.ebuild b/media-libs/grilo/grilo-0.2.2.ebuild
new file mode 100644
index 000000000000..44104519a71c
--- /dev/null
+++ b/media-libs/grilo/grilo-0.2.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/grilo/grilo-0.2.2.ebuild,v 1.1 2012/10/28 15:10:36 eva Exp $
+
+EAPI="4"
+GCONF_DEBUG="no" # --enable-debug only changes CFLAGS
+GNOME2_LA_PUNT="yes"
+PYTHON_DEPEND="test? 2"
+VALA_MIN_API_VERSION="0.12"
+VALA_MAX_API_VERSION="0.18" # explicitly specified in configure
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala python
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://live.gnome.org/Grilo"
+
+LICENSE="LGPL-2.1"
+SLOT="0.2"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk examples +introspection +network test vala"
+
+RDEPEND=">=dev-libs/glib-2.29.10:2
+	dev-libs/libxml2:2
+	gtk? ( >=x11-libs/gtk+-3:3 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9 )
+	network? ( >=net-libs/libsoup-2.33.4:2.4 )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/gtk-doc-am-1.10
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+	test? (
+		dev-python/pygobject:2[introspection?]
+		media-plugins/grilo-plugins:0.2 )"
+# eautoreconf requires gnome-common
+
+# Tests fail horribly, but return 0
+RESTRICT="test"
+
+pkg_setup() {
+	if use test; then
+		python_pkg_setup
+		python_set_active_version 2
+	fi
+}
+
+src_prepare() {
+	DOCS="AUTHORS NEWS README TODO"
+	# --enable-debug only changes CFLAGS, useless for us
+	G2CONF="${G2CONF}
+		--disable-maintainer-mode
+		--disable-static
+		--disable-debug
+		$(use_enable gtk test-ui)
+		$(use_enable introspection)
+		$(use_enable network grl-net)
+		$(use_enable test tests)
+		$(use_enable vala)"
+
+	# Don't build examples
+	sed -e '/SUBDIRS/s/examples//' \
+		-i Makefile.am -i Makefile.in || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_test() {
+	if use introspection; then
+		# Fails to import constants ???
+		emake -C tests/python check PYTHON=$(PYTHON -2)
+	fi
+}
+
+src_install() {
+	gnome2_src_install
+	# Upstream made this conditional on gtk-doc build...
+	emake -C doc install DESTDIR="${ED}"
+
+	# Prevent file collision with other slot
+	if use vala; then
+		mv "${ED}usr/bin/grilo-simple-playlist" \
+			"${ED}usr/bin/grilo-simple-playlist-${SLOT}" || die
+	fi
+
+	if use examples; then
+		# Install example code
+		insinto /usr/share/doc/${PF}/examples
+		doins "${S}"/examples/*.c
+	fi
+}