version bump; ebuild maintenance wrt bug #510004

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key BD3A97A3)

4 files changed, 93 insertions, 15 deletions

diff --git a/mate-base/mate-settings-daemon/ChangeLog b/mate-base/mate-settings-daemon/ChangeLog
index f62594fc1064..59e581c26c28 100644
--- a/mate-base/mate-settings-daemon/ChangeLog
+++ b/mate-base/mate-settings-daemon/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for mate-base/mate-settings-daemon
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-settings-daemon/ChangeLog,v 1.9 2014/07/02 09:47:05 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-settings-daemon/ChangeLog,v 1.10 2014/12/09 01:07:11 tamiko Exp $
+
+*mate-settings-daemon-1.8.2 (09 Dec 2014)
+
+  09 Dec 2014; Matthias Maier <tamiko@gentoo.org>
+  +mate-settings-daemon-1.8.2.ebuild, mate-settings-daemon-1.6.2.ebuild,
+  mate-settings-daemon-1.8.1.ebuild:
+  version bump; ebuild maintenance wrt bug #510004
 
   02 Jul 2014; Pacho Ramos <pacho@gentoo.org> mate-settings-daemon-1.8.1.ebuild:
   x86 stable, bug 513714
diff --git a/mate-base/mate-settings-daemon/mate-settings-daemon-1.6.2.ebuild b/mate-base/mate-settings-daemon/mate-settings-daemon-1.6.2.ebuild
index 09842f2837d4..4173fb19cd5a 100644
--- a/mate-base/mate-settings-daemon/mate-settings-daemon-1.6.2.ebuild
+++ b/mate-base/mate-settings-daemon/mate-settings-daemon-1.6.2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-settings-daemon/mate-settings-daemon-1.6.2.ebuild,v 1.4 2014/05/04 14:54:11 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-settings-daemon/mate-settings-daemon-1.6.2.ebuild,v 1.5 2014/12/09 01:07:11 tamiko Exp $
 
 EAPI="5"
 
@@ -77,12 +77,6 @@ src_configure() {
 		$(use_enable !pulseaudio gstreamer) \
 		$(use_enable smartcard smartcard-support) \
 		$(use_with X x)
-
-	if use pulseaudio; then
-		elog "Building volume media keys using Pulseaudio"
-	else
-		elog "Building volume media keys using GStreamer"
-	fi
 }
 
 DOCS="AUTHORS NEWS ChangeLog"
diff --git a/mate-base/mate-settings-daemon/mate-settings-daemon-1.8.1.ebuild b/mate-base/mate-settings-daemon/mate-settings-daemon-1.8.1.ebuild
index 9ad8f53a7f8e..fac4fa05097f 100644
--- a/mate-base/mate-settings-daemon/mate-settings-daemon-1.8.1.ebuild
+++ b/mate-base/mate-settings-daemon/mate-settings-daemon-1.8.1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-settings-daemon/mate-settings-daemon-1.8.1.ebuild,v 1.4 2014/07/02 09:47:05 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-settings-daemon/mate-settings-daemon-1.8.1.ebuild,v 1.5 2014/12/09 01:07:11 tamiko Exp $
 
 EAPI="5"
 
@@ -78,12 +78,6 @@ src_configure() {
 		$(use_enable !pulseaudio gstreamer) \
 		$(use_enable smartcard smartcard-support) \
 		$(use_with X x)
-
-	if use pulseaudio; then
-		elog "Building volume media keys using Pulseaudio"
-	else
-		elog "Building volume media keys using GStreamer"
-	fi
 }
 
 DOCS="AUTHORS NEWS ChangeLog"
diff --git a/mate-base/mate-settings-daemon/mate-settings-daemon-1.8.2.ebuild b/mate-base/mate-settings-daemon/mate-settings-daemon-1.8.2.ebuild
new file mode 100644
index 000000000000..3760ff343e5c
--- /dev/null
+++ b/mate-base/mate-settings-daemon/mate-settings-daemon-1.8.2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-settings-daemon/mate-settings-daemon-1.8.2.ebuild,v 1.1 2014/12/09 01:07:11 tamiko Exp $
+
+EAPI="5"
+
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2 versionator
+
+MATE_BRANCH="$(get_version_component_range 1-2)"
+
+SRC_URI="http://pub.mate-desktop.org/releases/${MATE_BRANCH}/${P}.tar.xz"
+DESCRIPTION="MATE Settings Daemon"
+HOMEPAGE="http://mate-desktop.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="X debug libnotify policykit pulseaudio smartcard"
+
+RDEPEND=">=dev-libs/dbus-glib-0.74:0
+	>=dev-libs/glib-2.17.3:2
+	>=mate-base/libmatekbd-1.6.1:0
+	>=mate-base/mate-desktop-1.8.1:0
+	media-libs/fontconfig:1.0
+	>=gnome-base/dconf-0.13.4:0
+	x11-libs/cairo:0
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-2.24:2
+	x11-libs/libX11:0
+	x11-libs/libXi:0
+	x11-libs/libXext:0
+	x11-libs/libXxf86misc:0
+	>=x11-libs/libxklavier-5:0
+	virtual/libintl:0
+	libnotify? ( >=x11-libs/libnotify-0.7:0 )
+	policykit? (
+		>=dev-libs/dbus-glib-0.71:0
+		>=sys-apps/dbus-1.1.2:0
+		>=sys-auth/polkit-0.97:0
+	)
+	pulseaudio? (
+		media-libs/libcanberra:0[gtk]
+		>=media-sound/pulseaudio-0.9.15:0
+	)
+	!pulseaudio? (
+		>=media-libs/gstreamer-0.10.1.2:0.10
+		>=media-libs/gst-plugins-base-0.10.1.2:0.10
+	)
+	smartcard? ( >=dev-libs/nss-3.11.2:0 )"
+
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.37.1:0
+	sys-devel/gettext:0
+	virtual/pkgconfig:0
+	x11-proto/inputproto:0
+	x11-proto/xproto:0"
+
+src_prepare() {
+	# More network filesystems not to monitor, upstream bug #606421
+	epatch "${FILESDIR}/${PN}-1.4.0-netfs-monitor.patch"
+
+	# mouse: Use event driven mode for syndaemon
+	epatch "${FILESDIR}/${PN}-1.2.0-syndaemon-mode.patch"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_with libnotify) \
+		$(use_enable debug) \
+		$(use_enable policykit polkit) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable !pulseaudio gstreamer) \
+		$(use_enable smartcard smartcard-support) \
+		$(use_with X x)
+}
+
+DOCS="AUTHORS NEWS ChangeLog"