version bump, see ChangeLog file for new features

(Portage version: 2.1.4.5)

2 files changed, 255 insertions, 1 deletions

diff --git a/mail-client/claws-mail/ChangeLog b/mail-client/claws-mail/ChangeLog
index ea7f5fe21e50..abe636c38529 100644
--- a/mail-client/claws-mail/ChangeLog
+++ b/mail-client/claws-mail/ChangeLog
@@ -1,6 +1,85 @@
 # ChangeLog for mail-client/claws-mail
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/ChangeLog,v 1.103 2008/12/22 13:35:23 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/ChangeLog,v 1.104 2008/12/22 13:54:57 fauli Exp $
+
+*claws-mail-3.7.0 (22 Dec 2008)
+
+  22 Dec 2008; Christian Faulhammer <fauli@gentoo.org>
+  +claws-mail-3.7.0.ebuild:
+  Version bump:
+
+  New in this release:
+
+  Expanding/Collapsing of threads is now approximately 95% faster.
+
+  Cache reading is now approximately 10% faster.
+
+  The shortcut key settings of the main window and the message list context
+  menus are now connected.
+
+  The preferences on the 'Other' page have now been moved to
+  Other/Miscellaneous. The parent pages are now unselectable and the first
+  page is automatically selected on opening the preferences.
+
+  In the Compose window, on the Others tab, the 'Save message to' entry now
+  has a drop-down list of the previous save locations.
+
+  In the Compose window, the Attachments Properties window is now confirmed
+  and closed with the Return key.
+
+  When using an external editor to compose messages, the message is
+  automatically saved to Drafts when the external editor is closed.
+
+  A hidden option has been added, 'primary_paste_unselects' which causes the
+  primary buffer to be cleared and the insertion point to be repositioned
+  when the middle mouse button is used for pasting text. It is turned off by
+  default.
+
+  In the Actions window, the Escape key now cancels the action editing.
+
+  Offline SSL certificate verification has been added.
+
+  Privacy plugins: The decryption failure messages are now shown in the
+  NoticeView just above the message text rather than in a popup window.
+
+  Privacy plugins: when listing the UIDs during a signature check, show the
+  UID validity
+
+  tools/kdeservicemenu Support for kde4 has been added.
+
+  tools/popfile-link.sh Support for reusing existing POPFile session ID has
+  been added.
+
+  win32: better integration has been implemented by using the standard file
+  associations.
+
+  The user manuals have been updated.
+
+  Updated Brazilian Portuguese, Bulgarian, Catalan, Dutch, Finnish, French,
+  German, Hungarian, Russian and Swedish translations.
+
+  Added Czech translation.
+
+  Removed unmaintained Serbian and Slovak translations.
+
+  Bug fixes: o bug 1591, S/MIME: better key handling/selection dialog o bug
+  1711, 'Save-as attachment crashes o bug 1736, Key import does not work o
+  bug 1746, Makes a mailto link from several paragraphs o bug 1756,
+  "Outdated translators list in About dialogue" o bug 1768, claws-mail
+  crashes while checking smime bad signature o bug 1771, Folder template
+  gets truncated when exiting the application o bug 1776, use encoded name
+  parameters for attachments instead of ascii o bug 1779, PGP Inline badly
+  handles multipart o bug 1789, filtering account selection (regression) o
+  bug 1796, PGP/MIME setting: "select key by your email address" doesnt work
+  o fix building with gnuTLS on (Open)Solaris o fix account selection in
+  Mailing list menu o fix "display sender using addressbook" when
+  prefs_common.swap_from is in use. o win32: fix unlinking, renaming and bug
+  with non-ascii username o win32: fix getting content-type o win32: prevent
+  multiple launch o win32: fix Start menu update after registering as
+  default Mail app
+
+  For further details of the numbered bugs listed above consult
+  http://www.thewildbeast.co.uk/claws-mail/bugzilla/index.cgi
 
   22 Dec 2008; Christian Faulhammer <fauli@gentoo.org>
   claws-mail-3.6.1.ebuild, claws-mail-3.6.1-r1.ebuild:
diff --git a/mail-client/claws-mail/claws-mail-3.7.0.ebuild b/mail-client/claws-mail/claws-mail-3.7.0.ebuild
new file mode 100644
index 000000000000..dd1b36adcba4
--- /dev/null
+++ b/mail-client/claws-mail/claws-mail-3.7.0.ebuild
@@ -0,0 +1,175 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/claws-mail/claws-mail-3.7.0.ebuild,v 1.1 2008/12/22 13:54:57 fauli Exp $
+
+inherit eutils multilib
+
+DESCRIPTION="An email client (and news reader) based on GTK+"
+HOMEPAGE="http://www.claws-mail.org/"
+
+SRC_URI="mirror://sourceforge/sylpheed-claws/${P}.tar.bz2"
+
+SLOT="0"
+LICENSE="GPL-3"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="bogofilter crypt dillo doc gnome gnutls imap ipv6 kde ldap nntp pda
+session smime spamassassin spell ssl startup-notification xface"
+
+COMMONDEPEND=">=x11-libs/gtk+-2.6
+	pda? ( >=app-pda/jpilot-0.99 )
+	ssl? ( net-libs/gnutls )
+	ldap? ( >=net-nds/openldap-2.0.7 )
+	crypt? ( >=app-crypt/gpgme-1.1.1 )
+	dillo? ( www-client/dillo )
+	spell? ( >=app-text/enchant-1.0.0 )
+	kde? ( kde-base/kdelibs )
+	imap? ( >=net-libs/libetpan-0.57 )
+	nntp? ( >=net-libs/libetpan-0.57 )
+	gnome? ( >=gnome-base/libgnomeprintui-2.2 )
+	gnutls? ( net-libs/gnutls )
+	startup-notification? ( x11-libs/startup-notification )
+	bogofilter? ( mail-filter/bogofilter )
+	session? ( x11-libs/libSM
+			x11-libs/libICE )
+	smime? ( >=app-crypt/gpgme-1.1.1 )"
+
+DEPEND="${COMMONDEPEND}
+	xface? ( >=media-libs/compface-1.4 )
+	dev-util/pkgconfig"
+
+RDEPEND="${COMMONDEPEND}
+	app-misc/mime-types
+	x11-misc/shared-mime-info"
+
+PLUGIN_NAMES="acpi-notifier archive att-remover attachwarner cachesaver fetchinfo gtkhtml mailmbox newmail notification perl rssyl spam_report tnef_parse vcalendar"
+
+src_compile() {
+	local myconf="--disable-libetpan"
+
+	# libetpan is needed if user wants nntp or imap functionality
+	use imap && myconf="--enable-libetpan"
+	use nntp && myconf="--enable-libetpan"
+
+	econf \
+		$(use_enable gnome gnomeprint) \
+		$(use_enable ipv6) \
+		$(use_enable ldap) \
+		$(use_enable pda jpilot) \
+		$(use_enable spell enchant) \
+		$(use_enable gnutls) \
+		$(use_enable ssl gnutls) \
+		$(use_enable xface compface) \
+		$(use_enable doc manual) \
+		$(use_enable startup-notification) \
+		$(use_enable session libsm) \
+		$(use_enable crypt pgpmime-plugin) \
+		$(use_enable crypt pgpinline-plugin) \
+		$(use_enable crypt pgpcore-plugin) \
+		$(use_enable dillo dillo-viewer-plugin) \
+		$(use_enable spamassassin spamassassin-plugin) \
+		$(use_enable bogofilter bogofilter-plugin) \
+		$(use_enable smime smime-plugin) \
+		--enable-trayicon-plugin \
+		--disable-maemo ${myconf} || die
+
+	emake || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	# Makefile install claws-mail.png in /usr/share/icons/hicolor/48x48/apps
+	# => also install it in /usr/share/pixmaps for other desktop envs
+	# => also install higher resolution icons in /usr/share/icons/hicolor/...
+	insinto /usr/share/pixmaps
+	doins ${PN}.png || die
+	local res resdir
+	for res in 64x64 128x128 ; do
+		resdir="/usr/share/icons/hicolor/${res}/apps"
+		insinto ${resdir}
+		newins ${PN}-${res}.png ${PN}.png || die
+	done
+
+	dodoc AUTHORS ChangeLog* INSTALL* NEWS README* TODO*
+	docinto tools
+	dodoc tools/README*
+
+	insinto /usr/share/applications
+	doins ${PN}.desktop
+
+	einfo "Installing extra tools"
+	cd "${S}"/tools
+	exeinto /usr/$(get_libdir)/${PN}/tools
+	doexe *.pl *.py *.conf *.sh || die
+	doexe tb2claws-mail update-po uudec uuooffice || die
+
+	if use kde; then
+		einfo "Installing kde service scripts"
+		local kdeprefix="$(kde-config --prefix)"
+		local servicescript="${PN}-kdeservicemenu.pl"
+		local desktopfile="${PN}-attach-files.desktop"
+		cd "${S}"/tools/kdeservicemenu
+		sed -i -e "s:SCRIPT_PATH:${kdeprefix}/bin/${servicescript}:g" \
+			${desktopfile}.template
+		dodir /usr/share/apps/konqueror/servicemenus
+		insopts -m 0644
+		insinto /usr/share/apps/konqueror/servicemenus
+		newins ${desktopfile}.template ${desktopfile} || die
+		dodir ${kdeprefix}/bin
+		insopts -m 755
+		exeinto ${kdeprefix}/bin
+		doexe ${servicescript} || die
+	fi
+
+	# kill useless plugin files
+	rm -f "${D}"/usr/lib*/${PN}/plugins/*.{la,a}
+}
+
+pkg_postinst() {
+	gtk-update-icon-cache -f -t "${ROOT}"/usr/share/icons/hicolor
+
+	UPDATE_PLUGINS=""
+	RENAME_PLUGINS=""
+	for x in ${PLUGIN_NAMES}; do
+		has_version mail-client/${PN}-$x && UPDATE_PLUGINS="${UPDATE_PLUGINS} $x"
+		has_version mail-client/sylpheed-claws-$x && RENAME_PLUGINS="${RENAME_PLUGINS} $x"
+	done
+	if [ -n "${RENAME_PLUGINS}" ]; then
+		elog
+		elog "The following sylpheed-claws plugins were found on your system:"
+		elog
+		for x in ${RENAME_PLUGINS}; do
+			elog "    mail-client/sylpheed-claws-$x"
+		done
+		elog
+		elog "If you want to continue using those you need to merge their "
+		elog "renamed counterparts:"
+		elog
+		for x in ${RENAME_PLUGINS}; do
+			elog "    mail-client/${PN}-$x"
+		done
+		elog
+	fi
+	if [ -n "${UPDATE_PLUGINS}" ]; then
+		elog
+		elog "You have to re-emerge or update the following plugins:"
+		elog
+		for x in ${UPDATE_PLUGINS}; do
+			elog "    mail-client/${PN}-$x"
+		done
+		elog
+	fi
+	if [ -n "${RENAME_PLUGINS}${UPDATE_PLUGINS}" ]; then
+		elog
+		elog "You can use"
+		elog "    /bin/bash ${FILESDIR}/plugins-rebuild.sh"
+		elog "to automatically handle this."
+		elog
+		epause 5
+		ebeep 3
+	fi
+}
+
+pkg_postrm() {
+	gtk-update-icon-cache -f -t "${ROOT}"/usr/share/icons/hicolor
+}