version bump

Signed-off-by: aballier@gentoo.org
(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

2 files changed, 110 insertions, 1 deletions

diff --git a/media-libs/aubio/ChangeLog b/media-libs/aubio/ChangeLog
index aecf23ef28ef..f8d759abd210 100644
--- a/media-libs/aubio/ChangeLog
+++ b/media-libs/aubio/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/aubio
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/aubio/ChangeLog,v 1.30 2015/01/03 11:00:24 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/aubio/ChangeLog,v 1.31 2015/03/11 09:22:54 aballier Exp $
+
+*aubio-0.4.1 (11 Mar 2015)
+
+  11 Mar 2015; Alexis Ballier <aballier@gentoo.org> +aubio-0.4.1.ebuild:
+  version bump
 
 *aubio-0.4.0-r1 (03 Jan 2015)
 
diff --git a/media-libs/aubio/aubio-0.4.1.ebuild b/media-libs/aubio/aubio-0.4.1.ebuild
new file mode 100644
index 000000000000..378f927c2a16
--- /dev/null
+++ b/media-libs/aubio/aubio-0.4.1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/aubio/aubio-0.4.1.ebuild,v 1.1 2015/03/11 09:22:54 aballier Exp $
+
+EAPI=5
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE='threads(+)'
+
+inherit distutils-r1 waf-utils multilib
+
+DESCRIPTION="Library for audio labelling"
+HOMEPAGE="http://aubio.org/"
+SRC_URI="http://aubio.org//pub/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc double-precision examples ffmpeg fftw jack libsamplerate sndfile python"
+
+RDEPEND="
+	ffmpeg? ( virtual/ffmpeg )
+	fftw? ( sci-libs/fftw:3.0 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	libsamplerate? ( media-libs/libsamplerate )
+	python? ( dev-python/numpy[${PYTHON_USEDEP}] ${PYTHON_DEPS} )
+	sndfile? ( media-libs/libsndfile )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	app-text/txt2man
+	doc? ( app-doc/doxygen )"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+DOCS=( AUTHORS ChangeLog README.md )
+PYTHON_SRC_DIR="${S}/python"
+
+src_prepare() {
+	sed -i -e "s:\/lib:\/$(get_libdir):" src/wscript_build || die
+	sed -i -e "s:doxygen:doxygen_disabled:" wscript || die
+}
+
+src_configure() {
+	python_setup
+	waf-utils_src_configure \
+		--enable-complex \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		$(use_enable double-precision double) \
+		$(use_enable fftw fftw3f) \
+		$(use_enable fftw fftw3) \
+		$(use_enable ffmpeg avcodec) \
+		$(use_enable jack) \
+		$(use_enable libsamplerate samplerate) \
+		$(use_enable sndfile)
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_configure
+	fi
+}
+
+src_compile() {
+	waf-utils_src_compile --notests
+
+	if use doc; then
+		cd "${S}"/doc || die
+		doxygen full.cfg || die
+	fi
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_compile
+	fi
+}
+
+src_test() {
+	waf-utils_src_compile --alltests
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_test
+	fi
+}
+
+src_install() {
+	waf-utils_src_install
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		DOCS="" distutils-r1_src_install
+		newdoc README README.python
+	fi
+
+	if use doc; then
+		dohtml -r doc/full/html/.
+		dodoc doc/*.txt
+	fi
+
+	if use examples; then
+		# install dist_noinst_SCRIPTS from Makefile.am
+		dodoc -r examples
+	fi
+}