Version bump. See ChangeLog for details

(Portage version: 2.2.0_alpha64/cvs/Linux x86_64)

2 files changed, 159 insertions, 1 deletions

diff --git a/media-gfx/imagemagick/ChangeLog b/media-gfx/imagemagick/ChangeLog
index bf362874dab3..9f323f7cb40a 100644
--- a/media-gfx/imagemagick/ChangeLog
+++ b/media-gfx/imagemagick/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-gfx/imagemagick
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/ChangeLog,v 1.444 2011/09/24 16:49:49 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/ChangeLog,v 1.445 2011/10/10 22:00:28 ssuominen Exp $
+
+*imagemagick-6.7.3.0 (10 Oct 2011)
+
+  10 Oct 2011; Samuli Suominen <ssuominen@gentoo.org>
+  +imagemagick-6.7.3.0.ebuild:
+  Version bump wrt #385427 by Kamen Dokov. Improve USE="opencl" logic wrt
+  #381281 by Sergey Parubochiy. Change --without-corefonts to
+  --without-windows-font-dir by Agostino Sarubbo.
 
   24 Sep 2011; Raúl Porcel <armin76@gentoo.org> imagemagick-6.7.1.0.ebuild:
   alpha/ia64/s390/sh/sparc stable wrt #378543
diff --git a/media-gfx/imagemagick/imagemagick-6.7.3.0.ebuild b/media-gfx/imagemagick/imagemagick-6.7.3.0.ebuild
new file mode 100644
index 000000000000..82e575573054
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-6.7.3.0.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/imagemagick/imagemagick-6.7.3.0.ebuild,v 1.1 2011/10/10 22:00:28 ssuominen Exp $
+
+EAPI=4
+inherit multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="autotrace bzip2 +corefonts cxx djvu fftw fontconfig fpx graphviz gs hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp perl png q32 q64 q8 raw static-libs svg tiff truetype video_cards_nvidia webp wmf X xml zlib"
+
+# libtool is required for loading plugins
+RDEPEND=">=sys-devel/libtool-2.2.6b
+	autotrace? ( >=media-gfx/autotrace-0.31.1 )
+	bzip2? ( app-arch/bzip2 )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( >=media-gfx/graphviz-2.6 )
+	gs? ( app-text/ghostscript-gpl )
+	jbig? ( media-libs/jbigkit )
+	jpeg? ( virtual/jpeg )
+	jpeg2k? ( media-libs/jasper )
+	lcms? ( media-libs/lcms:2 )
+	lqr? ( >=media-libs/liblqr-0.1.0 )
+	opencl? ( video_cards_nvidia? ( x11-drivers/nvidia-drivers >=dev-util/nvidia-cuda-toolkit-3.1 ) )
+	openexr? ( media-libs/openexr )
+	perl? ( >=dev-lang/perl-5.8.6-r6 )
+	png? ( >=media-libs/libpng-1.4 )
+	raw? ( media-gfx/ufraw )
+	svg? ( >=gnome-base/librsvg-2.9.0 )
+	tiff? ( >=media-libs/tiff-3.5.5 )
+	truetype? ( media-libs/freetype:2
+		corefonts? ( media-fonts/corefonts ) )
+	webp? ( media-libs/libwebp )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	X? (
+		x11-libs/libXext
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM
+	)
+	xml? ( >=dev-libs/libxml2-2.4.10 )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib )
+	!dev-perl/perlmagick
+	!media-gfx/graphicsmagick[imagemagick]"
+DEPEND="${RDEPEND}
+	>=sys-apps/sed-4
+	X? ( x11-proto/xextproto )"
+
+S=${WORKDIR}/${MY_P}
+
+RESTRICT="perl? ( userpriv )"
+
+DOCS=( AUTHORS.txt ChangeLog NEWS.txt README.txt )
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+	use q64 && depth=64
+
+	local opencl=disable
+	if use opencl && use video_cards_nvidia; then
+		opencl=enable
+	fi
+
+	local openmp=disable
+	if use openmp && tc-has-openmp; then
+		openmp=enable
+	fi
+
+	local myconf="--without-windows-font-dir"
+	if use truetype; then
+		myconf="$(use_with corefonts windows-font-dir /usr/share/fonts/corefonts)"
+	fi
+
+	econf \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		$(use_enable static-libs static) \
+		$(use_enable hdri) \
+		--${opencl}-opencl \
+		--with-threads \
+		--without-included-ltdl \
+		--with-ltdl-include="${EPREFIX}/usr/include" \
+		--with-ltdl-lib="${EPREFIX}/usr/$(get_libdir)" \
+		--with-modules \
+		--with-quantum-depth=${depth} \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options='INSTALLDIRS=vendor' \
+		--with-gs-font-dir="${EPREFIX}/usr/share/fonts/default/ghostscript" \
+		$(use_with bzip2 bzlib) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		$(use_with autotrace) \
+		$(use_with gs dps) \
+		$(use_with djvu) \
+		--with-dejavu-font-dir="${EPREFIX}/usr/share/fonts/dejavu" \
+		$(use_with fftw) \
+		$(use_with fpx) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_with gs gslib) \
+		$(use_with graphviz gvc) \
+		$(use_with jbig) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k jp2) \
+		--without-lcms \
+		$(use_with lcms lcms2) \
+		$(use_with lqr) \
+		$(use_with lzma) \
+		$(use_with openexr) \
+		$(use_with png) \
+		$(use_with svg rsvg) \
+		$(use_with tiff) \
+		$(use_with webp) \
+		${myconf} \
+		$(use_with wmf) \
+		$(use_with xml) \
+		--${openmp}-openmp
+}
+
+src_test() {
+	if has_version ~${CATEGORY}/${P}; then
+		emake -j1 check
+	else
+		ewarn "Skipping tests because installed version doesn't match."
+	fi
+}
+
+src_install() {
+	default
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -delete
+		find "${ED}" -depth -mindepth 1 -type d -empty -delete
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}