Add KDE 4.2.2

(Portage version: 2.2_rc29/cvs/Linux x86_64)

2 files changed, 71 insertions, 1 deletions

diff --git a/kde-base/kget/ChangeLog b/kde-base/kget/ChangeLog
index b993b4028f08..78cc923a687e 100644
--- a/kde-base/kget/ChangeLog
+++ b/kde-base/kget/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kget
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kget/ChangeLog,v 1.109 2009/04/11 18:41:10 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kget/ChangeLog,v 1.110 2009/04/11 23:08:42 alexxy Exp $
+
+*kget-4.2.2 (11 Apr 2009)
+
+  11 Apr 2009; Alexey Shvetsov <alexxy@gentoo.org> +kget-4.2.2.ebuild:
+  Add KDE 4.2.2
 
   11 Apr 2009; Raúl Porcel <armin76@gentoo.org> kget-4.2.1-r1.ebuild:
   Add ~alpha/~ia64 wrt #260777
diff --git a/kde-base/kget/kget-4.2.2.ebuild b/kde-base/kget/kget-4.2.2.ebuild
new file mode 100644
index 000000000000..d157a1b95a2f
--- /dev/null
+++ b/kde-base/kget/kget-4.2.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kget/kget-4.2.2.ebuild,v 1.1 2009/04/11 23:08:42 alexxy Exp $
+
+EAPI="2"
+
+KMNAME="kdenetwork"
+inherit kde4-meta
+
+DESCRIPTION="An advanced download manager for KDE"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="debug doc +plasma bittorrent bittorrent-external +semantic-desktop sqlite"
+
+DEPEND="
+	dev-libs/libpcre
+	>=kde-base/kdelibs-${PV}:${SLOT}[kdeprefix=,semantic-desktop?]
+	bittorrent? (
+		app-crypt/qca:2
+		dev-libs/gmp
+	)
+	bittorrent-external? ( >=net-p2p/ktorrent-3.1.5 )
+	sqlite? ( dev-db/sqlite )
+"
+RDEPEND="${DEPEND}
+	semantic-desktop? ( >=kde-base/nepomuk-${PV}:${SLOT}[kdeprefix=] )
+"
+
+pkg_setup() {
+	if use bittorrent && use bittorrent-external; then
+		echo
+		eerror "USE flag 'bittorrent' conflicts with these USE flag 'bittorrent-external'"
+		eerror
+		eerror "You must disable these conflicting flags before you can emerge this package."
+		eerror "You can do this by disabling one of these flags in /etc/portage/package.use:"
+		eerror "    =${CATEGORY}/${PN}-${PV} -bittorrent-external"
+		echo
+		die "Conflicting USE flags found"
+	fi
+
+	kde4-base_pkg_setup
+}
+
+src_prepare() {
+	if ! use bittorrent && ! use bittorrent-external; then
+		sed -i -e '/bittorrent/s:^:#DONOTCOMPILE :' \
+			kget/transfer-plugins/CMakeLists.txt \
+			|| die "sed to disable torrent support failed."
+		sed -i -e 's|application/x-bittorrent;||' \
+			kget/desktop/kget.desktop \
+			|| die "sed to disable torrent mime-type handling failed."
+	fi
+
+	kde4-meta_src_prepare
+}
+
+src_configure() {
+	mycmakeargs="${mycmakeargs}
+		$(cmake-utils_use_enable bittorrent EMBEDDED_TORRENT_SUPPORT)
+		$(cmake-utils_use_with plasma Plasma)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_with sqlite Sqlite)"
+
+	kde4-meta_src_configure
+}